/// Хранимый класс, данные которого будем показывать в jQuery Grid
Class User.jQGridTest Extends (%Persistent, %Populate) {

Property Code As %Integer [ Required ];
Index CodeIDX On Code [ Unique ];
Property Name As %String [ Required ];
Property Description As %String;

/// Класс будет отдавать свои данные в js
ClassMethod wJS(str As %String) As %Status {
 w ##class(%CSP.Page).QuoteJS(str) Q $$$OK
}

/// Выгрузить объект в формате JSON
ClassMethod wJSON(id As %String) As %Status {
	if '..%ExistsId(id) w "{id:''}" Q $$$ERROR(10001,"id:"_id_" not exists")
	s code=..CodeGetStored(id), name=..NameGetStored(id)
	  , desc=..DescriptionGetStored(id)
	w "{id:" d ..wJS(id) w ",code:" d ..wJS(code)
		w ",name:" d ..wJS(name) w ",desc:" d ..wJS(desc)
	w "}"
    Q $$$OK
}

/// Надо сообщать об ощибках в js
ClassMethod gErr(sc As %Status) As %String {
  Q $system.Status.GetErrorText(sc)
}

/// Ответ на действие
ClassMethod wResponse(ok As %Boolean, newid As %String, err As %String) As %Status {
 w "{ok:",$S(ok=1:"true",1:"false"),",newid:" d ..wJS(newid) w ",err:" d ..wJS(..gErr(err)) w "}" 
 Q $$$OK
}

/// Обработка вызова на добавление от интерфейса
ClassMethod jQGridAdd(ByRef reqData As %String) As %Status {
	s test=..%New(), test.Code=$G(reqData("code",1)), test.Name=$G(reqData("name",1)) 
	, test.Description=$G(reqData("desc",1))
	s sc=test.%Save(), id=test.%Id() k test
	d ..wResponse(+sc,id,sc) Q $$$OK
}

/// Обработка вызова на редактирование от интерфейса
ClassMethod jQGridEdit(ByRef reqData As %String) As %Status {
	s id=$G(reqData("id",1)) 
	if '..%ExistsId(id) {
		s sc=$$$ERROR( 10001 ,"id:"_id_" not exists") 
		d ..wResponse(+sc,id,sc) Q $$$OK
	}
	;упрощенный пример!
	s test=..%OpenId(id), test.Code=$G(reqData("code", 1 )), test.Name=$G(reqData("name", 1 )) 
	, test.Description=$G(reqData("desc", 1 ))
	s sc=test.%Save() k test
	d ..wResponse(+sc,id,sc) Q $$$OK
}

/// Обработка вызова на удаление от интерфейса
ClassMethod jQGridDel(ByRef reqData As %String) As %Status {
	s id=$G(reqData("id", 1 )) 
	if '..%ExistsId(id) {
		s sc=$$$ERROR(10001,"id:"_id_" not exists") 
		d ..wResponse(+sc,id,sc) Q $$$OK
	}
	s sc=..%DeleteId(id) d ..wResponse(+sc,id,sc) Q $$$OK
}

/// Разбор параметров запроса от интерфейса
ClassMethod jQGrid(ByRef reqData As %String) As %Status {
  s mode=$G(reqData("oper",1)) 
  Q:mode="add" ..jQGridAdd(.reqData) 
  Q:mode="edit" ..jQGridEdit(.reqData) 
  Q:mode="del" ..jQGridDel(.reqData)
  q ..jQGridOut(.reqData) ;по умолчанию
}

/// Вывод объектов постранично в jQuery Grid
ClassMethod jQGridOut(ByRef reqData As %String) As %Status {
  s pageNum=+$G(reqData("page",1),1) ;номер запрашиваемой страницы, по умолчанию первый
  s:pageNum<1 pageNum=1 ;контроль номера страницы 
    
  s pageSize=+$G(reqData("rows",100),100) ;вывести строк на страницу, по умолчанию 100
  s:pageSize<1 pageSize=100 ;контроль количества строк на страницу
  
  s SQL = "SELECT ID, Count(*) as records FROM SQLUser.jQGridTest"
  s where=..jQGridWhere(.reqData) s:where'="" SQL=SQL_where
  s order=..jQGridOrder(.reqData) s:order'="" SQL=SQL_order
  ;w "SQL:",SQL
  ;!!! В зависимости от версии Каше используем рекомендуемый %ResultSet || %ResultSet.SQL ||
  s rs=##class(%ResultSet).%New("%DynamicQuery:SQL")
  s sc=rs.Prepare(SQL) if 'sc d $system.OBJ.Dump(sc) Q sc
  s sc=rs.Execute() if 'sc d $system.OBJ.Dump(sc) Q sc
  
  ;диапазон выводимых строк
  s endRow=pageSize*pageNum ;последняя запись которую надо вывести с записи
  s startRow=endRow-pageSize ; начиная с записи
  s i=0,first=1,records=0,pages=0
  
  ;выводим
  w "{rows:["
  while rs.Next() {
   
   s i=i+1 ;счетчик пройденных строк
   if i<=startRow continue ;Не дошли до первой записи
   if i>endRow Q  ;прошли последнюю запись
   
   w:'first "," s:first first= 0  ;запятая после каждого объекта, кроме первого 
   s:records= 0  records=$G(rs.Data("records")) ;количество записей по запросу
   s id=$G(rs.Data("ID")) ;вывод объекта 
   d ..wJSON(id)
  
  }
  d rs.Close(),rs.%Close()
  s pages= 0   ;всего страниц данных
  s:records> 0  pages=records\pageSize ; если есть строки 
  s:records#pageSize> 0  pages=pages+ 1  ; непоместившиеся строки на след страницу
  w "],page:",pageNum,",total:",pages,",records:",records,"}"
  Q $$$OK
}

