function TSQLParams.Parse(const SQL: UnicodeString): UnicodeString;
  const
    Identifiers: set of AnsiChar = ['a'..'z', 'A'..'Z', '0'..'9', '_', '$'];
  var
    Src: PWideChar;
    Dest, idlen: Word;

    procedure next;
    begin
      inc(dest);
      Result[dest] := WideChar(Src^);
      inc(Src);
    end;

    procedure Skip(c: WideChar);
    begin
      repeat
        next;
        if Src^ = c then
        begin
          Next;
          Break;
        end;
      until (Src^ = #0);
    end;

    {$IFDEF FPC}
    function PrevChar(c: PWideChar): WideChar;
    begin
      dec(c);
      result := c^;
    end;
    {$ENDIF}
  begin
    Clear;
    Src := PWideChar(SQL);
    Dest := 0;
    SetLength(Result, Length(SQL));
    while true do
      case Src^ of
        // eof
        #0 :  begin
                SetLength(Result, Dest);
                Exit;
              end;
        // normal comments
        '/' : if Src[1] = '*' then
              begin
                inc(Src, 2);
                while (Src^ <> #0) do
                  if (Src^ = '*') and (Src[1] = '/') then
                  begin
                    inc(Src, 2);
                    Break;
                  end else
                    inc(Src);
              end else
                next;
        // Firebird comments -- My comment + (eol or eof)
        {.$IFDEF FB15_UP}
        '-' : if Src[1] = '-' then
              begin
                inc(Src, 2);
                while not ({$IFDEF UNICODE}(Src^ < #256) and {$ENDIF}(AnsiChar(Src^) in [#0, #13, #10])) do
                  inc(Src);
              end else
                next;
        {.$ENDIF}
        // text ''
        '''': Skip('''');
        // text ""
        '"' : Skip('"');
        // Unnamed Input
        '?' : begin
                AddField('');
                Next;
              end;
        '[' : Skip(']');
        // Named Input
        ':' : begin
                inc(dest);
                Result[dest] := '?';
                inc(Src);
                idlen := 0;
                // quoted identifiers
                if Src[idlen] = '"' then
                begin
                  inc(Src);
                  while true do
                    if {$IFDEF UNICODE}(Src[idlen] < #256) and {$ENDIF}(AnsiChar(Src[idlen]) in [#0, '"']) then
                      Break else
                      inc(idlen);
                end else
                // unquoted identifiers
                  while {$IFDEF UNICODE}(Src[idlen] < #256) and {$ENDIF}(AnsiChar(Src[idlen]) in Identifiers) do inc(idlen);
                AddField(copy(Src, 1, idlen));
                inc(Src, idlen);
                if Src^ = '"' then inc(Src);
              end;
        // skip everything when begin identifier found !
        // in procedures
        'b','B':
          begin
            if not ((dest > 0) and {$IFDEF UNICODE}(src[-1] < #256) and {$ENDIF} ({$IFDEF FPC}PrevChar(src){$ELSE}AnsiChar(src[-1]){$ENDIF}
              in Identifiers)) and (StrIComp(PWideChar(copy(Src, 0, 5)), 'begin') = 0) and
                not ({$IFDEF UNICODE}(Src[5] < #256) and{$ENDIF}(AnsiChar(Src[5]) in Identifiers)) then
                  while (Src^ <> #0) do Next else next;
          end;
        // declare should also stop param parsing, as a declare cursor statement
        // may contain variables.
        'd','D':
          begin
            if not ((dest > 0) and {$IFDEF UNICODE}(src[-1] < #256) and {$ENDIF} ({$IFDEF FPC}PrevChar(src){$ELSE}AnsiChar(src[-1]){$ENDIF}
              in Identifiers)) and (StrIComp(PWideChar(copy(Src, 0, 7)), 'declare') = 0) and
                not ({$IFDEF UNICODE} (Src[7] < #256) and {$ENDIF}(AnsiChar(Src[7]) in Identifiers)) then
                  while (Src^ <> #0) do Next else next;
          end;
      else
        next;
      end;
  end;

EXECUTE BLOCK(NAME VARCHAR(20) = :NAME1)
RETURNS(
  RNAME CHAR(31)
)AS
  DECLARE C CURSOR FOR (SELECT RDB$RELATION_NAME FROM RDB$RELATIONS where RDB$RELATION_NAME <> :NAME);
BEGIN
  OPEN C;
  FETCH C INTO :RNAME;
  WHILE (ROW_COUNT > 0) DO
  BEGIN
    SUSPEND;
    FETCH C INTO :RNAME;
  END
  CLOSE C;
END

EXECUTE BLOCK(NAME VARCHAR(20) = :NAME1)
RETURNS(
  RNAME CHAR(31)
)AS
VAR
  P1 INTEGER;
  P2 INTEGER;
  P3 CURSOR FOR (SELECT RDB$RELATION_NAME FROM RDB$RELATIONS where RDB$RELATION_NAME <> :Name);
BEGIN
END