FUNCTION NumberToStrRUS(pNumber IN NUMBER, pIntZeroLead IN NUMBER DEFAULT 0, pIntKind IN NUMBER DEFAULT 0
                        , pIntEdIzm0 IN VARCHAR2 DEFAULT NULL, pIntEdIzm1 IN VARCHAR2 DEFAULT NULL, pIntEdIzm2 IN VARCHAR2 DEFAULT NULL
                        , pModZeroTrail IN NUMBER DEFAULT 0, pModKind IN NUMBER DEFAULT 0
                        , pModEdIzm0 IN VARCHAR2 DEFAULT NULL, pModEdIzm1 IN VARCHAR2 DEFAULT NULL, pModEdIzm2 IN VARCHAR2 DEFAULT NULL
                        , pModCap IN NUMBER DEFAULT 0) RETURN VARCHAR2 DETERMINISTIC IS
    erIntToBig    CONSTANT PLS_INTEGER := -20000;
    erModToBig    CONSTANT PLS_INTEGER := -20001;
    nNumber       NUMBER;
    sbufInt       VARCHAR2(37);
    sbufMod       VARCHAR2(38);
    sNumb         VARCHAR2(29);
    sPow          VARCHAR2(15);
    sFract        VARCHAR2(10);
    sIntRez       VARCHAR2(4000) := '';
    sModRez       VARCHAR2(4000) := '';
    Tr1           VARCHAR(1);
    Tr2           VARCHAR(1);
    Tr3           VARCHAR(1);
    iexp          PLS_INTEGER;
    iposGr        PLS_INTEGER;
    ilenMod       PLS_INTEGER;
    iIntKind      PLS_INTEGER; -- род целой части: 0 - мужской, 1 - женский, 2 - средний
    iModKind      PLS_INTEGER; -- род дробной части
    bIntIsZero    BOOLEAN := FALSE; -- Целая часть = 0
    bModIsZero    BOOLEAN := FALSE; -- Дробная часть = 0
    bIntPrint     BOOLEAN; -- Выводить целую часть
    bModPrint     BOOLEAN; -- Выводить дробную часть
    iIntSufEdIzm  PLS_INTEGER; -- Окончание единиц измерения целой части, принимает значения: 0, 1, 2
    iModSufEdIzm  PLS_INTEGER; -- Окончание единиц измерения дробной части, принимает значения: 0, 1, 2
    sIntEdIzm     VARCHAR2(20);
    sModEdIzm     VARCHAR2(20);
