USE IN SELECT("CurMain")
CLEAR
lnSeconds = SECONDS()
IF GenTestCursor("CurMain",  3 ,  40000 )
	?"Заполнение курсора", SECONDS()-lnSeconds
	lnSeconds = SECONDS()
	ExportToExcel("CurMain")
	?"Выгрузка в эксель", SECONDS()-lnSeconds
ENDIF

PROCEDURE ExportToExcel
	LPARAMETERS tcCursor
	LOCAL loExcel, loBook, loSheet
	LOCAL lnField, lnFields, laFields( 1 )
	LOCAL lcValue, lcFormat
	PRIVATE laValues ( 1 )
	loExcel = CREATEOBJECT("Excel.Application")
	loBook	= loExcel.Workbooks.Add()
	loSheet	= loBook.Sheets( 1 )
	loSheet.Select()	
	
	lnFields = AFIELDS(laFields, tcCursor)
	FOR lnField =  1  TO lnFields
		STORE "" TO lcValue, lcFormat
		DO CASE
			CASE laFields[lnField,  2 ]=="C"
				lcValue = TEXTMERGE("NVL(<<laFields[lnField, 1]>>, '')")
				lcFormat	= "@"
			CASE laFields[lnField,  2 ]=="D"
				lcValue		= TEXTMERGE("NVL(<<laFields[lnField, 1]>>, {})")
				lcFormat	= "dd/mm/yyyy;@"
			CASE laFields[lnField,  2 ]=="I"
				lcValue		= TEXTMERGE("NVL(<<laFields[lnField, 1]>>, 0)")
				lcFormat	= "0;-0;"
			CASE laFields[lnField,  2 ]=="N"
				lcValue		= TEXTMERGE("NVL(<<laFields[lnField, 1]>>, 0)")
				lcFormat	= "#,##0.00;-#,##0.00;"
		ENDCASE
		IF !EMPTY(lcValue)
			SELECT &lcValue FROM (tcCursor) INTO ARRAY laValues
			loSheet.Cells[ 1 , lnField].Resize[_TALLY,  1 ] = RetArray("laValues")
			IF !EMPTY(lcFormat)
				loSheet.Cells[ 1 , lnField].Resize[_TALLY,  1 ].NumberFormat = lcFormat
			ENDIF
			*?laValues[ 1 ]
		ENDIF
	NEXT lnField
	loExcel.Cells.EntireColumn.AutoFit()
	loExcel.Visible = .T.
ENDPROC && ExportToExcel

PROCEDURE RetArray
	LPARAMETERS tcArrayName
	RETURN @&tcArrayName
ENDPROC

PROCEDURE GenTestCursor
	LPARAMETERS tcCursor, lnColCount, lnRowCount
	IF !USED(tcCursor)
		*-* (IGEL) Генерация макроподстановок
		lcFieldList = ""
		lcValList	= ""
		FOR m.i =  1  TO lnColCount
			lcFieldList	= lcFieldList + IIF(EMPTY(lcFieldList), "", ", ") + ;
				TEXTMERGE([i<<m.i>> I, c<<m.i>> C( 20 ), d<<m.i>> D])
			lcValList	= lcValList + IIF(EMPTY(lcValList), "", ", ") + ;
				TEXTMERGE([FLOOR(RAND()* 100 - 50 ), SYS( 2015 ), DATE() + FLOOR(RAND()* 100 - 50 )])
		ENDFOR
		TEXT TO lcScript TEXTMERGE NOSHOW PRETEXT  7 
			CREATE CURSOR <<tcCursor>> (<<lcFieldList>>)
		ENDTEXT
		&lcScript
		TEXT TO lcScript TEXTMERGE NOSHOW PRETEXT  7 
			INSERT INTO <<tcCursor>> VALUES (<<lcValList>>)
		ENDTEXT
		FOR m.i =  1  TO lnRowCount
			&lcScript
		ENDFOR
	ENDIF
ENDPROC && GenTestCursor