'Taking Object Ownership in C++
  'http://msdn.microsoft.com/en-us/library/windows/desktop/aa379620(v=vs.85).aspx
  Public Function SetSecurityOwner(ByVal pszObjName As String, _
   ByVal ObjectType As SE_OBJECT_TYPE, _
   ByVal AcctName As String, Optional ByVal DomnName As String = "") As Integer
    'назначает группу/аккаунт [DomnName + '\' +] AcctName владельцем объекта (по читаемому имени)

    'AcctName - account name, DomnName - domain name
    Dim AccountName As String 'на вход DomnName + '\' + AcctName

    Dim dwRes As Integer
    Dim hToken As IntPtr
    Dim p_abytSIDTarget() As Byte 'вместо pSIDTarget
    Dim pSIDTarget As IntPtr
    Dim dwSIDTarget As Integer 'size of the Sid buffer
    Dim DomainName As String = "" 'domain name на выходе
    Dim dwDomainName As Integer 'size of domain name buffer
    Dim eUse As Integer 'SID type
    Dim bRtnBool As Boolean

    If (pszObjName = "") Then
      SetSecurityOwner = ERROR_INVALID_PARAMETER
      'Debug.Print "ERROR_INVALID_PARAMETER"
      Exit Function
    End If

    'Create a SID for specified account
    If Strings.Len(DomnName) > 0 Then
      AccountName = DomnName & "\" & AcctName
    Else
      AccountName = AcctName
    End If
    'Preinitialize p_abytSIDAdmin array with one element. It will be redimmed lated
    ReDim p_abytSIDTarget(1)
    'First call to LookupAccountName to get the buffer sizes.
    bRtnBool = LookupAccountName(vbNullString, AccountName, p_abytSIDTarget, dwSIDTarget, _
     DomainName, dwDomainName, eUse)
    If (bRtnBool = False) And (Err.LastDllError <> ERROR_INSUFFICIENT_BUFFER) Then
      'Debug.Print("LookupAccountName (1) Error " & Err.LastDllError)
      dwRes = Err.LastDllError
      GoTo Cleanup
    End If

    'Debug.Print("dwSIDTarget=" & dwSIDTarget & vbCrLf & "dwDomainName=" & dwDomainName)

    'Allocate the required space in the p_abytSIDAdmin and DomainName string
    'variables. Allocate 1 byte less to avoid the appended NULL character.
    ReDim p_abytSIDTarget(dwSIDTarget)
    DomainName = Space(dwDomainName - 1)

    'Second call to LookupAccountName to get p_abytSIDAdmin.
    bRtnBool = LookupAccountName(vbNullString, AccountName, p_abytSIDTarget, dwSIDTarget, _
     DomainName, dwDomainName, eUse)
    If bRtnBool = False Then
      'Debug.Print("LookupAccountName (2) Error " & Err.LastDllError)
      dwRes = Err.LastDllError
      GoTo Cleanup
    End If

    'Debug.Print(DomainName)

    'If the preceding call failed because access was denied,
    'enable the SE_TAKE_OWNERSHIP_NAME privilege, create a SID for
    'Target group, take ownership of the object, and
    'disable the privilege. Then try again to set the object's DACL.

    ' Open a handle to the access token for the calling process.
    bRtnBool = OpenProcessToken(Process.GetCurrentProcess().Handle, _
                            TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, _
                            hToken)
    If bRtnBool = False Then
      'Debug.Print("OpenProcessToken Error " & Err.LastDllError)
      dwRes = Err.LastDllError
      GoTo Cleanup
    End If

    'Enable the SE_TAKE_OWNERSHIP_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_TAKE_OWNERSHIP_NAME, True)
    If dwRes <> 0 Then
      'Debug.Print("SetPrivilege (1) Error " & dwRes)
      GoTo Cleanup
    End If

    'Enable the SE_RESTORE_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_RESTORE_NAME, True)
    If dwRes <> 0 Then
      'Debug.Print("SetPrivilege (2) Error " & dwRes)
      GoTo Cleanup
    End If

    pSIDTarget = Marshal.AllocHGlobal(dwSIDTarget)
    Marshal.Copy(p_abytSIDTarget, 0, pSIDTarget, dwSIDTarget)
    'Set the owner in the object's security descriptor.
    dwRes = SetNamedSecurityInfo(pszObjName, ObjectType, _
     OWNER_SECURITY_INFORMATION, _
     pSIDTarget, IntPtr.Zero, IntPtr.Zero, IntPtr.Zero)
    If dwRes <> ERROR_SUCCESS Then
      'Debug.Print("SetNamedSecurityInfo Error " & CStr(dwRes) & RaiseAPIErrorByNumber(dwRes))
      GoTo Cleanup
    End If

    'Disable the SE_TAKE_OWNERSHIP_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_TAKE_OWNERSHIP_NAME, False)
    If dwRes <> 0 Then
      'Debug.Print "SetPrivilege (3) Error " & dwRes
      GoTo Cleanup
    End If

    'Disable the SE_RESTORE_NAME privilege.
    dwRes = SetPrivilege(hToken, SE_RESTORE_NAME, False)
    If dwRes <> 0 Then
      'Debug.Print "SetPrivilege (4) Error " & dwRes
      GoTo Cleanup
    End If

Cleanup:
    If hToken <> IntPtr.Zero Then CloseHandle(hToken)

    If Not pSIDTarget.Equals(0) Then
      Marshal.FreeHGlobal(pSIDTarget)
    End If

    SetSecurityOwner = dwRes

  End Function


  'Enabling and Disabling Privileges in C++
  'http://msdn.microsoft.com/en-us/library/windows/desktop/aa446619(v=vs.85).aspx
  Public Function SetPrivilege( _
   ByVal hToken As IntPtr, _
   ByVal lpszPrivilege As String, _
   ByVal bEnablePrivilege As Boolean) As Integer
    ' hToken - access token handle
    ' lpszPrivilege - name of privilege to enable/disable
    ' bEnablePrivilege - to enable or disable privilege

    Dim tP As New TOKEN_PRIVILEGES
    Dim New_tp As New TOKEN_PRIVILEGES
    Dim mLUID As New LUID
    If LookupPrivilegeValue("", lpszPrivilege, mLUID) = False Then
      Debug.Print("LookupPrivilegeValue Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    tP.PrivilegeCount = 1
    tP.pLuid = mLUID
    If bEnablePrivilege Then
      tP.Attributes = SE_PRIVILEGE_ENABLED
    Else
      tP.Attributes = 0
    End If
    If AdjustTokenPrivileges(hToken, False, tP, 4 + (12 * tP.PrivilegeCount), _
     New_tp, 4 + (12 * New_tp.PrivilegeCount)) = False Then
      Debug.Print("AdjustTokenPrivileges Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    If Err.LastDllError = ERROR_NOT_ALL_ASSIGNED Then
      Debug.Print("AdjustTokenPrivileges Error " & Err.LastDllError)
      SetPrivilege = Err.LastDllError
      Exit Function
    End If

    'при успехе эта ф-ция вернет 0
    Return 0
  End Function