;
; AutoIt Version: 3.0
; Language:       English
; Platform:       Win9x/NT
; (c) AndreTM, 2010

If WinExists(@ScriptName) Then Exit
AutoItWinSetTitle(@ScriptName)

$nTimerMsg=5

$sINIFileName=@WorkingDir & "\" & StringLeft(@ScriptName,StringInStr(@ScriptName,".",0,-1)) & "ini"
If Not FileExists($sINIFIleName) Then
	IniWriteSection($sINIFileName, "Site", "Url=http://" & @LF & "Title=" & @LF & "Timer=300")
    MsgBox(4096, "Error", "Error occurred, missing INI file." & @CRLF & "Filling it with real data", $nTimerMsg)
	Exit
EndIf

$aINISectionSite = IniReadSection($sINIFileName, "Site")
If @error Then 
    MsgBox(4096, "Error", "Error occurred, probably wrong INI file (missing [Site] section).", $nTimerMsg)
	Exit
Else
    For $i = 1 To $aINISectionSite[0][0]
		Switch $aINISectionSite[$i][0]
		Case "Title"
			$sMyWindowTitle=$aINISectionSite[$i][1]
			If StringLen($sMyWindowTitle)=0 or StringIsSpace($sMyWindowTitle) Then
				MsgBox(4096, "Error", "Error occurred, wrong INI file section [Site]." & @CRLF & "Key 'Title' must be not empty.", $nTimerMsg)
				Exit
			EndIf
		Case "Timer"
			$nTimer=Number($aINISectionSite[$i][1])
			If $nTimer<=0 Then
				MsgBox(4096, "Error", "Error occurred, wrong INI file section [Site]." & @CRLF & "Key 'Timer' must be a number.", $nTimerMsg)
				Exit
			EndIf
		EndSwitch	
    Next
EndIf

	Beep(1200, 100)
	Sleep(100)
	Beep(1000, 100)
	Sleep(100)
	Beep(1200, 100)
	Sleep(100)
	
AutoItSetOption("WinTitleMatchMode",2)

$hMyWindow=""

HotKeySet('^!{PAUSE}', '_Exit')

While 1
	Sleep(1000*$nTimer)
	$aWinList=WinList($sMyWindowTitle)
	For $i = 1 to $aWinList[0][0]
		ControlSend($aWinList[$i][1],"","","{F5}")
	Next
Wend


Func _Exit()
	Beep(1000, 100)
	Sleep(100)
	Beep(1200, 100)
	Sleep(100)
	Beep(1000, 100)
	Sleep(100)
    Exit
EndFunc   ;==>_Exit