* метод переливает данные из локального курсора в табличку на сервере
lparameters tcCreateTableCmd, ; && можно не передавать, если есть уже табличка
			;
			tcTableName,      ; && имя таблички на сервере
			tcKeyField,		  ; && id в табличке
			tcTableFields,    ; && поля таблицы
			;
			tcCursorName,     ; && курсор на локале
			tcCursorFields,   ; && поля курсора
			tcWhere             && условие отбора записей из курсора


if !empty(tcCreateTableCmd) 
	local lcAddCmd
	if  at("#", tcTableName)> 0 
		* удаляем только временные таблицы
		text to lcAddCmd  noshow textmerge pretext  3 
			if object_id('tempdb.<<tcTableName>>') is not null drop table <<tcTableName>>
			
		endtext
	else
		lcAddCmd = ""
	endif
	if oServer.SqlExec(lcAddCmd + tcCreateTableCmd)< 0 
		return .f.
	endif
endif


local loCad, llSuccess
loCad = this.createCadObject(this,				;
							 tcTableName,		;	&& таблица на сервере
							 tcKeyField,		;	&& ключь-линк в таблице
							 "#ALLFIELDS#",		;   && обновляемые поля в таблице
							 .f.,				;	&& схема - преобразов-е типов
							 "1=0", 			;   && условие в запросе
							 tcTableFields, 	;   && поля в строке запроса к таблице сервера
							 "", 				;	&& group by
							 "",			    ;	&& order by
							 "",				;	&& добавчик к SelectCmd
							 "", 				;   && если уж совсем нестандартный запрос
							 "SavedTable")			&& имя алиаза
							 
if 	vartype(loCad)="O"

	tcWhere = iif( empty(tcWhere), ".t.", tcWhere)
	try 
		insert into SavedTable ( &tcTableFields ) ;
			select &tcCursorFields ;
				from (tcCursorName) with (buffering=.t.) ;
				where &tcWhere
		llSuccess = .t.
	catch
		messagebox("Ошика запроса из курсора",  16 , "oServer.SaveTable") 
	endtry
	
	if llSuccess and loCad.SaveCursor()
		return .t.
	else
		return .f.
	endif 	

else
	return .f.
endif