Здравствуйте, <Аноним>, Вы писали:

А>Доброго времени суток.
А>Возник такой вопрос — как программно создать виртуальную директорию IIS с заданным именем и заданным физическим путем?


' Create an instance of the virtual directory object
' that represents the default Web site.
Set IIsWebVDirRootObj = GetObject("IIS://localhost/W3SVC/1/Root")

' Use the Windows ADSI container object "Create" method to create
' a new virtual directory.

dim args, virtDirName, realDir, fso
Set args = WScript.Arguments
Set fso = CreateObject("Scripting.FileSystemObject")

' Set web root path
if args.Count > 1 then
    realDir = args(0)
    virtDirName = args(1)
else
    realDir = fso.GetAbsolutePathName(".") & "\MyVirtualDir"
    virtDirName = "VirtualDirName"
end if

' Create virtual directory for main web application
CreateWebVDir virtDirName, realDir, 1, "Comments go here"

'''''''''''''''''''''' T H E    E N D '''''''''''''''''''''''''''''''''''''

' -------------------------------------------------------------------------
' Helper functions
' -------------------------------------------------------------------------

' protection {0: Low (INPROC) ; 1: High (OUTPROC); 2: Medium (POOLED)}.
sub CreateWebVDir ( virtDirName, _ 
                    realDir,     _ 
                    protection,  _ 
                    appName) 
    ' Set "read" permission for "everyone" on web-read folders
    call SetWebDirPerms( realDir )

    ' Delete virtual directory
    on error resume next
    IIsWebVDirRootObj.Delete "IIsWebVirtualDir", virtDirName
    on error goto 0

    'Clear cache for this virt directory - User Profile Path\VSWebCache\Server Name\virtDirName
    ClearCache virtDirName 

    Set IIsWebVDirObj = IIsWebVDirRootObj.Create("IIsWebVirtualDir", virtDirName)

    ' Use the Windows ADSI object "Put" method to
    ' set some required properties.
    IIsWebVDirObj.Put "Path", realDir
    IIsWebVDirObj.Put "AccessRead", True
    IIsWebVDirObj.Put "AccessScript", True

    ' Use the AppCreate2 method of the IIS ADSI provider to
    ' create an application on the new virtual directory.
    IIsWebVDirObj.AppCreate2 protection
    IIsWebVDirObj.Put "AppFriendlyName", appName '

    ' Use the Windows ADSI object "SetInfo" method to
    ' save the data to the metabase.
    IIsWebVDirObj.SetInfo

end sub


'  set permissions on the web-server-accessed folders to "read" by "everyone"
sub SetWebDirPerms( folderPath )
    dim wshShell, env
    ' create shell object
    set wshShell = CreateObject("WScript.Shell")
    ' create environment object for that shell
    Set env = wshShell.Environment("Process")
    ' set env variables for use by script batch
    env("FOLDER_PATH") = folderPath
    wshShell.Run "SET_PERMS.BAT", 1, true
end sub


'Clear cache for this virt directory - User Profile Path\VSWebCache\Server Name\virtDirName
sub ClearCache( virtDirName )
    Dim wshShell, env, cacheDir
    Set wshShell = CreateObject("WScript.Shell")
    Set env = wshShell.Environment("Process")
    cacheDir = env("USERPROFILE") & "\VSWebCache\" & env("COMPUTERNAME") & "\" & virtDirName
    If fso.FolderExists(cacheDir) Then
        fso.DeleteFolder cacheDir, True
    End If
end subhttp://www.qulix.com — Разработка систем любой направленности и сложности