CONST servername="192.168.1.2"

'Функция Alive() получает имя компьютера в локальной сети (или ip-адрес) и 
'возвращает True, если компьютер пингуется, и False в противном случае 
Function Alive(ByVal strHost) 
   Const SYSTEM_FOLDER = 1, TEMP_FOLDER = 2  ' константы FileSystemObject 
   Set objFSO = CreateObject("Scripting.FileSystemObject") 
   With objFSO 
      Do 
      strTempFile = .BuildPath(.GetSpecialFolder(TEMP_FOLDER), .GetTempName) 
      Loop While .FileExists(strTempFile) 

      strCmdLine = .BuildPath(.GetSpecialFolder(SYSTEM_FOLDER), "cmd.exe") _ 
         & " /c " & .BuildPath(.GetSpecialFolder(SYSTEM_FOLDER), "ping.exe") _ 
         & " -n 1 " & strHost & " > " & strTempFile 
   End With 
   CreateObject("Wscript.Shell").Run strCmdLine, 0, True 
   Set objRE = CreateObject("VBScript.RegExp") 
      objRE.Pattern = " TTL\=[0-9]{1,3}" 
   Set objTS = objFSO.OpenTextFile(strTempFile, 1) 
   Alive = objRE.Test(objTS.ReadAll) 
   objTS.Close 
   objFSO.DeleteFile strTempFile 
End Function 


if not Alive(servername) then

   strCmdLine = "cmd.exe /c net stop OpenVPNService" 
   CreateObject("Wscript.Shell").Run strCmdLine, 0, True 

   WScript.Sleep(15000)

   strCmdLine = "cmd.exe /c net start OpenVPNService" 
   CreateObject("Wscript.Shell").Run strCmdLine, 0, True 

end if