program project1;

{$IFDEF FPC}
  {$MODE objfpc}{$H+}
{$ENDIF}

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  crt, Classes, sysutils, BaseUnix, dynlibs;

//////////////////////////////////////////
/// FIREBIRD
//////////////////////////////////////////
const
  isc_dpb_version1 = 1;
  isc_dpb_user_name = 28;
  isc_dpb_password = 29;
  isc_dpb_sql_role_name = 60;
  isc_dpb_lc_ctype = 48;

type
  ISC_STATUS    = ptrint;
  UInt                 = DWord;
  Int                  = LongInt;
  PISC_STATUS = ^ISC_STATUS;
  FB_API_HANDLE = pointer;
  isc_db_handle   = FB_API_HANDLE;
  pisc_db_handle  =^isc_db_handle ;

var
  FSQLDatabaseHandle     : pointer;
  FStatus                : array [0..19] of ISC_STATUS;
  LibHandle : TLibHandle;

  fb_shutdown : function(_para1: UINT; _para2: integer):int; cdecl;
  isc_attach_database : function (_para1:PISC_STATUS; _para2:smallint; _para3:Pchar; _para4:Pisc_db_handle; _para5:smallint;_para6:Pchar):ISC_STATUS; cdecl;
  isc_detach_database : function (_para1:PISC_STATUS; _para2:Pisc_db_handle):ISC_STATUS; cdecl;

Function TryInitialiseIBase60(Const LibraryName : AnsiString) : Boolean;
begin
  Result := False;
  LibHandle := LoadLibrary(LibraryName);
  if LibHandle = nilhandle then
    Exit;
  pointer(fb_shutdown) := GetProcedureAddress(LibHandle,'fb_shutdown');
  pointer(isc_attach_database) := GetProcedureAddress(LibHandle,'isc_attach_database');
  pointer(isc_detach_database) := GetProcedureAddress(LibHandle,'isc_detach_database');
  Result := True;
end;

Procedure ReleaseIBase60;
begin
  if LibHandle <> NilHandle then
  begin
    // Shutdown embedded subsystem with timeout 300ms (Firebird 2.5+)
    // Required before unloading library; has no effect on non-embedded client
    if (pointer(fb_shutdown)<>nil) and (fb_shutdown(300,1)<>0) then
    begin
     //todo: log error; still try to unload library below as the timeout may have been insufficient
    end;
    if UnloadLibrary(LibHandle) then
      LibHandle := NilHandle;
  end;
end;

procedure ConnectFB(const UserName, Password, Role, CharSet, HostName, DatabaseName: string);
var
  ADatabaseName: String;
  DPB: string;
begin
  DPB := chr(isc_dpb_version1);
  if (UserName <> '') then
  begin
    DPB := DPB + chr(isc_dpb_user_name) + chr(Length(UserName)) + UserName;
    if (Password <> '') then
      DPB := DPB + chr(isc_dpb_password) + chr(Length(Password)) + Password;
  end;
  if (Role <> '') then
     DPB := DPB + chr(isc_dpb_sql_role_name) + chr(Length(Role)) + Role;
  if Length(CharSet) > 0 then
    DPB := DPB + Chr(isc_dpb_lc_ctype) + Chr(Length(CharSet)) + CharSet;

  FSQLDatabaseHandle := nil;
  if HostName <> '' then
    ADatabaseName := HostName+':'+DatabaseName
  else
    ADatabaseName := DatabaseName;
  if isc_attach_database(@FStatus[0], Length(ADatabaseName), @ADatabaseName[1],
       @FSQLDatabaseHandle, Length(DPB), @DPB[1]) <> 0 then
    if ((FStatus[0] = 1) and (FStatus[1] <> 0)) then
      WriteLn('ConnectFB ErrorCode ', FStatus[1]);
end;

procedure DisconnectFB;
begin
  if isc_detach_database(@FStatus[0], @FSQLDatabaseHandle) <> 0 then
    if ((FStatus[0] = 1) and (FStatus[1] <> 0)) then
      WriteLn('DisconnectFB ErrorCode ', FStatus[1]);
end;

//////////////////////////////////////////
/// SIG HANDLER
//////////////////////////////////////////
var
  terminated: boolean = False;
  new_act_term, new_act_int, new_act_hup, old_act: SigActionRec;

procedure DoSig(signal: longint; info: psiginfo; context: psigcontext); cdecl;
begin
  terminated := True;
end;

procedure SetSigHadnler(const Sig: cint; const new, old: PSigActionRec; const Handler: SigActionHandler);
begin
  new^.sa_handler := Handler;
  fillchar(new^.Sa_Mask, SizeOf(new^.sa_mask), #0);
  new^.sa_flags := 0;
  {$ifdef Linux}               // Linux specific
  new^.Sa_Restorer := nil;
  {$endif}
  fpSigAction(Sig, new, old);
end;

//////////////////////////////////////////
/// MAIN
//////////////////////////////////////////
const
  OS_USER_NAME = ;
begin
  SetSigHadnler(SIGTERM, @new_act_term, @old_act, @DoSig);
  SetSigHadnler(SIGINT, @new_act_int, @old_act, @DoSig);
  SetSigHadnler(SIGHUP, @new_act_hup, @old_act, @DoSig);

  {$if declared(UseHeapTrace)}
  GlobalSkipIfNoLeaks := True; // supported as of debugger version 3.1.1
  {$endif}

  if not TryInitialiseIBase60('libfbclient.so') then
  begin
    WriteLn('ibase lib init failed');
    exit;
  end;
  connectFB('SYSDBA', 'masterkey', '', 'UTF8', '127.0.0.1', '/home/' + OS_USER_NAME + '/EMPLOYEE.FDB');
  if not Assigned(FSQLDatabaseHandle) then
  begin
    WriteLn('db connect failed');
    exit;
  end;

  writeln('start PID:', FpGetPID, '..');
  while not terminated do
  begin
    sleep(250);
    if KeyPressed then
      if ReadKey = ^C then
      begin
        writeln('Ctrl-C pressed');
        Break;
      end;
  end;
  if terminated then
    writeln('terminated');
  writeln('..stop');

  try
    DisconnectFB;
    ReleaseIBase60;
  except
    writeln('exception occured!');
  end;
  writeln('end');
end.