PUBLIC oform1

oform1=NEWOBJECT("form1")
oform1.Show
RETURN

DEFINE CLASS form1 AS form
	Top =  0 
	Left =  0 
	Height =  305 
	Width =  388 
	DoCreate = .T.
	Caption = "Net Tree"
	Icon = (_Screen.Icon)
	enabledrag = .F.
	onode = .NULL.
	Name = "Form1"
	indrag = .F.

	ADD OBJECT tree AS olecontrol WITH ;
		DragIcon = "images\dragmove.cur", ;
		Top =  0 , ;
		Left =  0 , ;
		Height =  206 , ;
		Width =  281 , ;
		Name = "Tree"


	ADD OBJECT images AS olecontrol WITH ;
		Top =  265 , ;
		Left =  0 , ;
		Height =  100 , ;
		Width =  100 , ;
		Name = "Images"

	PROCEDURE loadnode
		Lparameters m.parentid
		With this
			Local o, tmp[ 1 ], m.id
			Select * from NetTree where parentid=m.parentid into cursor _
			If _TALLY >  0 
				Scan all
					.Tree.Nodes.Add(m.parentid, 4 ,id,name,NodeType)
					m.id=id
					select count(*) from NetTree where ParentId=m.Id into array tmp
					If TMP[ 1 ]> 0 
						o=.Tree.Nodes.Add(m.id, 4 ,,)
						o.Tag='~'
					EndIf
				EndScan 
			EndIf
			USE in _
		EndWith
	ENDPROC

	PROCEDURE makevisible
		Lparameters m.id
		With this
			Local tmp[ 1 ], tmpcount, oNode, m.ParentID
			Select NetTree
			Locate for ID=m.ID 
			If Found()
				Dimension tmp[ 1 ]
				tmpCount= 0 
				m.ParentId=ParentID
				DO While Found()
					tmpCount = tmpCount +  1  
					Dimension tmp[tmpCount]
					Tmp[tmpCount]=ID
					If Type(".Tree.Nodes.Item(id)")='O' 
						Exit
					Else
						m.ParentID=ParentID
						Locate for ID=m.ParentID
					EndIf
				EndDo
				For i=tmpCount to  1  step - 1 
					Select NetTree
					Locate for Id=TMP[i]
					oNode=.Tree.Nodes.Item(id)
					.Tree.Expand(oNode)
				Next
				oNode.EnsureVisible()
				.Tree.SelectedItem=oNode
			EndIf
		EndWith
	ENDPROC

	PROCEDURE Init
		With this
			Select NetTree
			Go TOP
			.Tree.ImageList=.Images.Object
			.Tree.Nodes.Add(, 0 ,id,"Acme Network", 5 , 5 )
			.LoadNode(id)

			.Resize()

		EndWith
	ENDPROC

	PROCEDURE Resize
		With this
			.Tree.Width=.Width
			.Tree.Height=.Height
		EndWith
	ENDPROC

	PROCEDURE tree.Expand
		*** ActiveX Control Event ***
		LPARAMETERS node
		With this
			If Node.Children >  0 
				If Node.Child.Tag='~'
					Local m.Index
					m.Index=Node.Child.Index
					This.Nodes.Remove(m.index)
					This.parent.LoadNode(Node.Key)
				EndIf
			EndIf
		EndWith
	ENDPROC

	PROCEDURE tree.MouseDown
		*** ActiveX Control Event ***
		LPARAMETERS button, shift, x, y
		If button= 1  and ThisForm.EnableDrag 
			ThisForm.onode=This.SelectedItem 
		EndIf
	ENDPROC

	PROCEDURE tree.MouseMove
		*** ActiveX Control Event ***
		LPARAMETERS button, shift, x, y
		If Button= 1 
			If ThisForm.EnableDrag
				If Not ThisForm.oNode.Key='__________'
					ThisForm.Indrag=.T.
					This.Drag( 1 )
				EndIf
			EndIf
		EndIf
	ENDPROC

	PROCEDURE tree.NodeCheck
		*** ActiveX Control Event ***
		LPARAMETERS node

		this.Object.Enabled=.F.

		IF node.checked=.f. && Крыжик убираем - обычный шрифт и "-" в тексте
			node.Bold=.f.
			node.text=node.text+' -'
		ELSE && Крыжик добавляем - жирный шрифт и "+" в тексте
			node.Bold=.t.
			node.text=node.text+' +'
		ENDIF 
		this.Object.Enabled=.T.
	ENDPROC


	PROCEDURE tree.DragDrop
		LPARAMETERS oSource, nXCoord, nYCoord
		If IsNull(This.DropHighlight)
			thisform.indrag=.F.
		Else
			If ThisForm.oNode=This.DropHighlight
			Else
				If Type("ThisForm.oNode.Parent")="O" ;
				and Not IsNull(ThisForm.oNode.Parent) 

					Local m.Id, m.ParentID

					Select NetTree
					Locate for Id=ThisForm.oNode.Key
					If Found()
						Replace ParentID with This.DropHighlight.Key
						ThisForm.oNode.Parent=This.DropHighlight
					EndIf
				EndIf
				thisform.indrag=.F.
				this.DropHighlight=.NULL.
			EndIf
		EndIf
	ENDPROC

	PROCEDURE tree.DragOver
		LPARAMETERS oSource, nXCoord, nYCoord, nState
		If ThisForm.indrag 
			Local x,y, o
			x=nXCoord-This.Left
			y=nYCoord-This.Top
			This.DropHighlight=This.HitTest(x* 15 , y* 15 )

			If Vartype(This.DropHighlight)="O" ;
				and not IsNull(This.DropHighlight)

				If This.DropHighlight.Children >  0  ;
				and Not This.DropHighlight.Expanded 

					This.Expand(This.DropHighlight)
					This.DropHighlight.Expanded=.T.

				EndIf
			EndIf
		EndIf
	ENDPROC

ENDDEFINE