Код классаClass demo.test [ Abstract ]
{

/// Публичные точки входа, использующиеся при перенаправлении ввода/вывода
ClassMethod redirects() [ Internal, Private, ProcedureBlock = 0 ]
{
wstr(s) d pStream.Write(s) q
wchr(c) d pStream.Write($c(c)) q
wnl d pStream.Write($c(13,10)) q
wff d pStream.Write($c(12)) q
wtab(s) d pStream.Write($j("",s-$x)) q

rstr(len,timeout) q "test"
rchr(timeout) q "-"

  /*
  // этот код нужно менять под Ваши нужды  
rstr(len,timeout)
  n rd,vr,rt
  s vr="rt"
  s rd=##class(%Device).ReDirectIO($$$NO)
  s:$d(len) vr=vr_"#"_len s:$d(timeout) vr=vr_":"_timeout
  r @vr
  s rd=##class(%Device).ReDirectIO(rd)
  s rd=$zu(96,4,$t)
  q rt
  */
}

/// Перенаправляем вывод с терминала в поток, используя публичные точки входа
ClassMethod Write2Stream(Output pStream As %Stream.Object) [ ProcedureBlock = 0 ]
{
  n io
  
  s pStream=##class(%Stream.TmpBinary).%New()

  s io = $io
  u io::("^"_$zn)
  d ##class(%Device).ReDirectIO($$$YES)
  
  d ..MyPackage()
  
  d ##class(%Device).ReDirectIO($$$NO)
  u io
  
  d pStream.Rewind() ##; идём в начало потока
}

/// наш пакет команд
ClassMethod MyPackage()
{
  s str="1+2"
  w "Привет!",!
  w str,"=",@str,!
  r a w a,!
  r *a w a,!
}

ClassMethod Test()
{
  d ..Write2Stream(.stream)
  
  ##; выводим размер потока и его содержимое
  
  w stream.Size,!,stream.Read()
}

}