*мой клас грида.
**************************************************
*-- ParentClass:  grid
*-- BaseClass:    grid
*-- Time Stamp:   05/04/08 12:20:03 PM
*
DEFINE CLASS grid_color AS grid


	ColumnCount = - 1 
	Anchor =  0 
	DeleteMark = .F.
	Height =  200 
	Width =  320 
	*-- nRecno
	nrecno =  1 
	selectstringsource = ""
	Name = "grid_color"



	*-- Метод, для массового выделения строк
	PROCEDURE selectstring
		LPARAMETERS lcSelectString
		*По определенному полю, имя которого передается в д-ый метод выделяются строки 
		*для своеобразного мультиселекта.
		*если в поле стоит  1  - красный цвет шрифта, а если к тому же данная стока в фокусе - тогда
		*текст выделяется жирным шрифтом. 
		*Если  0  (по умолчанию) или любая другая цифра - цвет шрифта остается черным.

		*Возвращает:
		*   0  - если не передан параметр
		* - 1  - если не верно узнан параметр (не существует такого поля)
		* - 2  - если произошла другая ошибка
		*   1  - если удачно установлено свойство мультиселект в гриде
		LOCAL lnError
		lnError= 0 
		ON ERROR lnError=ERROR()
		IF TYPE(lcSelectString)='L' &&параметр не передан
			ON ERROR 
			RETURN  0  
		ENDIF 
		IF TYPE(lcSelectString)='N' &&Если таблица.поле существует и тип Num
			this.SetAll("DynamicForeColor","IIF(&lcSelectString=1, RGB(255,0,0),RGB(0,0,0))", "column")
			*Отмеченную выделенную строку (lcSelectString= 1 ) красным цветом
			this.SetAll("DynamicFontBold","IIF(&lcSelectString=1 and RECNO()=this.nrecno, .T., .F.)", "column")
			*Отмечею строку жирным, которая выделена (lcSelectString= 1 ) и находиться в фокусе
			IF lnError= 0 
				ON ERROR 
				this.selectstringsource=lcSelectString
				RETURN  1 
			ELSE 
				ON ERROR 
				RETURN - 2 
			ENDIF 
		ELSE 
			ON ERROR 
			RETURN - 1 
		ENDIF 
	ENDPROC


	PROCEDURE MouseDown
		LPARAMETERS nButton, nShift, nXCoord, nYCoord
		IF !EMPTY(this.selectstringsource) AND nButton= 1 
			this.KeyPress( 0 ,nShift)
		ENDIF 
	ENDPROC


	PROCEDURE KeyPress
		LPARAMETERS nKeyCode, nShiftAltCtrl
		IF !EMPTY(this.selectstringsource)
			LOCAL lcTableName, lcFieldName
			lcTableName=LEFT(this.selectstringsource,AT('.', this.selectstringsource)- 1 )
			lcFieldName=RIGHT(this.selectstringsource, LEN(this.selectstringsource)-AT('.', this.selectstringsource))
			DO CASE 
				CASE m.nKeyCode= 22 
					NODEFAULT
					replace &lcFieldName WITH ABS(&lcFieldName - 1 ) IN &lcTableName
					KEYBOARD '{DNARROW}'  PLAIN CLEAR 
				CASE m.nKeyCode= 50  AND m.nShiftAltCtrl= 1 
					replace &lcFieldName WITH ABS(&lcFieldName - 1 ) IN &lcTableName
					KEYBOARD '{DNARROW}'  PLAIN CLEAR 
				CASE m.nKeyCode= 56  AND m.nShiftAltCtrl= 1 
					replace &lcFieldName WITH ABS(&lcFieldName - 1 ) IN &lcTableName
					KEYBOARD '{UPARROW}'  PLAIN CLEAR 
				CASE m.nKeyCode= 0  AND m.nShiftAltCtrl= 2  &&из MouseDown передается  0  + nShiftAltCtrl( 1 -Shift,  2 -Ctrl)
					replace &lcFieldName WITH ABS(&lcFieldName - 1 ) IN &lcTableName
				CASE m.nKeyCode= 0  AND m.nShiftAltCtrl= 1  &&из MouseDown передается  0  + nShiftAltCtrl( 1 -Shift,  2 -Ctrl)
					lnRecnoEnd=RECNO(lcTableName)
					SELECT MIN(nRecno) FROM (SELECT RECNO() as nRecno , &lcFieldName FROM &lcTableName) c1 ;
					WHERE &lcFieldName= 1  GROUP BY &lcFieldName HAVING MIN(nRecno)>lnRecnoEnd INTO ARRAY a_SelectString
					IF TYPE('a_selectString(1)')<>'N'
						SELECT MAX(nRecno) FROM (SELECT RECNO() as nRecno , &lcFieldName FROM &lcTableName) c1 ;
						WHERE &lcFieldName= 1  GROUP BY &lcFieldName HAVING MAX(nRecno)<lnRecnoEnd INTO ARRAY a_SelectString
					ENDIF 
					IF TYPE('a_selectString(1)')='N'
						lcCondition=IIF(lnRecnoEnd<a_selectString( 1 ),'BETWEEN(RECNO(),lnRecnoEnd,a_selectString(1))',;
																	'BETWEEN(RECNO(),a_selectString(1), lnRecnoEnd)')
						UPDATE &lcTableName SET &lcFieldName= 1  WHERE &lcCondition
						GO lnRecnoEnd IN &lcTableName
					ENDIF 
					DIMENSION a_selectString( 1 )
					RELEASE a_selectString
			ENDCASE 
		ENDIF
	ENDPROC


	PROCEDURE Init
		this.nrecno=RECNO()
		this.SetAll("DynamicBackColor" , ;
			" IIF(DELETED()=.T., RGB(129,129,129), IIF(RECNO()=this.nrecno, RGB(215,235,255), RGB(255,255,255)))" , "Column")
		*Выделяется синим цветом активная строка и серым строка помеченная на удаление
		FOR k= 1  TO this.ColumnCount
			this.Columns(k).Header1.Alignment= 2 
			this.Columns(k).Header1.FontBold=.t.
		ENDFOR 
		*Заголовк столбца, выравнивание по центру жирным шрифтом.
		LOCAL lcControl
		FOR k= 1  TO this.ColumnCount
			lcControl=this.Columns(k).currentControl
			BINDEVENT(this.Columns(k).&lcControl, "keyPress", this, "KeyPress")
			BINDEVENT(this.Columns(k).&lcControl, "MouseDown", this, "MouseDown")
		ENDFOR 
		*Не забудь прописать 'dodefault()' если добавляешь новый метод!!! 
	ENDPROC


	PROCEDURE AfterRowColChange
		LPARAMETERS nColIndex
		this.nrecno=RECNO()
		this.Refresh()
		*Не забудь прописать 'dodefault()' если добавляешь новый метод!!! 
	ENDPROC


	PROCEDURE Refresh
		this.nrecno=RECNO()
	ENDPROC


ENDDEFINE
*
*-- EndDefine: grid_color
**************************************************