Private Const ERROR_INSUFFICIENT_BUFFER = 122&

  'Well-known SIDs

  ' Identifier authority
  Public Const SECURITY_WORLD_SID_AUTHORITY = &H1 ' S-1-1 A group that includes all users.
  Public Const SECURITY_NT_AUTHORITY = &H5 'S-1-5

  ' Relative identifier authority
  Public Const SECURITY_WORLD_RID = &H0 'S-1-1 A group that includes all users.

  Public Const SECURITY_LOCAL_SYSTEM_RID = &H12 'S-1-5-18 A special account used by the operating system.
  Public Const SECURITY_BUILTIN_DOMAIN_RID = &H20& 'S-1-5-32 The built-in system domain.

  Public Const DOMAIN_ALIAS_RID_ADMINS = &H220& 'A local group used for administration of the domain.
  Public Const DOMAIN_ALIAS_RID_USERS = &H221& 'A local group that represents all users in the domain.

  Public Const DOMAIN_USER_RID_ADMIN = &H1F4 'The administrative user account in a domain.
  Public Const DOMAIN_USER_RID_GUEST = &H1F5 'The guest-user account in a domain. Users who do not have an account can automatically log on to this account.
  Public Const DOMAIN_GROUP_RID_ADMINS = &H200 'The domain administrators' group. This account exists only on systems running server operating systems.


  'Authorization Structures

  <StructLayout(LayoutKind.Sequential)>
  Public Structure SID_IDENTIFIER_AUTHORITY
    <MarshalAs(UnmanagedType.ByValArray, Sizeconst:=6)> Dim Value() As Byte
  End Structure

  'Authorization Functions
  Public Declare Function AllocateAndInitializeSid Lib "advapi32.dll" _
   (ByRef pIdentifierAuthority As SID_IDENTIFIER_AUTHORITY, _
   ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Integer, _
   ByVal nSubAuthority1 As Integer, ByVal nSubAuthority2 As Integer, _
   ByVal nSubAuthority3 As Integer, ByVal nSubAuthority4 As Integer, _
   ByVal nSubAuthority5 As Integer, ByVal nSubAuthority6 As Integer, _
   ByVal nSubAuthority7 As Integer, ByRef lpPSid As IntPtr) As Boolean
  Public Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As IntPtr)
  Public Declare Unicode Function LookupAccountSid Lib "advapi32.dll" _
   Alias "LookupAccountSidW" (ByVal lpSystemName As String, _
   ByVal lpSid As IntPtr, ByVal lpName As String, ByRef cchName As Integer, _
   ByVal lpReferencedDomainName As String, _
   ByRef cchReferencedDomainName As Integer, ByRef peUse As Integer) As Boolean

  Public Function ConstructUniversalAndNTWellKnownSids(GroupName As String) As String
    'возвращает имя стандартной группы пользователей на языке OS (рус,английский)

    ConstructUniversalAndNTWellKnownSids = ""

    Dim siaNtAuthority As New SID_IDENTIFIER_AUTHORITY
    Dim lSid As IntPtr

    Select GroupName
      Case "SYSTEM"
        ' Construct SID for System "NT well-known SID" ("SYSTEM")
        siaNtAuthority.Value = {0, 0, 0, 0, 0, SECURITY_NT_AUTHORITY}
        'siaNtAuthority.Value(5) = SECURITY_NT_AUTHORITY
        If AllocateAndInitializeSid(siaNtAuthority, 1, _
         SECURITY_LOCAL_SYSTEM_RID, 0, 0, 0, 0, 0, 0, 0, lSid) Then
          AddLog("  Calling AllocateAndInitializeSid... Done.")
          ' Use the constructed SID in the application
          ConstructUniversalAndNTWellKnownSids = DisplayNameOfSid(lSid)
          ' Free the memory allocated for the SID using FreeSid() API
          FreeSid(lSid)
        Else
          AddLog("  Calling AllocateAndInitializeSid... Failed. Error code: " & RaiseAPIError())
        End If

      Case "Everyone"
        ' Construct SID for Everyone "Universal well-known SID" ("Everyone")
        siaNtAuthority.Value = {0, 0, 0, 0, 0, SECURITY_WORLD_SID_AUTHORITY}
        If AllocateAndInitializeSid(siaNtAuthority, 1, _
         SECURITY_WORLD_RID, 0, 0, 0, 0, 0, 0, 0, lSid) Then
          AddLog("  Calling AllocateAndInitializeSid... Done.")
          ' Use the constructed SID in the application
          ConstructUniversalAndNTWellKnownSids = DisplayNameOfSid(lSid)
          ' Free the memory allocated for the SID using FreeSid() API
          FreeSid(lSid)
        Else
          AddLog("  Calling AllocateAndInitializeSid... Failed. Error code: " & RaiseAPIError())
        End If

      Case "Administrators"
        ' Construct SID for Administrators "Well-known group" ("Administrators")
        siaNtAuthority.Value = {0, 0, 0, 0, 0, SECURITY_NT_AUTHORITY}
        If AllocateAndInitializeSid(siaNtAuthority, 2, _
         SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, _
         0, 0, 0, 0, 0, 0, lSid) Then
          AddLog("  Calling AllocateAndInitializeSid... Done.")
          ' Use the constructed SID in the application
          ConstructUniversalAndNTWellKnownSids = DisplayNameOfSid(lSid)
          ' Free the memory allocated for the SID using FreeSid() API
          FreeSid(lSid)
        Else
          AddLog("  Calling AllocateAndInitializeSid... Failed. Error code: " & RaiseAPIError())
        End If

      Case "Users"
        ' Construct SID for Users "Well-known group" ("Users")
        siaNtAuthority.Value = {0, 0, 0, 0, 0, SECURITY_NT_AUTHORITY}
        If AllocateAndInitializeSid(siaNtAuthority, 2, _
         SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_USERS, _
         0, 0, 0, 0, 0, 0, lSid) Then
          AddLog("  Calling AllocateAndInitializeSid... Done.")
          ' Use the constructed SID in the application
          ConstructUniversalAndNTWellKnownSids = DisplayNameOfSid(lSid)
          ' Free the memory allocated for the SID using FreeSid() API
          FreeSid(lSid)
        Else
          AddLog("  Calling AllocateAndInitializeSid... Failed. Error code: " & RaiseAPIError())
        End If

      Case Else
    End Select
    If ConstructUniversalAndNTWellKnownSids <> "" Then _
     AddLog("    UsersGroupName: " & ConstructUniversalAndNTWellKnownSids & " ...OK")
  End Function

  Public Function DisplayNameOfSid(ByVal lSid As Long) As String
    ' Helper function to lookup a SID and display the name as a test

    Dim peUse As Integer
    ' Lookup the constructed SID to get the name
    Dim UserName As String = ""
    Dim DomainName As String = ""
    Dim cbUserName As Integer
    Dim cbDomainName As Integer
    'First call to LookupAccountSid to get the buffer sizes.
    If (LookupAccountSid(vbNullString, lSid, UserName, cbUserName, _
     DomainName, cbDomainName, peUse) = False) And (Err.LastDllError <> ERROR_INSUFFICIENT_BUFFER) Then
      AddLog("    Calling LookupAccountSid... Failed. Error code: " & RaiseAPIError())
      DisplayNameOfSid = ""
      Exit Function
    End If
    'Allocate the required space in the UserName and DomainName string
    'variables. Allocate 1 byte less to avoid the appended NULL character.
    UserName = Space(cbUserName - 1)
    DomainName = Space(cbDomainName - 1)
    If LookupAccountSid(vbNullString, lSid, UserName, cbUserName, _
     DomainName, cbDomainName, peUse) Then
      AddLog("    Calling LookupAccountSid... Done.")
      DisplayNameOfSid = UserName
    Else
      AddLog("    Calling LookupAccountSid... Failed. Error code: " & RaiseAPIError())
      DisplayNameOfSid = ""
    End If

  End Function