Так у меня работает с файлами:
*==========================================================================*
PROCEDURE WorkFileAttribute
*--------------------------------------------------------------------------*
LPARAMETERS lpFileName, npYesReadOnly

#DEFINE FILE_ATTRIBUTE_READONLY 1
#DEFINE FILE_ATTRIBUTE_HIDDEN 2
#DEFINE FILE_ATTRIBUTE_SYSTEM 4
#DEFINE FILE_ATTRIBUTE_DIRECTORY 16
#DEFINE FILE_ATTRIBUTE_ARCHIVE 32
#DEFINE FILE_ATTRIBUTE_NORMAL 128
#DEFINE FILE_ATTRIBUTE_TEMPORARY 512
#DEFINE FILE_ATTRIBUTE_COMPRESSED 2048

DECLARE SHORT SetFileAttributes IN kernel32;
STRING lpFileName, INTEGER dwFileAttributes

DECLARE INTEGER GetFileAttributes IN kernel32 STRING lpFileName

* Чтение атр-ов указанного файла
dwFileAttributes = GetFileAttributes (lpFileName)

IF dwFileAttributes = -1 && Указанный файл не существует
RETURN
ENDIF

IF dwFileAttributes > 0
DO CASE
CASE npYesReadOnly = 1
* read-only attribute будет установлен !!!!!
dwFileAttributes = BITOR(dwFileAttributes, FILE_ATTRIBUTE_READONLY)

CASE npYesReadOnly = 2
* read-only attribute будет удален !!!!!
IF BITAND(dwFileAttributes, FILE_ATTRIBUTE_READONLY) = FILE_ATTRIBUTE_READONLY
dwFileAttributes = dwFileAttributes - FILE_ATTRIBUTE_READONLY
ENDIF

CASE npYesReadOnly = 3
* HIDDEN attribute будет установлен !!!!!
dwFileAttributes = BITOR(dwFileAttributes, FILE_ATTRIBUTE_HIDDEN)

CASE npYesReadOnly = 4
* HIDDEN будет удален !!!!!
IF BITAND(dwFileAttributes, FILE_ATTRIBUTE_HIDDEN) = FILE_ATTRIBUTE_HIDDEN
dwFileAttributes = dwFileAttributes - FILE_ATTRIBUTE_HIDDEN
ENDIF
ENDCASE

* установка указанного атрибута для файла
= SetFileAttributes (lpFileName, dwFileAttributes)

ENDIF

* End WorkFileAttribute
*==========================================================================*