Пример серверной части для работы с UDPClass SqlRu.Test Extends %RegisteredObject [ Abstract ]
{

ClassMethod UDPReceive(
  host As %String = "127.0.0.1",
  port As %Integer = {$$$JDBCGatewayPort}) 
{
  #dim exception As %Exception.StatusException
    
  set N=2048
  set UDPPort=8090
    
  // Create a buffer to read datagrams into.
  // If a packet is larger than this buffer, the excess will simply be discarded!
  set buffer=##class(%GlobalBinaryStream).%New()
  for i=1:1:N  do buffer.Write(" ")
    
  try {
    #dim gateway As %Net.Remote.Gateway=##class(%Net.Remote.Gateway).%New()
    
    $$$ThrowOnError(gateway.%Connect(host,port))
    
    // Create a socket to listen on the port.
    #dim udp As java.net.DatagramSocket=##class(java.net.DatagramSocket).%New(gateway,UDPPort)
    
    // Create a packet to receive data into the buffer
    #dim packet As java.net.DatagramPacket=##class(java.net.DatagramPacket).%New(gateway,buffer,N)
    

    // Now loop forever, waiting to receive packets and printing them.
    while(1) {
    
      // Wait to receive a datagram
      do udp.receive(.packet)
    
      // Convert the contents to a string, and display them
      set str=packet.getData().Read(packet.getLength())
      w str,!
    
      q:str="exit"
    }
    
  } catch exception {
    write $system.Status.GetErrorText(exception.AsStatus(),"ru")
  }
  do:$IsObject(udp) udp.close()
  do:$IsObject(gateway) gateway.%Disconnect()
}
}