'-------------------------------------------------------------------------------
' Create unique constraint for every table on a diagram (Power Designer 15.2).
' It is assumed that every table has a NAME column.
'-------------------------------------------------------------------------------
Option Explicit

Dim model
set Model = ActiveModel ' Current active model
If (model Is Nothing) Or (Not model.IsKindOf(PdPDM.cls_Model)) Then
   MsgBox "The current model is not a PDM model."
Else
   ProcessTables model
End If

'-----------------------------------------------------------------------------
' Recursively process all tables.
'-----------------------------------------------------------------------------
Sub ProcessTables(package)
   ' Process all tables belonging to this package.
   Dim table
   For Each table In package.Tables
      ' Shortcuts are also processed.
      ProcessTable package, table
   Next

   ' Process tables defined in all subpackages.
   Dim subpackage
   For Each subpackage in package.Packages
      If Not subpackage.IsShortcut Then
         ProcessTables subpackage
      End If
   Next
End Sub

'-----------------------------------------------------------------------------
' Recursively process all tables.
'-----------------------------------------------------------------------------
Sub ProcessTable(package, table)
   dim shortcutCharacter
   if table.isShortcut then
      ' Do nothing
   else
      ' Create a key
      CreateKey table, "UC_" + table.Name + "_Name", "Key on the Name column", "Name"
   end if
End Sub

'-----------------------------------------------------------------------------
' Add a key to a table.
'
' Parameters:
'     table
'     keyName
'     keyComment
'     columnNames   List of column names separated by comma's
'-----------------------------------------------------------------------------
Sub CreateKey(table, keyName, keyComment, columnNames)
   dim key : set key = table.Keys.CreateNew()
   dim colArray : colArray = split(LCase(columnNames), ",")

   key.Name = keyName
   key.Code = keyName
   key.Comment = keyComment
   key.ConstraintName = keyName

   dim column
   dim counter
   For Each column In table.Columns
      for counter =  0  to UBound(colArray)
         if colArray(counter) = LCase(column.Name) then
            key.Columns.Add(column)
         end if
      next
   Next
   set key = Nothing
   set column = Nothing
End Sub