Везде:
*Ip  -  IP соединившегося клиента
*hSocket -  хендл соединения, через него соединением можно рулить
*На  1  порт можно подключить  1024  клиента, у каждого будет свой hSocket 

XDllR.dll -  клиент tcp-ip, должен лежать по пути видимому приложению -  клиенту по SET("PATH")
XDll.dll  -  сервер, tcp-ip, должен лежать по пути видимому приложению - серверу (  у вас это уже принт  -  сервер ) по SET("PATH")

* Сервер
* Реализовать на машине  к которой подключен принтер
*Пример -  использоваания 
Public oServer As cWinSockSever
oServer =  Createobject("cWinSockSever")
* К сожалению, пока объект сервера может быть именован только как oServer(!)
With oServer
	.cTCPPort =   23   && Это для тестинга по телнету, лучше использовать порты за  5001 
	?  .InitSocket() &&  Слушаем порт, ждем клиентов
Endwith

* Реализация 
Define Class cWinSockSever As Custom
	cTCPPort =  23 
	iIDispath = Sys( 3095 ,_vfp)
	hSocket =  0 
	
	PROCEDURE Init
		Declare Integer GetSum In XDll.Dll  Integer, Integer
		Declare Integer InitSocket In XDll.Dll  Integer, Integer
		Declare Integer Send_Message In XDll.Dll  String @, Integer
		Declare Integer Socket_Close In XDll.Dll  Integer
		Declare Integer WSAGetLastError In ws2_32.Dll
	EndProc

	Procedure InitSocket
	This.hSocket = InitSocket(This.cTCPPort,This.iIDispath)
	Return ( This.hSocket >  0 )
	Endproc

	Procedure WsMessage
	Lparameters cMsg
		*Асинхронное
		*Диангостические сообщения, можно выводить в статус бар.. например
		*Все ошибки критические, если такую словили все, разбирайтесь что-то не так либо с сетью либо с параметрами ( в частности порт )
		*Возвращает:
		*WSAStartup Error           - ошибка инициализации интерфейса winsocket  2 . 0 
		*INVALID_SOCKET             - ошибка создания сокета
		*bind error                 - ошибка ассоциации сокета с сетевым интерфейсом (очень редкая,но возможная)
		*Error listen               - ошибка инициализации слушателя порта
		*WSA_WAIT_FAILED            - ошибка времени ожидания событий FD_READ|FD_CLOSE ( установлено в бесконечно, реализовано в потоке, работу не тормозит)
		*SOCKET_ERROR               - ошибка перечесления собитий для слушателя порта
		*Accept Error   		    - ошибка  анализа запроса соединения
		*WSAEnumNetworkEvents Error - фиг знает что за собтие приперлось вместо сетевого
		
		*OK -  все Хокей!
		*Реальные номера ошибок можно получить через WSAGetLastError , описание в MSDN
	?"Error ",cMsg
    ? WSAGetLastError()
	Endproc

* Принял соединение
	Procedure WsAccept
	*Асинхронное
	* Тут можете послать клиента через Socket_Close( hSocket )  если адрес не устраивает,
	* если нет, то  соединение клиента принимается по умолчанию
	Lparameters Ip As String, hSocket As Integer
	? "Accept ",Ip
	? "hSocket ",hSocket
	Endproc


	Procedure WsRead
	*Асинхронное
	*Событие  -  прием данных
	*Send_Message(@tStr,hSendSock) эхо ответ, для тестинга
	*тут разбираете tcStr и пихаете в порт данные. Лучше   MS Com Control ActiveX  не использовать.
	* лучше описать функции ввода  - вывода на с++ и сделать асинхронные очереди.
	Lparameters tcStr As String
	?? tcStr
	Endproc

	Procedure WsClose
	*Асинхронное
	* собитие  -  узер с адресом Ip закрыл соединение
	Lparameters Ip, hSocket
	? "CLOSE ",Ip, ' ', hSocket
	ENDPROC
Enddefine


*Клиент
*Реализовать на строне приложения- клиента
*Пример -  использоваания
	Public oClient
	oClient =  Createobject("cWinSockClient")
	* К сожалению, пока объект клиента может быть именован только как oClient(!)
	oClient.nTcpPort =  23 
	oClient.sHost = "192.168.0.1" && Для случая когда клиента и сервер запущены на  1  машине
	oClient.Connect()
	
	* Заершение работы приложения клиента - выдать oClient.CloseConnect(), на сервере возникнет собитие oClient.WsClose( Ip, hSocket )

* Реализация 	
Define Class cWinSockClient As Custom
	nTcpPort =  23 
	sHost = ""
	iIDispath = Sys( 3095 ,_vfp)
	hSocket =  0 

	Procedure Connect
	*Асинхронное
	* Запрос на соединение с сервером 
	Local lcHost
	lcHost =  This.sHost
	With This
		This.hSocket = WsConnect( .nTcpPort, .iIDispath, @lcHost)
	Endwith
	Return ( This.hSocket >  0 )
	Endproc

	Procedure WsMessage( tMessage As String )
	*Асинхронное
	? tMessage
	
	Endproc

	Procedure WsConnected( )
	*Асинхронное
	* Соединение с сервером установлено, можно слать данные
	? "Соединение установлено"
	Endproc

	Procedure WsClose()
	*Асинхронное
	* Сервер закрыл соединение с текущим клиентом

	Endproc

	Procedure CloseConnect
	* Если нужно отрубиться от сервера, стоит ее вызвать
	Return Socket_Close_Cli( This.hSocket )
	Endproc

	Procedure WsRead(tData As String)
	*Асинхронное
	* Пришли данные от сервера
	? tData
	Endproc

	Procedure Init
	Declare Integer WsConnect 	 In XDllR.Dll  Integer, Integer, String @
	Declare Integer Send_Message In XDllR.Dll  String @, Integer, integer 
	Declare Integer Socket_Close In XDllR.Dll As Socket_Close_Cli Integer
	Declare Integer WSAGetLastError In ws2_32.Dll
	Endproc

	Procedure s_message(tData As String)
	* Послать сообщение на сервер, сервер примет данные в событии oServer.WsRead(...)
	* Вот тут и посылаете свои данные из любого места  программы клиента (ну конечно после соединения с сервером)
             * Строка для обмена  100  байт, могу увеличить
	LOCAL  cMessage as String
	cMessage  = tData+CHR( 0 )
	Send_Message(@cMessage , This.hSocket,LEN(cMessage  ))
	Endproc
ENDDEFINE