Class del.d Extends %Persistent
{

/// PROPERTYVALIDATION parameter defined in %RegisteredObject
/// overridden here to VALIDATEONSAVE ( 2 ).
Parameter PROPERTYVALIDATION As INTEGER [ Constraint = "0,1,2", Flags = ENUM ] =  0 ;

Property a As %Integer;

Property b As %Integer;

Property c As %Integer;

/// Заполнение случайными данными с помощью объектного подхода.
/// <br><i>Параметры:</i>
/// <br><b>ACount</b> - количество генерируемых объектов;
/// <br><b>WithTrans</b> - включить/выключить транзакции.
ClassMethod FillObjects(
	ACount As %Integer =  1000 ,
	WithTrans As %Boolean =  1 ) As %Status
{
 set t1=$ZH
 do ##class(del.d).%KillExtent()
 if WithTrans {
   TSTART
 } else {
   do $system.OBJ.SetTransactionMode( 0 )
 }
 try{
   for i= 1 : 1 :ACount {
     set t=##class(del.d).%New()
   
     set t.a=$random( 1000 )
     set t.b=$random( 1000 )
     set t.c=$random( 1000 )

     do t.%Save( 0 )
   }
   //set a= 5 / 0 
   if WithTrans {
     TCOMMIT
   } else {
     do $system.OBJ.SetTransactionMode( 1 )
   }
 } catch ex {
   TROLLBACK
 }
 write "Ввод данных = ",($ZH-t1)_" с.",!
 quit $$$OK
}

/// Заполнение случайными данными с помощью SQL.
/// <br><i>Параметры:</i>
/// <br><b>ACount</b> - количество генерируемых записей;
ClassMethod FillSQL(ACount As %Integer =  1000 ) As %Status
{
 set t1=$ZH
 do ##class(del.d).%KillExtent()
 TSTART
 for i= 1 : 1 :ACount {
   set a( 1 )=$random( 1000 )
   set a( 2 )=$random( 1000 )
   set a( 3 )=$random( 1000 )
   &sql(insert %NOCHECK %NOLOCK %NOINDEX %NOTRIGGER into del.d(a,b,c) values(:a( 1 ),:a( 2 ),:a( 3 )))
 }
 TCOMMIT
 write "Ввод данных = ",($ZH-t1)," с.",!
 quit $$$OK
}

/// Заполнение случайными данными с помощью глобалов.
/// <br><i>Параметры:</i>
/// <br><b>ACount</b> - количество генерируемых записей;
ClassMethod FillDirect(ACount As %Integer =  1000 ) As %Status
{
 set t1=$ZH
 do ##class(del.d).%KillExtent()
 TSTART
 for i= 1 : 1 :ACount {
   set ^del.dD(i)=$LB("",$random( 1000 ),$random( 1000 ),$random( 1000 ))
 }
 set ^del.dD=ACount
 TCOMMIT
 write "Ввод данных = ",($ZH-t1)," с.",!
 quit $$$OK
}

}