BEGIN TRAN

DECLARE
        @ITEMNO VARCHAR( 24 ) -- код позиции
        ,@CITEM VARCHAR( 24 ) -- текущая позиция
        ,@D DATETIME -- дата периода
        ,@OH INT -- начальный остаток
        ,@OHC INT -- расчетный начальный остаток
        ,@GR INT -- плановая реализация
        ,@TR INT -- количество товара в пути
        ,@SR INT -- ожидаемый приход по утвержденным заказам
        ,@RU INT -- потребность
        ,@PA INT -- прогнозный остаток на конец периода
        ,@RO INT -- количество товара в плановом заказе
        ,@LT INT -- срок доставки
        ,@LS INT -- размер (кратность) партии поставки
        ,@ERRCODE INT -- код ошибки
        ,@SST FLOAT -- страховой запас (%)


DECLARE C CURSOR FOR

        SELECT TOP  100  PERCENT ITEMNO,PDATE,OH,GR,TR,SR,SST,LT,LS,RU
        FROM MRP01
        ORDER BY ITEMNO,PDATE

 OPEN C

    FETCH NEXT FROM C INTO @ITEMNO,@D,@OH,@GR,@SR,@TR,@SST,@LT,@LS,@RU
    SET @CITEM = @ITEMNO
    SET @OHC = @OH

    WHILE @@FETCH_STATUS =  0 
    BEGIN

        SET @ERRCODE =  0 

        --1 Расчет прогнозного остатка
        SET @PA = @OHC + @SR+@TR+@RU - @GR
        SET @RU =  0 

        -- 2 Если прогнозный остаток менее страхового запаса, то вычисление планового заказа и запись его в план закупок
        IF @PA < @GR*@SST/ 100 
        BEGIN
                IF @LS =  0  SET @LS =  1 
                IF @LS =  1 
                BEGIN
                        SET @RU =  (@GR*@SST/ 100 ) - @PA
                        SET @RO = (@GR*@SST/ 100 ) - @PA
                END ELSE
                BEGIN
                        SET @RU =  (ROUND(((@GR*@SST/ 100 ) - @PA)/@LS, 0 , 1 ) +  1 ) * @LS
                        SET @RO = (ROUND(((@GR*@SST/ 100 ) - @PA)/@LS, 0 , 1 ) +  1 ) * @LS
                END
                SET @PA = @OHC + @SR + @TR + @RO - @GR

                INSERT INTO MRP02 (ID,ITEMNO,ODATE,RDATE,UM,AM,TRAM,ST) VALUES (NEWID(),@ITEMNO,@D-@LT,@D,@RO, 0 , 0 , 0 )
                IF @D-@LT < GETDATE()
                        SET @ERRCODE =  1  -- Просроченный заказ
        END

        -- 3 Обновление остатка, прогнозного остатка и потребностей в сводной таблице
        UPDATE MRP01 SET
            OH = @OHC
            ,PA = @PA
            ,RU = @RU
            ,ERRCODE = @ERRCODE
        WHERE ITEMNO = @ITEMNO AND PDATE = @D

        SET @OHC = @PA

        FETCH NEXT FROM C INTO @ITEMNO,@D,@OH,@GR,@SR,@TR,@SST,@LT,@LS,@RU

        IF @ITEMNO <> @CITEM
        BEGIN
            -- Переход к следующей категории товара
                SET @CITEM = @ITEMNO
                SET @OHC = @OH
        END -- @ITEMNO <> @CITEM

    END -- WHILE

    CLOSE C
    DEALLOCATE C


IF @@ERROR <>  0 
    ROLLBACK TRAN
ELSE
    COMMIT TRAN