Если потребуется это делать хотя бы еще пару раз, то можно использовать Cache SQL Storage для того, чтобы навернуть на ваши глобали классы Cache.

Если операция разовая, то проще всего создать свой запрос на основе Cache Object Script, который будет виден из SQL Server как хранимая процедура. Результаты этого запроса вы определяете самостоятельно. Пример:

ClassMethod testqueryClose(ByRef qHandle As %Binary) As %Status [ PlaceAfter = testqueryExecute ]
{
write "--------------------------------",!
write "Start: ",$ZDT($LI(qHandle,2)),!
write "End: ",$ZDT($H),!
Quit $$$OK
}

ClassMethod testqueryExecute(ByRef qHandle As %Binary) As %Status
{
set qHandle=$LB("",$H) ;; ID,Start
Quit $$$OK
}

ClassMethod testqueryFetch(ByRef qHandle As %Binary, ByRef Row As %List, ByRef AtEnd As %Integer = 0) As %Status [ PlaceAfter = testqueryExecute ]
{
set Row="" ;; reset the row
set i=$LI(qHandle,1) ;; previous eid
set eid=$order(^a(i)) ;; current eid

if eid="" {
set AtEnd=1
}
else {
set name=$g(^a(eid))
set Row=$LB(eid,name) ;; set the result
set $LI(qHandle,1)=eid ;; pass the current eid to the next fetch
}
Quit $$$OK
}

Query testquery() As %Query(ROWSPEC = "eid:%String,name:%String")
{
}

Запрос testquery можно определить как хранимую процедуру. Делаем глобал:

1) ^a(1)="Serg", ^a(2)="InterSystems", ^a(3)="Cache-rulezz"
2) Запускаем testquery
(3)Результат:
eid:1 name:Serg
eid:2 name:InterSystems
eid:3 name:Cache-rulezz