BEGIN
    -- обработка целой части
    IF pNumber IS NULL THEN RETURN NULL; END IF;

    sbufInt := to_char(abs(trunc(pNumber)),'fm999999999999999999999999999999999999', 'NLS_NUMERIC_CHARACTERS = ''. ''');
    IF substr(sbufInt, 1, 1) = '#' THEN raise_application_error(erIntToBig, 'Число слишком большое'); END IF;
    --ilenInt := LENGTH(sbufInt);
    IF sbufInt = '0' THEN
        sIntRez := ' ноль';
        sFract := ' целых';
        iIntSufEdIzm := 0;
        bIntIsZero := TRUE;
    END IF;
    IF pModCap > 0 THEN nNumber := ROUND(pNumber, pModCap); ELSE nNumber := pNumber; END IF;
    sbufMod := to_char(abs(nNumber-trunc(nNumber)),rpad(rpad('fmD', 3+pModCap, '0'), 39, '9'), 'NLS_NUMERIC_CHARACTERS = ''. ''');
    IF substr(sbufMod, 1, 1) = '#' THEN raise_application_error(erModToBig, 'Cлишком длинная дробная часть'); END IF;
    sbufMod := substr(sbufMod, 2);
    ilenMod := LENGTH(sbufMod);
    IF nNumber-trunc(nNumber) = 0 THEN
        sModRez := ' ноль';
        ilenMod := 1;
        iModSufEdIzm := 0;
        bModIsZero := TRUE;
    END IF;

    iIntKind := pIntKind;
    iModKind := pModKind;

    IF pModEdIzm1 IS NULL AND NOT bModIsZero THEN iIntKind := 1; iModKind := 1; END IF; -- меняем пол на женский один килограмм, но одна целая две десятых килограмма

    bIntPrint := NOT bIntIsZero OR pIntZeroLead <> 0 OR bModIsZero/* OR pModEdIzm1 IS NULL*/;
    bModPrint := NOT bModIsZero OR pModZeroTrail <> 0;

    iexp := 0;
    IF NOT bIntIsZero THEN
        <<RazrLoop>>
        LOOP
            sNumb := '';
            iposGr := -iexp * 3;
            Tr3 := substr(sbufInt, iposGr - 1, 1);
            Tr2 := nvl(substr(sbufInt, iposGr - 2, 1), '0');
            Tr1 := nvl(substr(sbufInt, iposGr - 3, 1), '0');
            EXIT RazrLoop WHEN Tr3 IS NULL;
            Tr3 := nvl(Tr3, '0');
            -- обработка первой цифры
            CASE Tr1
                WHEN '0' THEN NULL;
                WHEN '1' THEN sNumb := sNumb||' сто';
                WHEN '2' THEN sNumb := sNumb||' двести';
                WHEN '3' THEN sNumb := sNumb||' триста';
                WHEN '4' THEN sNumb := sNumb||' четыреста';
                WHEN '5' THEN sNumb := sNumb||' пятьсот';
                WHEN '6' THEN sNumb := sNumb||' шестьсот';
                WHEN '7' THEN sNumb := sNumb||' семьсот';
                WHEN '8' THEN sNumb := sNumb||' восемьсот';
                WHEN '9' THEN sNumb := sNumb||' девятьсот';
                ELSE NULL;
            END CASE;
            -- обработка второй цифры
            CASE Tr2
                WHEN '0' THEN NULL;
                WHEN '1' THEN
                            CASE Tr3
                                WHEN '0' THEN sNumb := sNumb||' десять';
                                WHEN '1' THEN sNumb := sNumb||' одиннадцать';
                                WHEN '2' THEN sNumb := sNumb||' двеннадцать';
                                WHEN '3' THEN sNumb := sNumb||' тринадцать';
                                WHEN '4' THEN sNumb := sNumb||' четырнадцать';
                                WHEN '5' THEN sNumb := sNumb||' пятнадцать';
                                WHEN '6' THEN sNumb := sNumb||' шестнадцать';
                                WHEN '7' THEN sNumb := sNumb||' семнадцать';
                                WHEN '8' THEN sNumb := sNumb||' восемнадцать';
                                WHEN '9' THEN sNumb := sNumb||' девятнадцать';
                                ELSE NULL;
                            END CASE;
                WHEN '2' THEN sNumb := sNumb||' двадцать';
                WHEN '3' THEN sNumb := sNumb||' тридцать';
                WHEN '4' THEN sNumb := sNumb||' сорок';
                WHEN '5' THEN sNumb := sNumb||' пятьдесят';
                WHEN '6' THEN sNumb := sNumb||' шестьдесят';
                WHEN '7' THEN sNumb := sNumb||' семьдесят';
                WHEN '8' THEN sNumb := sNumb||' восемьдесят';
                WHEN '9' THEN sNumb := sNumb||' девяносто';
                ELSE NULL;
            END CASE;
            -- обработка 3 цифры
            IF Tr2 != '1' THEN
                CASE Tr3
                    WHEN '0' THEN NULL;
                    WHEN '1' THEN
                                CASE iexp
                                    WHEN 0 THEN
                                              CASE iIntKind
                                                  WHEN 1 THEN sNumb := sNumb||' одна';
                                                  WHEN 2 THEN sNumb := sNumb||' одно';
                                                  ELSE sNumb := sNumb||' один';
                                              END CASE;
                                    WHEN 1 THEN sNumb := sNumb||' одна';
                                    ELSE sNumb := sNumb||' один';
                                END CASE;
                    WHEN '2' THEN
                                CASE iexp
                                    WHEN 0 THEN
                                              CASE iIntKind
                                                  WHEN 1 THEN sNumb := sNumb||' две';
                                                  ELSE sNumb := sNumb||' два';
                                              END CASE;
                                    WHEN 1 THEN sNumb := sNumb||' две';
                                    ELSE sNumb := sNumb||' два';
                                END CASE;
                    WHEN '3' THEN sNumb := sNumb||' три';
                    WHEN '4' THEN sNumb := sNumb||' четыре';
                    WHEN '5' THEN sNumb := sNumb||' пять';
                    WHEN '6' THEN sNumb := sNumb||' шесть';
                    WHEN '7' THEN sNumb := sNumb||' семь';
                    WHEN '8' THEN sNumb := sNumb||' восемь';
                    WHEN '9' THEN sNumb := sNumb||' девять';
                    ELSE NULL;
                END CASE;
            END IF; -- Tr2 != '1'

            sPow := '';
            IF sNumb IS NOT NULL THEN
                IF iexp BETWEEN 2 AND 11 THEN
                    CASE iexp
                        WHEN 11 THEN sPow := ' декалион';
                        WHEN 10 THEN sPow := ' ноналион';
                        WHEN 9 THEN sPow := ' окталион';
                        WHEN 8 THEN sPow := ' септилион';
                        WHEN 7 THEN sPow := ' секстилион';
                        WHEN 6 THEN sPow := ' квинтилион';
                        WHEN 5 THEN sPow := ' квадрилион';
                        WHEN 4 THEN sPow := ' трилион';
                        WHEN 3 THEN sPow := ' миллиард';
                        WHEN 2 THEN sPow := ' миллион';
                        ELSE NULL;
                    END CASE;

                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN sPow := sPow || 'ов'; -- XX0, XX5-XX9, X11-X19
                        WHEN Tr3 = '1' THEN NULL; -- XX1 кроме X11
                        WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := sPow || 'а'; -- XX2-XX4 кроме X1X
                        ELSE NULL;
                    END CASE;
                END IF; -- IF iexp BETWEEN 2 AND 11 THEN

                --тысячи
                IF iexp = 1 THEN
                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN sPow := ' тысяч';
                        WHEN Tr3 = '1' THEN sPow := ' тысяча';
                        WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := ' тысячи';
                        ELSE NULL;
                    END CASE;
                END IF; -- IF iexp = 1 THEN

                --единицы
                IF iexp = 0 THEN
                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN sFract := ' целых'; iIntSufEdIzm := 0;
                        WHEN Tr3 = '1' THEN sFract := ' целая'; iIntSufEdIzm := 1;
                        --WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := ' тысячи';
                        ELSE sFract := ' целые'; iIntSufEdIzm := 2;
                    END CASE;
                END IF; -- IF iexp = 0 THEN
            END IF; -- IF sNumb IS NOT NULL
            sIntRez := sNumb || sPow || sIntRez;

            iexp := iexp + 1;
        END LOOP RazrLoop;
    END IF; -- sbuf = '0' else
    -- конец обработки целых

    -- обработка дробной части
    iexp := 0;
    IF NOT bModIsZero THEN
        <<ModLoop>>
        LOOP
            sNumb := '';
            iposGr := -iexp * 3;
            Tr3 := substr(sbufMod, iposGr - 1, 1);
            Tr2 := nvl(substr(sbufMod, iposGr - 2, 1), '0');
            Tr1 := nvl(substr(sbufMod, iposGr - 3, 1), '0');
            EXIT ModLoop WHEN Tr3 IS NULL;
            Tr3 := nvl(Tr3, '0');
            -- обработка первой цифры
            CASE Tr1
                WHEN '0' THEN NULL;
                WHEN '1' THEN sNumb := sNumb||' сто';
                WHEN '2' THEN sNumb := sNumb||' двести';
                WHEN '3' THEN sNumb := sNumb||' триста';
                WHEN '4' THEN sNumb := sNumb||' четыреста';
                WHEN '5' THEN sNumb := sNumb||' пятьсот';
                WHEN '6' THEN sNumb := sNumb||' шестьсот';
                WHEN '7' THEN sNumb := sNumb||' семьсот';
                WHEN '8' THEN sNumb := sNumb||' восемьсот';
                WHEN '9' THEN sNumb := sNumb||' девятьсот';
                ELSE NULL;
            END CASE;
            -- обработка второй цифры
            CASE Tr2
                WHEN '0' THEN NULL;
                WHEN '1' THEN
                            CASE Tr3
                                WHEN '0' THEN sNumb := sNumb||' десять';
                                WHEN '1' THEN sNumb := sNumb||' одиннадцать';
                                WHEN '2' THEN sNumb := sNumb||' двеннадцать';
                                WHEN '3' THEN sNumb := sNumb||' тринадцать';
                                WHEN '4' THEN sNumb := sNumb||' четырнадцать';
                                WHEN '5' THEN sNumb := sNumb||' пятнадцать';
                                WHEN '6' THEN sNumb := sNumb||' шестнадцать';
                                WHEN '7' THEN sNumb := sNumb||' семнадцать';
                                WHEN '8' THEN sNumb := sNumb||' восемнадцать';
                                WHEN '9' THEN sNumb := sNumb||' девятнадцать';
                                ELSE NULL;
                            END CASE;
                WHEN '2' THEN sNumb := sNumb||' двадцать';
                WHEN '3' THEN sNumb := sNumb||' тридцать';
                WHEN '4' THEN sNumb := sNumb||' сорок';
                WHEN '5' THEN sNumb := sNumb||' пятьдесят';
                WHEN '6' THEN sNumb := sNumb||' шестьдесят';
                WHEN '7' THEN sNumb := sNumb||' семьдесят';
                WHEN '8' THEN sNumb := sNumb||' восемьдесят';
                WHEN '9' THEN sNumb := sNumb||' девяносто';
                ELSE NULL;
            END CASE;
            -- обработка 3 цифры
            IF Tr2 != '1' THEN
                CASE Tr3
                    WHEN '0' THEN NULL;
                    WHEN '1' THEN
                                CASE iexp
                                    WHEN 0 THEN
                                              CASE iModKind
                                                  WHEN 1 THEN sNumb := sNumb||' одна';
                                                  WHEN 2 THEN sNumb := sNumb||' одно';
                                                  ELSE sNumb := sNumb||' один';
                                              END CASE;
                                    WHEN 1 THEN sNumb := sNumb||' одна';
                                    ELSE sNumb := sNumb||' один';
                                END CASE;
                    WHEN '2' THEN
                                CASE iexp
                                    WHEN 0 THEN
                                              CASE iModKind
                                                  WHEN 1 THEN sNumb := sNumb||' две';
                                                  ELSE sNumb := sNumb||' два';
                                              END CASE;
                                    WHEN 1 THEN sNumb := sNumb||' две';
                                    ELSE sNumb := sNumb||' два';
                                END CASE;
                    WHEN '3' THEN sNumb := sNumb||' три';
                    WHEN '4' THEN sNumb := sNumb||' четыре';
                    WHEN '5' THEN sNumb := sNumb||' пять';
                    WHEN '6' THEN sNumb := sNumb||' шесть';
                    WHEN '7' THEN sNumb := sNumb||' семь';
                    WHEN '8' THEN sNumb := sNumb||' восемь';
                    WHEN '9' THEN sNumb := sNumb||' девять';
                    ELSE NULL;
                END CASE;
            END IF; -- Tr2 != '1'

            sPow := '';
            IF sNumb IS NOT NULL THEN
                IF iexp BETWEEN 2 AND 11 THEN
                    CASE iexp
                        WHEN 11 THEN sPow := ' декалион';
                        WHEN 10 THEN sPow := ' ноналион';
                        WHEN 9 THEN sPow := ' окталион';
                        WHEN 8 THEN sPow := ' септилион';
                        WHEN 7 THEN sPow := ' секстилион';
                        WHEN 6 THEN sPow := ' квинтилион';
                        WHEN 5 THEN sPow := ' квадрилион';
                        WHEN 4 THEN sPow := ' трилион';
                        WHEN 3 THEN sPow := ' миллиард';
                        WHEN 2 THEN sPow := ' миллион';
                        ELSE NULL;
                    END CASE;

                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN sPow := sPow || 'ов'; -- XX0, XX5-XX9, X11-X19
                        WHEN Tr3 = '1' THEN NULL; -- XX1 кроме X11
                        WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := sPow || 'а'; -- XX2-XX4 кроме X1X
                        ELSE NULL;
                    END CASE;
                END IF; -- IF iexp BETWEEN 2 AND 11 THEN

                --тысячи
                IF iexp = 1 THEN
                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN sPow := ' тысяч';
                        WHEN Tr3 = '1' THEN sPow := ' тысяча';
                        WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := ' тысячи';
                        ELSE NULL;
                    END CASE;
                END IF; -- IF iexp = 1 THEN
                --единицы
                IF iexp = 0 THEN
                    CASE
                        WHEN (Tr3 = '0') OR (Tr3 BETWEEN '5' AND '9') OR (Tr2 = '1') THEN iModSufEdIzm := 0;
                        WHEN Tr3 = '1' THEN iModSufEdIzm := 1;
                        --WHEN Tr3 BETWEEN '2' AND '4' THEN sPow := ' тысячи';
                        ELSE  iModSufEdIzm := 2;
                    END CASE;
                END IF; -- IF iexp = 0 THEN
            END IF; -- IF sNumb IS NOT NULL
            sModRez := sNumb || sPow || sModRez;

            iexp := iexp + 1;
        END LOOP ModLoop;
    END IF; -- IF NOT bModIsZero THEN
    -- ед. изм.
    CASE ilenMod
        WHEN 1 THEN sPow := ' десят';
        WHEN 2 THEN sPow := ' сот';
        WHEN 3 THEN sPow := ' тысячн';
        WHEN 4 THEN sPow := ' десятитысячн';
        WHEN 5 THEN sPow := ' стотысячн';
        WHEN 6 THEN sPow := ' миллионн';
        WHEN 7 THEN sPow := ' десятимиллионн';
        WHEN 8 THEN sPow := ' стомиллионн';
        WHEN 9 THEN sPow := ' миллиардн';
        WHEN 10 THEN sPow := ' десятимиллиардн';
        WHEN 11 THEN sPow := ' стомиллиардн';
        WHEN 12 THEN sPow := ' трилионн';
        WHEN 13 THEN sPow := ' десятитрилионн';
        WHEN 14 THEN sPow := ' стотрилионн';
        WHEN 15 THEN sPow := ' квадрилионн';
        WHEN 16 THEN sPow := ' десятиквадрилионн';
        WHEN 17 THEN sPow := ' стоквадрилионн';
        WHEN 18 THEN sPow := ' квинтилионн';
        WHEN 19 THEN sPow := ' десятиквинтилионн';
        WHEN 20 THEN sPow := ' стоквинтилионн';
        WHEN 21 THEN sPow := ' секстилионн';
        WHEN 22 THEN sPow := ' десятисекстилионн';
        WHEN 23 THEN sPow := ' стосекстилионн';
        WHEN 24 THEN sPow := ' септилионн';
        WHEN 25 THEN sPow := ' десятисептилионн';
        WHEN 26 THEN sPow := ' стосептилионн';
        WHEN 27 THEN sPow := ' окталионн';
        WHEN 28 THEN sPow := ' десятиокталионн';
        WHEN 29 THEN sPow := ' стоокталионн';
        WHEN 30 THEN sPow := ' ноналионн';
        WHEN 31 THEN sPow := ' десятиноналионн';
        WHEN 32 THEN sPow := ' стононалионн';
        WHEN 33 THEN sPow := ' декалионн';
        WHEN 34 THEN sPow := ' десятидекалионн';
        WHEN 35 THEN sPow := ' стодекалионн';
        ELSE NULL;
    END CASE;

    Tr3 := nvl(Tr3, '0'); -- по NULL мы вышли из цикла

    CASE iModSufEdIzm
        WHEN 0 THEN sPow := sPow || 'ых'; -- XX0, XX5-XX9, X11-X19 {Пять}
        WHEN 1 THEN sPow := sPow || 'ая'; -- XX1 кроме X11 {Одна}
        WHEN 2 THEN sPow := sPow || 'ые'; -- XX2-XX4 кроме X1X {Две}
        ELSE NULL;
    END CASE;
    -- конец обработки дробных

    sIntEdIzm := CASE iIntSufEdIzm
                      WHEN 0 THEN CASE WHEN pIntEdIzm0 IS NULL THEN NULL ELSE ' '||pIntEdIzm0 END
                      WHEN 1 THEN CASE WHEN pIntEdIzm1 IS NULL THEN NULL ELSE ' '||pIntEdIzm1 END
                      ELSE CASE WHEN pIntEdIzm2 IS NULL THEN NULL ELSE ' '||pIntEdIzm2 END
                  END;
    sModEdIzm := CASE iModSufEdIzm
                    WHEN 0 THEN CASE WHEN pModEdIzm0 IS NULL THEN NULL ELSE ' '||pModEdIzm0 END
                    WHEN 1 THEN CASE WHEN pModEdIzm1 IS NULL THEN NULL ELSE ' '||pModEdIzm1 END
                    ELSE CASE WHEN pModEdIzm2 IS NULL THEN NULL ELSE ' '||pModEdIzm2 END
                 END;

    IF NOT bIntPrint THEN sIntRez := ''; sFract := ''; sIntEdIzm := ''; END IF;
    IF NOT bModPrint THEN sModRez := ''; sPow := ''; sModEdIzm := ''; END IF;

    IF pModEdIzm1 IS NULL THEN
        IF NOT bModIsZero OR pModZeroTrail <> 0
            THEN RETURN SUBSTR(sIntRez||sFract||sModRez||sPow||CASE WHEN pIntEdIzm2 IS NULL THEN NULL ELSE ' '||pIntEdIzm2 END ,2); -- 1 целая 5 десятых рубля
            ELSE RETURN SUBSTR(sIntRez||sIntEdIzm, 2);  --  1 рубль
        END IF;
    ELSE -- IF pModEdIzm1 IS NULL
        RETURN SUBSTR(sIntRez||sIntEdIzm||sModRez||sModEdIzm , 2);
    END IF;

END NumberToStrRUS;
---------------------------------------------------------------------------------------
FUNCTION NumberToRUB(pNumber IN NUMBER) RETURN VARCHAR2 DETERMINISTIC AS
BEGIN
    RETURN NumberToStrRUS(pNumber=>pNumber, pIntZeroLead=>1, pIntKind=>0, pIntEdIzm0=>'рублей', pIntEdIzm1=>'рубль', pIntEdIzm2=>'рубля', pModZeroTrail=>1, pModKind=>1, pModEdIzm0=>'копеек', pModEdIzm1=>'копейка', pModEdIzm2=>'копейки', pModCap=>2);
END NumberToRUB;