Dim objEmail
Set objEmail = WScript.CreateObject("CDO.Message")
objEmail.From = "Отправитель <server@sql.ru>;"
objEmail.To = "Получатель <admin@sql.ru>;"
objEmail.Subject = "Хозяин неправильно ввели пароль 3 раза. Лови отчёт."
objEmail.BodyPart.Charset = "windows-1251"
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost"
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Item("urn:schemas:mailheader:content-language") = "windows-1251"
objEmail.Configuration.Fields.Update
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate, (Security)}!\\" & _
        strComputer & "\root\cimv2")

Set colMonitoredEvents = objWMIService.ExecNotificationQuery _    
    ("Select * from __instancecreationevent where " _
        & "TargetInstance isa 'Win32_NTLogEvent' " _
            & "and TargetInstance.EventCode = '4625' ")
i=0
Do	
	i=i+1
    Set objLatestEvent = colMonitoredEvents.NextEvent
		strAlertToSend = objLatestEvent.TargetInstance.User _ 
		& "Запись №.: " & objLatestEvent.TargetInstance.RecordNumber & VbCrLf _
		& objLatestEvent.TargetInstance.TimeWritten & VbCrLf _ 
		& "Источник: " & objLatestEvent.TargetInstance.SourceName & VbCrLf _
		& "Категория: " & objLatestEvent.TargetInstance.CategoryString & VbCrLf _
		& "Тип события: " & objLatestEvent.TargetInstance.Type & VbCrLf _
		& "Компьютер: " & objLatestEvent.TargetInstance.ComputerName & VbCrLf _
		& "Пользователь: " & objLatestEvent.TargetInstance.User & VbCrLf _
		& "Сообщение: " & objLatestEvent.TargetInstance.Message
		if (i = 3) then			
			objEmail.Textbody = strAlertToSend			
			objEmail.Send
			'Wscript.Echo "Сообщение отослано"
			i=0
		End If		
Loop