Method GetNodeInfo2(Output tSC As %Status, ByRef pParams As %String, pLevel As %Integer, ByRef pHandle As %String, pNodeInfo As %ZEN.Auxiliary.NodeInfo) As %Boolean
{
	#; pHandle is current subscript
	#; pLevel is current piece of subscript

	If ((pHandle = "")&&('$D(pHandle("done")))) {
		#; first call
		Set pHandle = $O(^rINDEXCLASS(""))
	}

	If (pHandle = "") {
		#; no data
		Quit 0
	}

	#; get number of pieces at the current level
	Set tDepth = $L(pHandle,".")

	If (pLevel < tDepth) {
		#; descend
		#; remember data at this level
		Set pHandle(pLevel) = $P(pHandle,".",pLevel)
		
		#; get info about this node
		Set tClass = $LG(^rINDEXCLASS(pHandle),2)
		Set pNodeInfo.hasChildren = 1
		Set pNodeInfo.text = $P(tClass,".",pLevel) // piece of subscript
		Set pNodeInfo.value = $P(tClass,".",1,pLevel) // pkg
		Set ret = 1
	}
	Else {
		#; are we a leaf of the current parent?
		Set ret = 1
		For n=1:1:pLevel-1 {
			If (pHandle(n) '= $P(pHandle,".",n)) {
				Set ret =  0 
				Quit
			}
		}
		
		If (ret) {
			Set tClass = $LG(^rINDEXCLASS(pHandle), 2 )
			Set pNodeInfo.hasChildren =  0 
			Set pNodeInfo.text = $P(tClass,".",pLevel) // piece of subscript
			Set pNodeInfo.value = tClass // class

		}
		#; advance to next node
		Set pHandle = $O(^rINDEXCLASS(pHandle))
		If (pHandle="") {
			#; no more data; set done flag
			Set pHandle("done") =  1 
		}
	}

	Quit ret
}