Public Function RegistrySaveKey(ByVal hKey As IntPtr, ByVal lpszSubKey As String, _
   ByVal lpFile As String, Optional ByVal SaveFlag As Integer = 0, _
   Optional ByVal reg64 As Boolean = False, Optional ByVal reg32 As Boolean = False) As Boolean
    'SaveFlag = 0 -используем RegSaveKey
    'SaveFlag = 1-3 -используем RegSaveKeyEx с указанием формата

    Dim dwRes As Integer
    Dim phkResult As IntPtr
    Dim hToken As IntPtr
    Dim bRtnBool As Boolean

    RegistrySaveKey = False 'default

    If IO.File.Exists(lpFile) Then
      Try
        IO.File.Delete(lpFile)
      Catch
        'Debug.Print("DeleteFile Error. Error code: " & Err.Number.ToString & " (" & Err.Description & ")")
        Exit Function
      End Try
    End If

    If reg64 Then
      dwRes = RegOpenKeyEx(hKey, lpszSubKey, 0, KEY_READ Or KEY_WOW64_64KEY, phkResult)
    ElseIf reg32 Then
      dwRes = RegOpenKeyEx(hKey, lpszSubKey, 0, KEY_READ Or KEY_WOW64_32KEY, phkResult)
    Else
      dwRes = RegOpenKeyEx(hKey, lpszSubKey, 0, KEY_READ, phkResult)
    End If
    If dwRes <> ERROR_SUCCESS Then
      'Debug.Print("RegOpenKeyEx Error " & RaiseAPIErrorByNumber(dwRes))
      Exit Function
    End If

    ' Open a handle to the access token for the calling process.
    bRtnBool = OpenProcessToken(Process.GetCurrentProcess().Handle, _
                            TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, _
                            hToken)
    If bRtnBool = False Then
      'Debug.Print("OpenProcessToken Error " & RaiseAPIErrorByNumber(Err.LastDllError))
      dwRes = Err.LastDllError
      GoTo cleanup
    End If

    'Enable the SE_BACKUP_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_BACKUP_NAME, True)
    If dwRes <> 0 Then
      Debug.Print("SetPrivilege (1) Error " & RaiseAPIErrorByNumber(dwRes))
      GoTo cleanup
    End If

    If SaveFlag = 0 Then
      dwRes = RegSaveKey(phkResult, lpFile, IntPtr.Zero)
      If dwRes <> ERROR_SUCCESS Then
        Debug.Print("RegSaveKey Error " & RaiseAPIErrorByNumber(dwRes))
      Else
        RegistrySaveKey = True
      End If
    Else
      dwRes = RegSaveKeyEx(phkResult, lpFile, 0, SaveFlag)
      If dwRes <> ERROR_SUCCESS Then
        Debug.Print("RegSaveKeyEx Error " & RaiseAPIErrorByNumber(dwRes))
      Else
        RegistrySaveKey = True
      End If
    End If

    'Disable the SE_BACKUP_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_BACKUP_NAME, False)
    If dwRes <> 0 Then
      Debug.Print("SetPrivilege (2) Error " & RaiseAPIErrorByNumber(dwRes))
    End If

cleanup:
    If hToken <> IntPtr.Zero Then CloseHandle(hToken)
    If phkResult <> IntPtr.Zero Then RegCloseKey(phkResult)

  End Function

  'Enabling and Disabling Privileges in C++
  'http://msdn.microsoft.com/en-us/library/windows/desktop/aa446619(v=vs.85).aspx
  Public Function SetPrivilege( _
   ByVal hToken As IntPtr, _
   ByVal lpszPrivilege As String, _
   ByVal bEnablePrivilege As Boolean) As Integer
    ' hToken - access token handle
    ' lpszPrivilege - name of privilege to enable/disable
    ' bEnablePrivilege - to enable or disable privilege

    Dim tP As New TOKEN_PRIVILEGES
    Dim New_tp As New TOKEN_PRIVILEGES
    Dim mLUID As New LUID
    If LookupPrivilegeValue("", lpszPrivilege, mLUID) = False Then
      Debug.Print("LookupPrivilegeValue Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    tP.PrivilegeCount = 1
    tP.pLuid = mLUID
    If bEnablePrivilege Then
      tP.Attributes = SE_PRIVILEGE_ENABLED
    Else
      tP.Attributes = 0
    End If
    If AdjustTokenPrivileges(hToken, False, tP, 4 + (12 * tP.PrivilegeCount), _
     New_tp, 4 + (12 * New_tp.PrivilegeCount)) = False Then
      Debug.Print("AdjustTokenPrivileges Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    If Err.LastDllError = ERROR_NOT_ALL_ASSIGNED Then
      Debug.Print("AdjustTokenPrivileges Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    'при успехе эта ф-ция вернет 0
    Return 0
  End Function