* метод переливает данные из локального курсора в табличку на сервере
lparameters tcCreateTableCmd, ; && можно не передавать, если есть уже табличка
			;
			tcTableName,      ; && имя таблички на сервере
			tcKeyField,		  ; && id в табличке
			tcTableFields,    ; && поля таблицы
			;
			tcCursorName,     ; && курсор на локале
			tcCursorFields,   ; && поля курсора
			tcWhere,          ; && условие отбора записей из курсора
			toObject            && объект, у которого есть курсор и у объекта есть приватная датасессия 

if !empty(tcCreateTableCmd) 
	local lcAddCmd
	if at("#", tcTableName)> 0 
		* удаляем только временные таблицы
		text to lcAddCmd  noshow textmerge pretext  3 
			if object_id('tempdb..<<tcTableName>>') is not null drop table <<tcTableName>>
			
		endtext
	else
		lcAddCmd = ""
	endif
	if this.SqlExec(lcAddCmd + tcCreateTableCmd)<= 0 
		return .f.
	endif
endif

if vartype(toObject)="O" and pemstatus( toObject, "dataSessionId",  5 )
	if set("Datasession")<>toObject.dataSessionId
		set datasession to toObject.dataSessionId
	endif 
endif

local loCad, llSuccess, lcCmd
loCad = this.createCadObject(this,				;
							 tcTableName,		;	&& таблица на сервере
							 tcKeyField,		;	&& ключь-линк в таблице
							 "#ALLFIELDS#",		;   && обновляемые поля в таблице
							 .f.,				;	&& схема - преобразов-е типов
							 "1=0", 			;   && условие в запросе
							 "*", 				;   && поля в строке запроса к таблице сервера
							 "", 				;	&& group by
							 "",			    ;	&& order by
							 "",				;	&& добавчик к SelectCmd
							 "", 				;   && если уж совсем нестандартный запрос
							 "SavedTable")			&& имя алиаза
							 
if 	vartype(loCad)="O" and used("SavedTable")

	tcWhere = iif( empty(tcWhere), ".t.", tcWhere)
	* подготавливаем команду для налива данных в курсорадаптер
	Text to lcCmd NOSHOW TEXTMERGE PRETEXT  15 
		insert into SavedTable (<<tcTableFields>>)
			select <<tcCursorFields>>
				from <<tcCursorName>> with (buffering=.t.)
				where <<tcWhere>>
	EndText
	* добавляем данные из локального курсора в пуской курсорадаптер
	try 
		&lcCmd
		llSuccess = .t.
	catch
		messagebox("Ошибка запроса из курсора !",  16 , "oServer.SaveTable") 
	endtry
	* сохраняем данные на сервер
	return (llSuccess and loCad.SaveCursor())

else

	* не поднялся курсорадаптер
	return .f.

endif