*!*	При отправке отчета на принтер всегда появляется стандартное окно "Printing..." 
*!*	(в русскоязычной Run-Time библиотеке, т.е. в готовом EXE, это окно имеет 
*!*	имя "Печать..."). 

*!*	Подавить выдачу этого окна нельзя. Однако его можно скрыть сдвинув за область 
*!*	видимости.

*!*	Данное решение использует пользовательскую функцию

*!*	Для VFP вызов этой функции следует поместить в разделе On Entry полосы Title. 
*!*	Для FoxPro 2.x  - в выражении поля в полосе Title, причем в самой функции 
*!*	обязательно следует добавить RETURN ""

*!*	В конце данного файла это функция HidePrn

*!*	В данном примере специально использовано большое количество записей, 
*!*	чтобы Вы успели рассмотреть это окно (более 300 страниц отчета)


PARAMETERS tnRecAmount
IF TYPE('tnRecAmount')<>"N" OR tnRecAmount<1
	tnRecAmount=1000
ENDIF

IF USED("curReport")=.T.
	USE IN curReport
ENDIF

CREATE CURSOR curReport (RecordID I, NickName C(50))

LOCAL lnI
FOR m.lnI=1 TO m.tnRecAmount
	INSERT INTO curReport VALUES (m.lnI, "Строка отчета № "+LTRIM(STR(m.lnI)))
ENDFOR

* Собственно выполнение отчета
select curReport
REPORT FORM (Contents.NameFRX) NOCONSOLE TO PRINTER PROMPT PREVIEW
* Если хочется подчеркнуть, что запускается именно файл FRX, то
*REPORT FORM (AllTrim(Contents.NameFRX)+'.FRX') NOCONSOLE TO PRINTER PROMPT PREVIEW

USE IN curReport

******************************************************************************
* Функция, предназначенная для сокрытия диалогового окна "Printing..."

FUNCTION HidePrn
* Для этапа отладки и англоязычной Run-Time библиотеки
IF WEXIST("Printing...")=.T.
    MOVE WINDOW "Printing..." TO -1000, -1000
ENDIF
* Для русскоязычной Run-Time библиотеки
IF WEXIST("Печать...")=.T.
    MOVE WINDOW "Печать..." TO -1000, -1000
ENDIF
* Если у Вас другой язык, то название окна придется определять 
* экспериментальным путем.
RETURN ""	&& для VFP - эта строка не обязательна
ENDFUNC