--Табличка, думаю поля и так будут понятны, индексы под свои задачи сделаете
CREATE TABLE [Category] (
	[cat_id] [int] IDENTITY ( 1 ,  1 ) NOT NULL ,
	[cat_parent] [int] NULL ,
	[cat_left] [int] NULL ,
	[cat_right] [int] NULL ,
	[cat_level] [int] NULL ,
	[cat_name] [varchar] ( 100 ) COLLATE Cyrillic_General_CI_AS NOT NULL ,
	CONSTRAINT [PK_Category] PRIMARY KEY  NONCLUSTERED 
	(
		[cat_id]
	)  ON [PRIMARY] ,
	CONSTRAINT [IX_Category_Category] UNIQUE  CLUSTERED 
	(
		[cat_left],
		[cat_right],
		[cat_level]
	)  ON [PRIMARY] ,
	CONSTRAINT [FK_Category_Category] FOREIGN KEY 
	(
		[cat_parent]
	) REFERENCES [Category] (
		[cat_id]
	)
) ON [PRIMARY]
GO
--Просто вспомогательная процедурка, считает "координаты",  упрощает перемещение и вставку.
CREATE  PROC admin_p_CategoryPoint
(
	@cat_id int, @axis_x bit, @axis_y bit,
	@pnt_parent int output,
	@pnt_point int output,
	@pnt_level int output
)
AS
	SET NOCOUNT ON
	DECLARE @cat_parent int, @cat_left int, @cat_right int, @cat_level int
	SELECT @cat_parent = cat_parent, @cat_left = cat_left, @cat_right = cat_right, @cat_level = cat_level
		FROM dbo.Category WHERE cat_id = @cat_id	
	IF @axis_y =  1 
		BEGIN
			SET @pnt_parent = @cat_id
			IF @axis_x =  1  SET @pnt_point = @cat_right -  1  ELSE SET @pnt_point = @cat_left
			SET @pnt_level = @cat_level +  1 
		END
	ELSE
		BEGIN
			SET @pnt_parent = @cat_parent
			IF @axis_x =  1  SET @pnt_point = @cat_right ELSE SET @pnt_point = @cat_left - 1 
			SET @pnt_level = @cat_level
		END

GO
--Процедурка, добавляет ноду.
CREATE PROC admin_p_CategoryIns 
(
	@cat_id int output,
	@cat_parent int,
	@axis_x bit,
	@axis_y bit,
	@cat_name varchar ( 100 )
)
AS
	SET NOCOUNT ON
	DECLARE @pnt_parent int, @pnt_point int, @pnt_level int
	EXEC dbo.admin_p_CategoryPoint @cat_parent, @axis_x, @axis_y,
		@pnt_parent OUTPUT , @pnt_point OUTPUT , @pnt_level OUTPUT
	UPDATE dbo.Category SET 
		cat_left	= CASE WHEN cat_left > @pnt_point THEN cat_left +  2  ELSE cat_left END,
		cat_right	= cat_right +  2 
	WHERE cat_right > @pnt_point
	INSERT INTO dbo.Category (cat_parent, cat_left, cat_right, cat_level, cat_name)
		VALUES (@pnt_parent, @pnt_point +  1 , @pnt_point +  2 , @pnt_level, @cat_name)
	SELECT @cat_id = SCOPE_IDENTITY()

GO
--Процедурка, перемещает ноду
CREATE PROC admin_p_CategoryUpd
(
	@cat_id int,
	@cat_parent int,
	@axis_x bit,
	@axis_y bit,
	@cat_name varchar ( 100 )
)
AS
	SET NOCOUNT ON

	DECLARE @cat_left int, @cat_right int, @cat_level int
	SELECT @cat_left = cat_left, @cat_right = cat_right, @cat_level = cat_level
		FROM dbo.Category WHERE cat_id = @cat_id

	DECLARE @pnt_parent int, @pnt_point int, @pnt_level int
	EXEC dbo.admin_p_CategoryPoint @cat_parent, @axis_x, @axis_y,
		@pnt_parent OUTPUT , @pnt_point OUTPUT , @pnt_level OUTPUT

	IF @pnt_point BETWEEN @cat_left AND @cat_right
		RAISERROR ('#00012',  16 ,  1 )

	DECLARE @d1 int, @d2 int, @d3 int
	SET @d1 = @cat_right - @cat_left +  1 
	SET @d2 = @pnt_level - @cat_level

	IF @pnt_point > @cat_right
		BEGIN
			SET @d3 = @pnt_point - @cat_right
			UPDATE dbo.Category SET
				cat_left = CASE WHEN cat_right <= @cat_right THEN cat_left + @d3 ELSE CASE WHEN cat_left > @cat_right THEN cat_left - @d1 ELSE cat_left END END,
				cat_right = CASE WHEN cat_right <= @cat_right THEN cat_right + @d3 ELSE CASE WHEN cat_right <= @pnt_point THEN cat_right - @d1 ELSE cat_right END END,
				cat_level = CASE WHEN cat_right <= @cat_right THEN cat_level + @d2 ELSE cat_level END
			WHERE cat_left <= @pnt_point AND cat_right > @cat_left
		END
	ELSE
		BEGIN
			SET @d3 = @pnt_point - @cat_left +  1 
			UPDATE dbo.Category SET
				cat_right = CASE WHEN cat_left >= @cat_left THEN cat_right + @d3 ELSE CASE WHEN cat_right < @cat_left THEN cat_right + @d1 ELSE cat_right END END,
				cat_left = CASE WHEN cat_left >= @cat_left THEN cat_left + @d3 ELSE CASE WHEN cat_left > @pnt_point THEN cat_left + @d1 ELSE cat_left END END,
				cat_level = CASE WHEN cat_left >= @cat_left THEN cat_level + @d2 ELSE cat_level END
			WHERE @cat_right > cat_left AND @pnt_point < cat_right
		END

	UPDATE dbo.Category SET
		cat_parent = @pnt_parent,
		cat_level = @pnt_level,
		cat_name = @cat_name
	WHERE cat_id = @cat_id
GO

-- ну собственно нода на которой будет происходить
-- преобразование (включая ее дочерние элементы), назовем ее "A"
@cat_id int,

-- вот тут маленькая поправка, это не просто родитель,
-- это нода относительно которой будем ориентироваться при вставка/перемещении "A", назовем ее "B"
@cat_parent int,

-- дополнительные флаги
@axis_x bit,  @axis_y bit,  Результат
  false,        false         "A" встанет на одном уровне с "B", до "B"
  false,        true          "A" встанет на одном уровне с "B", после "B"
  true,         false         "A" станет первым дочерним элементом "B"
  true,         true          "A" станет последним дочерним элементом "B"