/// Сложная страница, которая сформирует новые xml данные, 
/// запакует их в формат xls, 
/// отдаст пользователю
Class csp.out Extends %CSP.Page {

/// подменим на excel
Parameter CONTENTTYPE = "application/excel";

///Parameter CHARSET не определен, так как будем отдавать Excel


/// "text/html";
/// Пишет файл с данными
/// см. исходный файл : template\xl\worksheets\sheet1.xml
ClassMethod wSheet1() As %String
{
 ;Код ниже просто скопирован из файла шаблона и оставлен как есть
 &html<<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
  <worksheet 
     xmlns="http://schemas.openxmlformats.org/spreadsheetml/2006/main" 
     xmlns:r="http://schemas.openxmlformats.org/officeDocument/2006/relationships">>
     ;<dimension ref="A1:D2"/> - вывод этой строки подавляем, так как данных у нас будет больше
     &html<<sheetViews>
      <sheetView workbookViewId="0">
      <pane xSplit="2" ySplit="1" topLeftCell="C2" activePane="bottomRight" state="frozenSplit"/>
      <selection pane="bottomLeft" activeCell="A2" sqref="A2"/>
      <selection pane="topRight" activeCell="C1" sqref="C1"/>
      <selection pane="bottomRight" activeCell="C2" sqref="C2"/>
     </sheetView>
     </sheetViews>
     <sheetFormatPr defaultRowHeight="12.75"/>
     <cols>
      <col min="1" max="1" width="10" customWidth="1"/>
      <col min="2" max="2" width="8.7109375" customWidth="1"/>
      <col min="3" max="3" width="19.42578125" customWidth="1"/>
      <col min="4" max="4" width="14.28515625" customWidth="1"/>
     </cols>
     <sheetData>>
      
      ;Обратите внимание на описание заголовков колонок 
      ;вместо строковых значений - ссылки справочник в файле sharedStrings.xml
      
      &html<<row r="1" spans="1:4" ht="15.75" thickBot="1">
       <c r="A1" s="1" t="s"><v> 0 </v></c>
       <c r="B1" s="1" t="s"><v> 1 </v></c>
       <c r="C1" s="1" t="s"><v> 2 </v></c>
       <c r="D1" s="1" t="s"><v> 3 </v></c>
      </row>>
      
      /******ДИНАМИЧЕСКАЯ ЧАСТЬ ОТЧЕТА**************/
      d ##class(test.data).%KillExtent() ;каждый раз разный отчет
      d ##class(test.data).Populate( 1000 )
      &sql(Declare rs Cursor For
       Select code,name,amount Into :code,:name,:amount
       From test.data
      ) &sql(Open rs)
      s i= 0 
      for { &sql(Fetch rs) q:SQLCODE
       s i=i+ 1  &html<<row><c><v>#(i)#</v></c>> ;числовые данные отдаем сразу
       
       ;текстовые значения пакуем в инлайн-стринг 
       &html<
            <c t="inlineStr"><is><t>#(code)#</t></is></c>
            <c t="inlineStr"><is><t>#(name)#</t></is></c>
       > 
       ;опять числовые
       &html<<c><v>#(amount)#</v></c>
       </row>>
       
      } &sql(Close rs)
      
    ;дальше снова просто копия из файла шаблона  
    &html<</sheetData>
    <autoFilter ref="A1:D2"/>
     <pageMargins left="0.7" right="0.7" top="0.75" bottom="0.75" header="0.3" footer="0.3"/>
     <pageSetup paperSize="9" orientation="portrait" horizontalDpi="300" verticalDpi="300" r:id="rId1"/>
     </worksheet>
 >
}

/// Перед тем как отдать файл 
/// копируем каталог шаблона во временный каталог
/// в каталог генерим новый файл со своими данными
/// зипуем каталог в файл, выдаем на странице
ClassMethod OnPage() As %Status
{
 ;Определяем абсолютные пути
 s cspPath=$system.CSP.GetFileName(%request.URL) ;csp-приложение
 
 #define FILE ##class(%File)
 s appPath=$$$FILE.GetDirectory(cspPath) ;по нему определили каталог
 s templatePath=appPath_"\Template\" ;предопределенное положение шаблона
  
 ;создаем случайный каталог для отчета
 s ext="xlsx"
 s tempFile=$$$FILE.TempFilename("xlsx") ;будущий архив
 s tempDir=$$$FILE.GetDirectory(tempFile) ;абсолютный путь к временному каталогу
 s var=$$$FILE.GetFilename(tempFile) ;нужна только "случайная" часть от имени временного файла
 s var=$p(var,"."_ext)
 s tempDir=tempDir_var ;абсолютный путь к временному каталогу нового отчета
 
 ;копируем файлы шаблона
 d $$$FILE.CopyDir(templatePath,tempDir, 1 , 1 , 1 ) ;надо бы проверить
 
 ;файл с новыми данными 
 s dataFile=tempDir_"\xl\worksheets\sheet1.xml" ;предопределенное положение файла с данными (см. стандарт)
 ;записываем его 
 open dataFile:"WNUK\UTF8\" ;Открываем для записи - проверить
 use dataFile d ..wSheet1()
 close dataFile
 
 ;архивируем результат
 s zipper=appPath_"zipper\pkzipc.exe" ;путь к архиватору
 s cmd=zipper_" -add -move -attr=all -dir -path=relative -nozip "_tempFile_" "_tempDir_"\*.*"
 ;w "cmd: ",cmd
 d $zf(- 1 ,cmd) ;мне повезет!
 
 ;отдаем на страницу
 s file=$$$FILE.%New(tempFile)
 d file.Open("RU:/TRANSLATE=0")
 d file.OutputToDevice()
 d file.Close() k file
 
 Q $$$OK
}

ClassMethod OnPreHTTP() As %Boolean [ ServerOnly =  1  ] {
 s %response.ContentType = "application/excel"
 d %response.SetHeader("content-disposition","attachment; filename=Report.xlsx")
 Q  1 
}
}