<job>
<?job debug="true"?>
<script language="VBScript">
' отслежка подключения/удаления дисков 
' для отслеживания только флэшек нужно 
' раскомментировать 4 строки а также
' добавить корректную обработку индексов массивов

	Dim WSHShell, fso
	Dim arrDrv(), arrDrvTmp()
	Dim idDrv, addDrv, addedDrv, remDrv, removedDrv, str
	Set WSHShell = WScript.CreateObject("WScript.Shell")
	Set fso = WScript.CreateObject("Scripting.FileSystemObject")

	idDrv =  0 
	' Проверяем все драйвы в системе на старте скрипта
	For each i In fso.Drives 
'		If i.DriveType= 1  Then ' флэшка - тип 1
			ReDim Preserve arrDrv(idDrv)
			arrDrv(idDrv) = i.DriveLetter
			idDrv = idDrv + 1
'		End If
	Next
	
	' покажем какие диски были в системе при запуске скрипта
	For i = 0 To UBound(arrDrv)
		str = str & arrDrv(i) & vbCrLf
	Next
	WSHShell.Popup str, 2, "Диски при старте скрипта"
	
	Do While True ' собственно говоря, выхода из цикла нет
		ReDim arrDrvTmp( 0 )
		idDrv =  0 
		addedDrv = False
		removedDrv = False
		' Проверяем все драйвы в системе в цикле
		For each i In fso.Drives 
'			If i.DriveType= 1  Then ' флэшка - тип 1
				ReDim Preserve arrDrvTmp(idDrv)
				arrDrvTmp(idDrv) = i.DriveLetter
				' проверка на новый диск 
				addDrv = True ' предположим что есть новый
				For id = 0 To UBound(arrDrv)
					If i.DriveLetter = arrDrv(id) Then
						addDrv = False ' нет... он уже был
					End If
				Next
				If addDrv Then addedDrv = True
				idDrv = idDrv +  1 
'			End If
		Next
		
		' а может быть драйв удален?
		For id =  0  To UBound(arrDrv)
			remDrv = True ' предположим... 
			For idt = 0 To UBound(arrDrvTmp)
				If arrDrv(id) = arrDrvTmp(idt) Then 
					remDrv = False ' нет, живой...
					idt = UBound(arrDrvTmp) ' дальше можно не проверять
				End If
			Next
			If remDrv Then ' ага, диск пропал!
				removedDrv = True
				id = UBound(arrDrv) ' дальше можно не проверять
			End If
		Next
		
		' обновление и отображение списка дисков в случае изменения
		If addedDrv Or removedDrv Then 
			ReDim arrDrv(UBound(arrDrvTmp))
			For id =  0  To UBound(arrDrvTmp)
				arrDrv(id) = arrDrvTmp(id)
			Next

			' теперь покажем новый список дисков
			str = ""
			For id = 0 To UBound(arrDrv)
				str = str & arrDrv(id) & vbCrLf
			Next
			If addedDrv Then
				WSHShell.Popup str, 2, "Диск добавлен"
			Else
				WSHShell.Popup str, 2, "Диск удален"
			End If
		End If
		WScript.Sleep 1000 '  1  секунда задержки
	Loop
	
</script>
</job>