Вот пример работы с ADO через OLEDB и ODBC провайдеров
там есть примеры чтения и записи данных с поддержкой транзакций
все для 1с 8.2 - если надо кину конфигурацию

// Процедура создания соединения с БД
Procedure CreateConnection(Form) export
// создаем соединение c БД
if isnull(Form.Connection) then
try
Form.Connection = Новый COMОбъект("ADODB.Connection");
if isnull(Form.ConnectionString) = true then
if Form.Provider = "SQLNCLI" then
if Form.Trusted_Connection = false then
Form.ConnectionString = "Provider = SQLNCLI;DRIVER=SQL Native Client;server="+Form.server+";uid="+Form.uid+";pwd="+Form.pwd+";Database="+Form.database+";Trusted_Connection=no;";
else
Form.ConnectionString = "Provider = SQLNCLI;DRIVER=SQL Native Client;server="+Form.server+";Database="+Form.database+";Trusted_Connection=yes;";
endif;
else
Form.Provider = "SQLOLEDB";
if Form.Trusted_Connection = false then
Form.ConnectionString = "Provider=SQLOLEDB;Driver=SQL Server;server="+Form.server+"; uid="+Form.uid+";pwd="+Form.pwd+";Database="+Form.database+";Trusted_Connection=no;";
else
Form.ConnectionString = "Provider=SQLOLEDB;Driver=SQL Server;server="+Form.server+";Database="+Form.database+";Trusted_Connection=yes;";
endif;
endif;
endif;
Form.Connection.ConnectionTimeout = 10;
Form.Connection.CommandTimeout = 0;
Form.Connection.CursorLocation = 3;
except
Form.Connection = NULL;
Предупреждение("Невозможно создать соединение. " + ОписаниеОшибки(),0,"Внимание !");
endtry;
endif;
endprocedure

// Процедура соединения с БД
Procedure Connect(Form) export
if not isnull(Form.Connection) then
// проверяем соединение
if Form.Connection.State = 0 and not isnull(Form.ConnectionString) then
try
// Соединяемся с БД
Form.Connection.Open(Form.ConnectionString);
except
Form.Connection = NULL;
Предупреждение("Невозможно установить соединение. " + ОписаниеОшибки(),0,"Внимание !");
endtry;
endif;
endif;
endprocedure

// Проседура разрыва соединения
Procedure Disconnect(Form,DWP) export
// разрываем соединение при закрытии окна
if Form.CloseConnection = true then
if not isnull(DWP.Recordset.Source) then
DWP.Recordset.close();
endif;
if not isnull(Form.Connection) then
try
Form.Connection.close();
except
Предупреждение("Невозможно разорвать соединение. "+ОписаниеОшибки(),0,"Внимание !");
endtry;
endif;
endif;

Form.Connection = NULL;
DWP.Recordset = NULL;
endprocedure

Procedure RollbackSQLTransaction(Connection) export
cnt = 0;
ТЗ = Выполнить_Запрос_SQL("select @@TRANCOUNT",Connection,false);
if ТЗ.count() > 0 then
if ТЗ.ВыгрузитьКолонку(0)[0] > 0 then
Connection.Execute("Rollback");
endif;
endif;
endprocedure

Procedure BeginSQLTransaction(Connection) export
Connection.Execute("BEGIN TRANSACTION");
endprocedure

Procedure CommitSQLTransaction(Connection) export
cnt = 0;
ТЗ = Выполнить_Запрос_SQL("select @@TRANCOUNT",Connection,false);
if ТЗ.count() > 0 then
if ТЗ.ВыгрузитьКолонку(0)[0] > 0 then
Connection.Execute("Commit");
endif;
endif;
endprocedure

// Функция выполняет SQL запрос без параметров и возвращает Таблицу Значений
Function Выполнить_Запрос_SQL(val ТекстЗапроса,Connection,Transactional) export
ТаблицаЗначенийРезультата = Новый ТаблицаЗначений;

if isnull(ТекстЗапроса) or isnull(Connection) then
return ТаблицаЗначенийРезультата;
endif;

try
ADODBError = false;

Cmd = Новый COMОбъект("ADODB.Command");
Cmd.ActiveConnection = Connection;

Cmd.CommandText = ТекстЗапроса;
if isnull(Cmd.CommandType) then
Cmd.CommandType = КонстантаCommandType("adCmdUnknown");
endif;

RecordSet = Новый COMОбъект("ADODB.RecordSet");

if Transactional then
Connection.Execute("BEGIN TRANSACTION");
Connection.Execute("set implicit_transactions off");
endif;

