Class my.test Extends %Persistent
{

Property f As %Integer [ InitialExpression = 5 ];

/// d ##class(my.test).Test()
ClassMethod Test()
{
  #define JSONUpsert(%json) $s(%json."_id"="":$system.OBJ.New(%json."_class"),1:$system.OBJ.OpenId(%json."_class",%json."_id"))
  
  d ..%KillExtent()
  d ..%New().%Save()
  
  s obj1=..%OpenId(1) ; или ..%New()
  
  ; отправляем клиенту JSON-строку
  w "<- f = ",obj1.f,!,"<- json = ",obj1.$toJSON(),!!
  
  ; меняем наш JSON где-то на стороне и получаем его обратно. 
  ; допустим мы получили это
  
  s jsonStr="{""_class"":""my.test"",""_id"":""1"",""f"":3}"
  w "-> json = ",jsonStr,!
  
  ; преобразовываем JSON-строку в JSON-объект
  s json=({}).$fromJSON(jsonStr)
  
  ; создаём или открываем объект нужного типа (и с нужным ID)
  s obj2=$$$JSONUpsert(json)
  ; заполняем его данными из JSON-объекта 
  d json.$compose(obj2)

  ;сохраняем как обычно
  d obj2.%Save()
  k obj2

  w "-> f = ",..%OpenId(1).f
}

/// Дополнительно к встроенному поведению, также присваиваем значения свойствам _class и _id
Method %ToDynamicObject(
  target As %Object = "",
  ignoreUnknown = 0) [ ServerOnly = 1 ]
{
  s:target="" target = {}
  s target."_class" = $classname() 
  s target."_id" = ..%Id()
  d ##super(.target,.ignoreUnknown)
}

}

s db = ##class(%DataModel.Document.Database).$getDatabase()

;удаляем данные от предыдущих тестов
d db.$dropCollection("test")

;получаем коллекцию наших объектов
s coll = db.$getCollection("test")

; сохраняем некий объект в БД
d coll.$insert({"id":1,"поле 1":"значение 1","a":true,"b":null}) 
; вставляем или обновляем другой объект в БД с documentID=2
d coll.$upsert(2,{"id":1,"поле 2":"значение 2","a":false,"b":"null"}) 

; отображаем содержимое нашей коллекции
d coll.$getAll().$toJSON()    

; выбираем один объект, где b is null и отображаем его (здесь вместо JSON Path Language можно использовать "обычный" SQL)
s rset=coll.$queryCollection(
        {"columns":[{"column":"b","path":"$.b"}],
         "restriction":"b is null",
         "limit":1})
w !!,"1)",!,rset.$toJSON()

; открываем объект c documentID=2 и отображаем его
s obj=coll.$get(2)
w !!,"2) ",obj.$toJSON(),!!

; меняем объект (можем добавить новые поля или удалить уже существующие)
s obj."новое поле 1"="новое значение 1"
d obj.$remove("id")

; обновляем его в БД
d coll.$replace(2,obj)
; отображаем текущее состояние нашей БД
d coll.$getAll().$toJSON()    

USER>d ^test
[
{"documentID":1,"documentVersion":1,"content":{"id":1,"поле 1":"значение 1","a":true,"b":null}},
{"documentID":2,"documentVersion":2,"content":{"id":1,"a":false,"b":"null","поле 2":"значение 2"}}
]
 
1)
[
{"_sourceID":1,"_sourceVersion":1,"content":{"id":1,"поле 1":"значение 1","a":true,"b":null}}
]
 
2) {"id":1,"a":false,"b":"null","поле 2":"значение 2"}
 
[
{"documentID":1,"documentVersion":1,"content":{"id":1,"поле 1":"значение 1","a":true,"b":null}},
{"documentID":2,"documentVersion":3,"content":{"a":false,"b":"null","поле 2":"значение 2","новое поле 1":"новое значение 1"}}
]