Можете приложить полный пример вашего кода, с вызовом openssl ?

В общем, простого способа отправить подписанное сообщение нет
стандартный %Net.SMTP такое не поддерживает

у тебя есть ошибки в формировании MIME Parts, вот как это работает у меня, сравнивай  SET msg=##class(%Net.MIMEPart).%New()
  set msg.Boundary="NextPart"_$zstrip($random(100000)/17,"<>W")
  SET msg.ContentType="multipart/mixed; boundary="""_msg.Boundary_""""
  
  SET msg1=##class(%Net.MIMEPart).%New()
  set file=##class(%Stream.FileBinary).%New()
  set file.Filename="test.txt"
  set msg1.ContentType="application/octet-stream"
  do msg1.SetHeader("Content-Disposition", "attachment; filename=""test.txt""")
  set msg1.ContentTransferEncoding="base64"
  SET msg1.Body=##class(%Stream.GlobalBinary).%New()
  DO msg1.Body.CopyFrom(file)

  SET msg2=##class(%Net.MIMEPart).%New()
  set msg2.ContentType="text/plain"
  set msg2.ContentCharset="utf-8"
  set msg2.ContentTransferEncoding="7bit"
  SET msg2.Body=##class(%Stream.GlobalCharacter).%New()
  DO msg2.Body.Write("Hello")

  do msg.Parts.Insert(msg2)
  do msg.Parts.Insert(msg1)

  SET writer=##class(%Net.MIMEWriter).%New()
  SET status=writer.OutputToFile("Testtest.txt")
  Set status=writer.WriteMIMEMessage(msg)
с openssl тоже ошибочка вышла, стоял флаг -text, который принимал входящий файл как текстовый и неважно что там уже multipart

d $zf(-1,"openssl smime -sign -in Testtest.txt -signer mail.crt -inkey mail.key -passin pass:laimon -out Testtestsign.txt")

ну и то что у тебя не вышло это отправка сообщений
Возможно это и можно решить на стандартном %Net.SMTP, но мне было проще переопределить один из его методов - SendMessagePart, чтобы в нем вывести полностью как есть результат от opensslClass Net.SMTP Extends %Net.SMTP
{

Method SendMessagePart(msg As %Net.MailMessagePart) [ Internal, Private ]
{
  set mailmsg=msg.Parts.GetAt(1)
  if mailmsg.%IsA("%Stream.Object") {
    do mailmsg.OutputToDevice()
  } else {
    do ##super(msg)
  }
}

}
и собственно сама отправка сообщения, с использованием нашего Net.SMTP  set s=##class(Net.SMTP).%New()
  set s.smtpserver="smtp server"
  set m=##class(%Net.MailMessage).%New()
  set m.From="test@mail.ru"
  do m.To.Insert("test@mail.ru")

  set auth=##class(%Net.Authenticator).%New() ; use default authentication list
  set auth.UserName="userlogin"
  set auth.Password="password"
  set s.authenticator=auth
  
  set m.Subject="Sent by Cache' mail"

  // вот тут добавляем поток на файл полученный от openssl
  SET signedData=##class(%Stream.FileBinary).%New()
  set signedData.Filename="Testtestsign.txt"
  // и он будет выводится как есть в сообщение
  do m.Parts.SetAt(signedData, 1)
  set m.IsMultiPart=0 // важно поставить в 0
  
  set sc=s.Send(m)

KaIIIuct,

Может, я то проверял на 2016.1 версии

Вот кстати, сегодня выложили на community портале выложили проект под Ensemble для такой же цели подписание smime. посмотри может что найдешь интересного

DAiMorВот кстати, сегодня выложили на community портале выложили проект под Ensemble для такой же цели подписание smime. посмотри может что найдешь интересногоПосмотрел внимательней, он там просто файлы с openssl обрабатывает в продукции, без отправки по почте