<NOTES>
<NOTE Text="str1 13; 10;str2 13; 10;str3"/>
</NOTES>

<?xml version="1.0" encoding="UTF-8"?>
<NOTES>
<NOTE Text="str1
str2
str3"></NOTE>
</NOTES>

Include %occConstant

Class tmp.Notes Extends (%Persistent, %XML.Adaptor)
{

Property Text As %XML.String(XMLPROJECTION = "ATTRIBUTE") [ SqlColumnNumber =  4  ];

/// Импорт из XML файла
ClassMethod ImportXML(fn As %String) As %Status
{
	Set sc=..%KillExtent()
	//
	Set status=$$$OK
	Set reader=##class(%XML.Reader).%New()
	Set sc=reader.OpenFile(fn)
	If $$$ISOK(sc) {
		Do reader.Correlate("NOTE","tmp.Notes")
		While reader.Next(.note,.sc) {
			If $$$ISOK(sc) {
				Set sc=note.%Save()
				If $$$ISERR(sc) Do $system.OBJ.DisplayError(sc)
			} Else {
				Do $system.OBJ.DisplayError(sc)
			}
		}
	} Else {
		Set status=sc
	}	
	Quit status
}

/// Экпорт в XML файла
ClassMethod ExportXML(fn As %String)
{
	Set status= 1 
	Set writer=##class(%XML.Writer).%New()
	Set writer.Charset="UTF-8",writer.Indent= 1 ,writer.IndentChars=""
	Set sc=writer.OutputToFile(fn)
	If $$$ISOK(sc) {
		Set sc=writer.RootElement("NOTES")
		If $$$ISOK(sc) {
			Set rs=##class(%ResultSet).%New("tmp.Notes:Extent")
			Set sc=rs.Prepare()
			If $$$ISOK(sc) {
				Set sc=rs.Execute()
				If $$$ISOK(sc) {
					While rs.Next() {
						Set oref=..%OpenId(rs.Get("ID"),,.sc)
						If $$$ISOK(sc) {
							Set sc=writer.Object(oref,"NOTE")
							Set oref=$$$NULLOREF
						}
					}
				}
			}
			//
			Set sc=writer.EndRootElement()
		}
	}
	//
	Set writer=$$$NULLOREF
	Quit
}

}