/// Сбор условий для Where 
ClassMethod jQGridWhere(ByRef reqData As %String) As %String {
 if $d(reqData("_search", 1 ))= 0  Q ""
 s where=" WHERE 1=1 "
 ;!!! Так делать нехорошо. Используйте параметры запроса
 s code=$G(reqData("code", 1 )) s:code'="" where=where_" AND Code['"_code_"'"
 s name=$G(reqData("name",1)) s:name'="" where=where_" AND Name['"_name_"'"
 s desc=$G(reqData("desc", 1 )) s:desc'="" where=where_" AND Description['"_desc_"'"
 q where
}

/// Сбор Order
ClassMethod jQGridOrder(ByRef reqData As %String) As %String {
 s sidx=$G(reqData("sidx",1)) ;сортировать по столбцу 
 if ",code,name,desc,"'[(","_sidx_",") Q ""  ;проверка наименование столбцов сортировки
 s:sidx="desc" sidx="Description"
 s order=" ORDER BY "_sidx
 s sord=$G(reqData("sord", 1 )) if sord'="desc" Q order
 Q order_" "_sord
}

}

/// Промежуточный слой 
Class json.jQGridTest Extends %CSP.Page {
Parameter CHARSET = "utf-8";
ClassMethod OnPage() As %Status {
	m reqData=%request.Data
	Q ##class(User.jQGridTest).jQGrid(.reqData)
}
}

/// Интерфейс
Class csp.jQGridTest Extends %CSP.Page {
Parameter CHARSET = "utf-8"; 
ClassMethod OnPage() As %Status {
 &html<
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html><head><title> Пример интерфейса на jQuery Grid плагине </title>
<!--link rel="SHORTCUT ICON" href=""/-->
<link rel='stylesheet' href='css/redmond/jquery-ui-1.7.2.custom.css' type='text/css'/>
<link rel="stylesheet" href="css/ui.jqgrid.css" type="text/css" media="all"  />
<link rel="stylesheet" href="css/jquery.autocomplete.css" type="text/css" media="all"  />
<style type="text/css"> #gbox_table {margin-left:auto;margin-right:auto;} </style>
<body>

<table id="table"></table> 
<div id="navigator"></div>

<script type="text/javascript" src="js/jquery-1.3.2.min.js"></script>
<script type="text/javascript" src="js/jquery-ui-1.7.2.min.js"></script>
<script type="text/javascript" src="js/i18n/grid.locale-ru.js" ></script>
<script type="text/javascript" src="js/jquery.jqGrid.min.js" ></script>


<script type="text/javascript">
//нужно вынести во внешний скрипт и сжать
var page=document.page||{};
//Обработчик ответа сервера 
page.fn_ServerResponse=function(response,postdata){
   var server=response.responseText;
   server=eval("("+server+")");
   return [server.ok,server.newid,server.err];
}

page.init=function(){
	var code={name:'code',index:'code',label:"Код"
	    ,width: 60 , sorttype:"int",search:true
 		,editable:true
 	};
	var name={name:'name',index:'name',label:"Наименование"
 		,width: 350 ,search:true,stype:'text'
 		,editable:true,edittype:"text",editoptions:{size: 50 }
 	};
 	var desc={name:'desc',index:'desc',label:"Описание"
 		,width: 350 ,search:true,stype:'text'
 		,editable:true,edittype:"text",editoptions:{size: 50 }
 	};	

var grid={
   url:"json.jQGridTest.cls",editurl:"json.jQGridTest.cls"
  ,datatype: "json",mtype:"POST"
  ,jsonReader : { repeatitems: false}
  ,caption: "Тестовые данные для примера"
  ,colModel:[code,name,desc]
  ,autowidth:false
  ,height:  400 
  ,gridview:true
  ,rownumbers:true,viewrecords:true,rowNum: 100 
  ,pager:$("#navigator")
  ,scrollrows:true,scroll: 1 
 }
 
 var table=jQuery("#table"); table.jqGrid(grid); //Создали таблицу
 table.filterToolbar({autosearch:true}); //добавили строку фильтра 
 
 var addOptions={afterSubmit:page.fn_ServerResponse,closeAfterAdd:true
 	,width: 500  
 };
 var editOptions={afterSubmit:page.fn_ServerResponse,closeAfterEdit:true
 	,width: 500  
 };
 var delOptions={afterSubmit:page.fn_ServerResponse,closeAfterDel:true};
 table.jqGrid('navGrid',"#navigator",
       {add:true, view:false, del:true,edit:true,search:false}, 
       editOptions,addOptions,delOptions
 );
 
}
$(page.init);   
</script>
</body>
</html>>

 Quit $$$OK
}

}

USER>d ##class(jQGridTest).Populate( 1000 )

<script type="text/javascript" src="js/i18n/grid.locale-ru.js"></script>

Parameter CHARSET = "utf-8"; 
ClassMethod OnPage() As %Status {
 &html<
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html><head>
<META http-equiv="content-type" content="text/html; charset=utf-8" />
<title> Пример интерфейса на jQuery Grid плагине </title>