sigmov, на этом соревновании по оптимизации запросов был вот такой класс-оценки производительности запросов
Include datesrus
Class DatesRUs.WorkShop
{

ClassMethod Run(pInit As %Boolean = 1, pTuneTable As %Boolean = 1)
{
    #dim SQLStats as %String
    #dim tRun as Run
    
    write !!
    do:pInit ..Init(pTuneTable)
    
    
    s SQLStats("Stime")= $ZH
    s SQLStats("Sline")= $$$GetLinesExecuted
    s SQLStats("Sglo") = $$$GetGlobalReferences

    #dim tIdx,tStart,tDiff,tResult,tStartGloRefs,tDiffGloRefs as %Numeric = 0
    #dim tTotalRows as %Integer = 0
    write !,"Method#",?10,"rowcount",?22,"  exec time",?35,"       glorefs"
    write !,$tr($j(" ",50)," ","-")
    for tIdx = 1:1:10
    {
        set tStart = $zh, 
            tStartGloRefs = $$$GetGlobalReferences
        set tResult = $classmethod($classname(),"Method"_tIdx) ;вызов запроса
        set tDiff = $zh-tStart, 
            tTotalRows = tTotalRows + tResult,
            tDiffGloRefs = $$$GetGlobalReferences - tStartGloRefs
        write !,$j(tIdx,2),?10,$j($fn(tResult,","),8),?22,$j($fn(tDiff,",",2),10)_"s",?35,$j($fn(tDiffGloRefs,","),14)
    }
    write !,$tr($j(" ",50)," ","-")
    s SQLStats("Etime") = $ZH
    s SQLStats("Eline") = $$$GetLinesExecuted
    s SQLStats("Eglo")  = $$$GetGlobalReferences
    
    
    w !,!
    w !,"Total # of rows: ",?25,$j($fn(tTotalRows,","),15)
    w !,"Global Refs:  ",?25,$j($fn((SQLStats("Eglo")-SQLStats("Sglo")),","),15)
    w !,"TotalTime: ",?25, $j($fn((SQLStats("Etime")-SQLStats("Stime")),",",2),15)_"s"
    w !,"Score:  ",?25,$j($fn((SQLStats("Eglo")-SQLStats("Sglo"))*(SQLStats("Etime")-SQLStats("Stime")),",",2),15)
    w !

    QUIT
}

ClassMethod Init(pTuneTable As %Boolean = 0)
{
    #dim tClass,tMethod as %String
    write !,"intializing..."
    #; purge query cache
    write !,"purging all query cache"
    do $SYSTEM.SQL.Purge()
    
    #; rebuild indices
    write !,"purge and rebuild all indices"
    for tClass = "Person","Customers","DateHistory","Employee","Profile","Survey" {
        //s gln="^DatesRUs."_tClass_"I" k @gln         
        for tMethod = "%PurgeIndices","%BuildIndices" {
            do $classmethod("DatesRUs."_tClass,tMethod)
        }   
    }
    #; run TuneTable (TuneSchema) to get the right results for your definitions
    if (pTuneTable)
    { 
        write !,"tuning tables"
        #; don't display
        do $SYSTEM.SQL.TuneSchema("DatesRUs",1,0)
        
    }
    write !
}

}