Class del.e Extends %Persistent
{

Property Value As %BigInt(MINVAL =  1 ) [ InitialExpression =  1 , Required ];

ClassMethod FillSQL(ACount As %Integer = {1e3}) As %Status
{
 set t1 = $ZHOROLOG
 do ##class(del.e).%KillExtent()
 set ^del.eD = - 1  ;первичный ключ начинаем с  0 
 do DISABLE^%NOJRN ;отключаем для сессии журналирование
 ;TSTART
 &sql(insert into del.e default values)
 for i =  1 : 1 :ACount- 1  {
   set id1 = $random(i)
   set id2 = $random(i)
   set id3 = $random(i)
  
   &sql(select %NOLOCK Value into :val1 from del.e where %ID=:id1)
   &sql(select %NOLOCK Value into :val2 from del.e where %ID=:id2)
   &sql(select %NOLOCK Value into :val3 from del.e where %ID=:id3)
   &sql(insert %NOCHECK %NOLOCK %NOINDEX %NOTRIGGER into del.e(Value) values(:val1+:val2+:val3))

   ; или &sql(insert into del.e(Value) select sum(Value) from del.e where %ID in (:id1,:id2,:id3))
    
 }
 do ENABLE^%NOJRN
 ;TCOMMIT
 write "Ввод данных = ",($ZHOROLOG - t1)," с.",!
 quit $$$OK
}

ClassMethod FillDirect(ACount As %Integer = {1e3}) As %Status
{
 set time = $ZHOROLOG
 do ##class(del.e).%KillExtent()
 ;do DISABLE^%NOJRN
 TSTART
 
 set ^del.eD( 0 ) = $ListBuild("", 1 )
 for i =  1 : 1 :ACount- 1  {

   s ^del.eD(i) = $lb("",$li(^del.eD($r(i)), 2 ) + $li(^del.eD($r(i)), 2 ) + $li(^del.eD($r(i)), 2 ))

   /* или
   set id1 = $random(i)
   set id2 = $random(i)
   set id3 = $random(i)
   set val1 = $list(^del.eD(id1),2)
   set val2 = $list(^del.eD(id2),2)
   set val3 = $list(^del.eD(id3),2)
   set ^del.eD(i) = $ListBuild("",val1 + val2 + val3)
   */
 }
 set ^del.eD = ACount- 1 
 ;do ENABLE^%NOJRN
 TCOMMIT
 write "Ввод данных = ",($ZHOROLOG - time)," с.",!
 quit $$$OK
}
}

Class del.f Extends %Persistent
{

Property m As %BigInt [ Required ];

Property s1 As del.f [ Required ];

Property s2 As del.f [ Required ];

Property s3 As del.f [ Required ];

ClassMethod Fill(
  ACount As %Integer = {1e6},
  ARnd As %Boolean =  0 ) As %Status
{
 set time = $ZHOROLOG
 do ##class(del.f).%KillExtent()
 do DISABLE^%NOJRN
 set ^del.fD = - 1 
 if ARnd =  0  {
   for i =  0 : 1 :ACount- 1  {
     set ^del.fD(i) = $listbuild("",i+ 1 ,i,i,i)
   }
 } else {
   for i =  0 : 1 :ACount- 1  {
     set ^del.fD(i) = $listbuild("",i+ 1 ,$random(ACount),$random(ACount),$random(ACount))
   }
 }
 set ^del.fD = ACount- 1 
 do ENABLE^%NOJRN
 write "Ввод данных = ",($ZHOROLOG - time)," с.",!
 quit $$$OK
}

/// Хранимая процедура SPQuery1 равнозначна SPQuery2, но удобней в написании благодаря объектному расширению SQL
Query SPQuery1() As %SQLQuery(ROWSPEC="Результат:%BigInt") [SqlProc]
{
  SELECT sum(s1->m + s2->m + s3->m) FROM del.f
}

Query SPQuery2() As %SQLQuery(ROWSPEC="Результат:%BigInt") [SqlProc]
{
  SELECT sum(t1.m + t2.m + t3.m)
  from del.f t
  join del.f t1 on t1.id = t.s1
  join del.f t2 on t2.id = t.s2
  join del.f t3 on t3.id = t.s3
}

ClassMethod SPQuery3() As %BigInt [SqlProc]
{
  set result =  0 
  for i =  0 : 1 :^del.fD {
    set s1 = $list(^del.fD(i), 3 )
    set s2 = $list(^del.fD(i), 4 )
    set s3 = $list(^del.fD(i), 5 )
    set m1 = $list(^del.fD(s1), 2 )
    set m2 = $list(^del.fD(s2), 2 )
    set m3 = $list(^del.fD(s3), 2 )
    set result = result + m1 + m2 + m3
  }
  quit result
}
}

...
ClassMethod SPQuery3(nThread As %Integer(VALUELIST=",1,2,4,5,8,10") =  2 ) As %BigInt [ SqlProc ]
{
  quit:($listfind($listbuild( 1 , 2 , 4 , 5 , 8 , 10 ),nThread)= 0 ) - 1 
  kill ^CacheTempUser($job)

  set result= 0 ,k=^del.fD+ 1 \nThread
  
  for i= 1 : 1 :nThread job ..Thread(i- 1 *k,i*k- 1 ,i,$job)

  for i= 1 : 1 :nThread {
    for  quit:$data(^CacheTempUser($job,i))
    set result=result+^CacheTempUser($job,i)
  }

  quit result
}

ClassMethod Thread(i1,i2,n,j) [ServerOnly =  1 ]
{
  set result= 0 
  for i=i1: 1 :i2 set result=result+$li(^del.fD($li(^del.fD(i), 3 )), 2 )+$li(^del.fD($li(^del.fD(i), 4 )), 2 )+$li(^del.fD($li(^del.fD(i), 5 )), 2 )
  // или &sql(select sum(s1->m + s2->m + s3->m) into :result FROM del.f where %ID between :i1 and :i2)
  set ^CacheTempUser(j,n)=result
}
...