RecordSet = Cmd.Execute(); //Выполнение и получение набора данных

if Transactional then
Connection.Execute("Commit");
endif;

if RecordSet.State = 1 then
// заполняем ТЗ
for i = 0 to RecordSet.Fields.Count - 1 do //Создание и добавление колонок
ColumnName = RecordSet.Fields.Item(i).Name;
ColumnType = GetTypeColumn(RecordSet.Fields.Item(i).Type,RecordSet.Fields.Item(i).ActualSize);

if isnull(ColumnType) then
ТаблицаЗначенийРезультата.Колонки.Добавить(ColumnName);
else
ТаблицаЗначенийРезультата.Колонки.Добавить(ColumnName,ColumnType);
endif;
enddo;

while RecordSet.EOF = 0 do // Заполнение созданной таблицы
НоваяСтрока = ТаблицаЗначенийРезультата.Добавить();
for НомерСтолбца = 0 По RecordSet.Fields.Count - 1 do
НоваяСтрока.Установить(НомерСтолбца,RecordSet.Fields(НомерСтолбца).Value);
enddo;
RecordSet.MoveNext();
enddo;
RecordSet.close();
endif;

Cmd = NULL;
RecordSet = NULL;
except
ADODBError = true;
if Transactional then
RollbackSQLTransaction(Connection);
endif;
Предупреждение("Невозможно выполнить запрос: "+ТекстЗапроса+". " + ОписаниеОшибки(),0,"Внимание !");
Message("Невозможно выполнить запрос: "+ТекстЗапроса);
endtry;
return ТаблицаЗначенийРезультата;
endfunction

// Функция выполняет SQL запрос с параметрами и возвращает Таблицу Значений
Function Выполнить_Запрос_SQL_Параметры(val ТекстЗапроса,Connection,Параметры) export
ТаблицаЗначенийРезультата = Новый ТаблицаЗначений;

if isnull(ТекстЗапроса) or isnull(Connection) then
return ТаблицаЗначенийРезультата;
endif;

try
ADODBError = false;

Cmd = Новый COMОбъект("ADODB.Command");
Cmd.ActiveConnection = Connection;

Cmd.CommandText = ТекстЗапроса;
if isnull(Cmd.CommandType) then
Cmd.CommandType = КонстантаCommandType("adCmdUnknown");
endif;

if Параметры.Count() > 0 then
ПараметрЗапроса = Новый COMОбъект("ADODB.Parameter");

for each КлючИЗначение in Параметры do
if isnull(КлючИЗначение.Значение) then
Cmd = NULL;
return ТаблицаЗначенийРезультата;
endif;
P = ParameterADO(КлючИЗначение);
ПараметрЗапроса = Cmd.CreateParameter(P.Name,P.Type,P.Direction,P.Size,P.Value);
Cmd.Parameters.Append(ПараметрЗапроса)
enddo;
endif;

RecordSet = Новый COMОбъект("ADODB.RecordSet");
RecordSet = Cmd.Execute(); //Выполнение и получение набора данных

// заполняем ТЗ
if RecordSet.State = 1 then
for i = 0 to RecordSet.Fields.Count - 1 do //Создание и добавление колонок
ColumnName = RecordSet.Fields.Item(i).Name;
ColumnType = GetTypeColumn(RecordSet.Fields.Item(i).Type,RecordSet.Fields.Item(i).ActualSize);

if isnull(ColumnType) then
ТаблицаЗначенийРезультата.Колонки.Добавить(ColumnName);
else
ТаблицаЗначенийРезультата.Колонки.Добавить(ColumnName,ColumnType);
endif;
enddo;

while RecordSet.EOF = 0 do // Заполнение созданной таблицы
НоваяСтрока = ТаблицаЗначенийРезультата.Добавить();
for НомерСтолбца = 0 По RecordSet.Fields.Count - 1 do
НоваяСтрока.Установить(НомерСтолбца,RecordSet.Fields(НомерСтолбца).Value);
enddo;
RecordSet.MoveNext();
enddo;
RecordSet.close();
endif;

Cmd = NULL;
RecordSet = NULL;
except
ADODBError = true;

Предупреждение("Невозможно выполнить запрос: "+ТекстЗапроса+". " + ОписаниеОшибки(),0,"Внимание !");
Message("Невозможно выполнить запрос: "+ТекстЗапроса);
endtry;
return ТаблицаЗначенийРезультата;
endfunction

Послал конфигурацию - что непонятно - пишите