Процедура Сформировать()
    
    Если ПустоеЗначение(КонецПериода) =  1  Тогда
        Сообщить("Пожалуйста задайте дату формирования отчета", "!");
        Возврат;
    КонецЕсли;
    
    ФильтрПоСчетам = "10";
    
    ПараметрыОтчета = "По счетам: " + ФильтрПоСчетам + ";";
    
    БИ = СоздатьОбъект("БухгалтерскиеИтоги");
    
    Если Склад.Выбран() =  1  Тогда
        БИ.ИспользоватьСубконто(ВидыСубконто.МестаХранения, Склад);
        ПараметрыОтчета = ПараметрыОтчета + " По складу: " + Склад + ";";
    Иначе
        БИ.ИспользоватьСубконто(ВидыСубконто.МестаХранения);
        ПараметрыОтчета = ПараметрыОтчета + "По складу: Все склады"
    КонецЕсли;                                              
    
    БИ.ИспользоватьСубконто(ВидыСубконто.Материалы);
                                                 
    БИ.ВыполнитьЗапрос(,КонецПериода, ФильтрПоСчетам,,,  1 ,,  5 );
    
    ПечИтогоКоличество = БИ.СКД( 3 );
    ПечИтогоСумма = БИ.СКД( 1 );
    
    Таб = СоздатьОбъект("Таблица");
    
    Таб.ВывестиСекцию("Заголовок");
    Таб.ВывестиСекцию("ПараметрыОтчета");
    Таб.ВывестиСекцию("Шапка");
    
    // Открываем выборку по складам
 
    БИ.ВыбратьСубконто( 1 );
    
    // обходим склады и выводим их в отчет
 
    Пока БИ.ПолучитьСубконто( 1 ) =  1  Цикл
       
        ПечСклад = БИ.Субконто( 1 );
        ПечИтогоСклад = БИ.СКД( 1 );
        
        Таб.ВывестиСекцию("СтрокаСклад");
        
        БИ.ВыбратьСубконто( 2 );
        
        Пока БИ.ПолучитьСубконто( 2 ) =  1  Цикл
            ПечМатериал = БИ.Субконто( 2 );
            ПечКоличество = БИ.СКД( 3 );
            ПечСумма = БИ.СКД( 1 );
            
            Таб.ВывестиСекцию("СтрокаМатериал");
        КонецЦикла;
    КонецЦикла;
    
    Таб.ВывестиСекцию("Итого");
    
    Таб.Опции( 0 ,  1 );
    Таб.Показать("Остатки материалов на " + КонецПериода);
    
КонецПроцедуры