/// Логин по умолчанию
Parameter DefL = "_user";
/// Пароль по умолчанию
Parameter DefP = "sys";
/// Занимаем свободный слот лицензии
ClassMethod LoginFreeSlot(IsCSP As %Boolean = 0) As %Integer
{
	s $zt = "errLoginFreeSlot"
	s res = 1
	// выходим, если объявлена лишь одна лицензия
	s LicenceCapacity = $System.License.KeyLicenseUnits()
	g:(LicenceCapacity<=1) exitLoginFreeSlot
	// один слот должен быть всегда свободен, иначе не будут порождаться дочерние job-ы
	s MaxConnections = $System.License.MaxConnections() - 1
	// получаем идентификатор текущего пользователя
	s userId = $select(IsCSP:%CSP.Session.LicenseId, 1:$System.License.GetUserId())
	//
	l +^LoginFreeSlot
	s fLock = 1
	// получаем индекс лицензии, если она наша
	s indexUserId = 0
	if (userId [ ..#DefL)
	{
		s ConnectionCount = $System.License.ConnectionCount(userId)
		if (ConnectionCount <= MaxConnections)
		{
		#if 1
			// см. код ниже
			s indexUserId = +$e(userId,$l(..#DefL)+1,$l(userId))
		#else
			// не пересаживаем процесс, если еще есть свободные слоты в текущей лицензии
			s res = ConnectionCount
			g exitLoginFreeSlot
		#endif
		}
	}
	// получаем количество свободных лицензий
	s FreeCapacity = $System.License.LUAvailable() - $g(^Licence("Reserv"),0)
	s flag = $select((FreeCapacity<1):-1, 1:1)
	// ищем свободную лицензию (с минимальным индексом, чтобы пересаживаться на освободившиеся слоты)
	s indexFirstFree = 0
	s i = 1
	f {
		s ConnectionCount = $System.License.ConnectionCount(..#DefL_i)
		if (ConnectionCount < MaxConnections)
		{
			s indexFirstFree = i
			q
		}
		//
		q:($i(i) >= LicenceCapacity)
	}
	// восстанавливаем индекс лицензии, если не нашли более подходящую лицензию
	s:(indexUserId>0) indexFirstFree = $select((indexUserId<indexFirstFree):indexUserId, 1:indexFirstFree)
	// выходим, если не нашли свободную лицензию
	if (indexFirstFree <= 0)
	{
		s res = 0
		g exitLoginFreeSlot
	}
	// формируем идентификатор пользователя
	s userId = ..#DefL_indexFirstFree
	// перекидываем процесс на полученный идентификатор
	s res = $select(IsCSP:%CSP.Session.Login(userId,..#DefP,1), 1:$System.License.Login(userId,..#DefP))
	// возвращаем результат - число соединений на выбранной лицензии
	g exitLoginFreeSlot
	//
errLoginFreeSlot
	s $zt = ""
	s ^zErrorLoginFreeSlot($i(^zErrorLoginFreeSlot)) = $lb($zdt($h,3), $ze)
	s res = 0
	//
exitLoginFreeSlot
	l:($g(fLock,0)) -^LoginFreeSlot
	s fLock = 0
	//
	q res
}