|
Из строки в массив(COS)
#36753858
Ссылка:
Ссылка на сообщение:
Ссылка с названием темы:
Ссылка на профиль пользователя:
|
Участник
Откуда: г. Кишинёв, Республика Молдова
Сообщения: 3 167
|
|
Изменённый код 1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
80.
;-- Set test string
set tab=85
set zt="~"
set N=10000
set string=""
for i=1:1:N-1 {
set string=$s(i=5000:string_"A~",1:string_"1~")
set arr(i)=""
}
set string=string_"B"
set list=$listfromstring(string,zt)
;-- Test ListFromString (A CLOSE #2 IN SPEED)
set value=""
set ptr=0
set t=$zhorolog
for i=1:1 {
q:'$listnext(list,ptr,value)
set arr(i)=value
}
write "[Тест №1] Время прохода по всему списку, используя $listnext = ",?tab,$zhorolog-t," c.",!
;-- Test ListFromString - Get specific element
set value=""
set ptr=0
set t=$zhorolog
for i=1:1:5000 quit:'$listnext(list,ptr,value)
write "A=",value
write " [Тест №1.1] Время получения 5000-го элемента, используя $listnext = ",?tab,$zhorolog-t," c.",!,!
;-- Test List Get (ONLY SLIGHTLY FASTER THAN $PIECE)
set t=$zhorolog
for i=1:1:N set arr(i)=$LG(list,i)
write "[Тест №2] Время прохода по всему списку, используя $listget = ",?tab,$zhorolog-t," c.",!
;-- Test List Get for specific element
set t=$zhorolog
write "A=",$LG(list,5000)
write " [Тест №2.1] Время получения 5000-го элемента, используя $listget = ",?tab,$zhorolog-t," c.",!,!
;-- Test $Piece (SLOWEST OPTION)
set t=$zhorolog
for i=1:1:N set arr(i)=$p(string,"~",i)
write "[Тест №3] Время прохода по всему списку, используя $p = ",?tab,$zhorolog-t," c.",!
set str=string
set t=$zhorolog
for i=1:1:N {
set arr(i)=$p(str,zt,1,1)
set str=$p(str,zt,2,N+1-i)
}
write "[Тест №3.0] Время прохода по всему списку, используя $p с сужением области поиска = ",?tab,$zhorolog-t," c.",!
;-- Test $Piece For specific element (FASTEST BY FAR!)
set t=$zhorolog
write "A=",$p(string,zt,5000)
write " [Тест №3.1] Время получения 5000-го элемента, используя $p = ",?tab,$zhorolog-t," c.",!,!
;-- Test $Find-$Extract (FASTEST!!!)
set t=$zhorolog
set p1=1 ; starting pos
set string=string_"~" ; add delimiter to extract the last piece
for i=1:1 {
set p2=$f(string,"~",p1) q:p2=0
set arr(i)=$e(string,p1,p2-2)
set p1=p2
}
write "[Тест №5] Время прохода по всему списку, используя $f/$e = ",?tab,$zhorolog-t," c.",!
;-- Test $Find-$Extract for specific element
set value=""
set p1=1 ; starting pos
;-- set string=string_"~" ; add delimiter to extract the last piece
set t=$zhorolog
for i=1:1 {
set p2=$f(string,"~",p1) q:p2=0
i i=5000 s value=$e(string,p1,p2-2) q
set p1=p2
}
write "A=",value
write " [Тест №5.1] Время получения 5000-го элемента, используя $f/$e = ",?tab,$zhorolog-t," c.",!,!
Результаты: 1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
[Тест №1] Время прохода по всему списку, используя $listnext = .001316 c.
A=A [Тест №1.1] Время получения 5000-го элемента, используя $listnext = .000285 c.
[Тест №2] Время прохода по всему списку, используя $listget = .07716 c.
A=A [Тест №2.1] Время получения 5000-го элемента, используя $listget = .000018 c.
[Тест №3] Время прохода по всему списку, используя $p = .338546 c.
[Тест №3.0] Время прохода по всему списку, используя $p с сужением области поиска = .138815 c.
A=A [Тест №3.1] Время получения 5000-го элемента, используя $p = .000031 c.
[Тест №5] Время прохода по всему списку, используя $f/$e = .001623 c.
A=A [Тест №5.1] Время получения 5000-го элемента, используя $f/$e = .000364 c.
Выводы:
1) почему [1] < [2] объяснялось выше;
2) [1.1] > [2.1], [3.1] < [5.1] - здравый смысл;
3) [3] > [5], так как в [5] область поиска с каждой итерацией сужается;
4) следует разделять функции для быстрого получения единичного элемента и для быстрого прохода по всем элементам. |
|
|
