Option Explicit
Option Base 0
Option Compare Binary

Rem модуль bas_memo2


 Rem получение построенного заполненного первоначальными данными буфера
 Private Function get_c_buffer(ByVal n As Long) As cls_cyrcle_vbuffer
  Dim o_buffer As cls_cyrcle_vbuffer
  Set o_buffer = New cls_cyrcle_vbuffer
  o_buffer.Init n
  Set get_c_buffer = o_buffer
 End Function

Function F(ByVal n As Long, ByVal k As Long) As Variant
  Rem требуется n> 0, k >= 0
  
  Dim cn_Zero As Variant
  Dim cn_One As Variant
  cn_Zero = CDec(0)
  cn_One = CDec(1)
  
  If n = 1 Then
    F = cn_Zero
    Exit Function
  End If
  If k < n Then
    F = k
    Exit Function
  End If
  
  Rem получаем буфер
  Dim o_buffer As cls_cyrcle_vbuffer
  Set o_buffer = get_c_buffer(n)
  '-------------------------
  Dim n_sign As Variant, x_value As Variant
  Dim i As Long, j As Long
  
  Rem считаем k-n+1 значений последовательности
  For i = 1 To k - n + 1
    x_value = cn_Zero
    n_sign = cn_One
    Rem цикл расчета одного значения
    For j = 1 To n
      x_value = x_value + (n_sign * j * o_buffer.read_Next_Backward)
      n_sign = -n_sign
    Next j
    Rem помещаем свежерасчитанное значение в буфер
    o_buffer.insert_next x_value
    o_buffer.Rewind_To_Insert_Pos
  Next i

  F = o_buffer.Last_Inserted
    
End Function

Option Explicit
Option Base 0
Option Compare Binary
Rem класс cls_cycle_vbuffer , работает как кольцевой буфер
'----------------------------------
Const ci_Low_end As Long = 0

Rem флаг завершения построения буфера с первоначальным заполнением
Private pb_inited As Boolean

Rem размер буфера
Private p_Size As Long

Rem точка вставки в буфер
Private pi_insert_pos As Long

Rem точка начала обратного чтения
Private pi_backward_read_pos As Long

Rem массив для буфера
Private a_buffer() As Variant

Property Get Size() As Long
  Size = p_Size
End Property

Rem вставка в следующий элемент буфера
Sub insert_next(pn_nextval As Variant)
  Rem смещение позиции вставки
  Dim pos As Long
  pos = pi_insert_pos
  pos = pos + 1
  If (pos >= Size) Then
    pos = ci_Low_end
  End If
  pi_insert_pos = pos
  
  Rem установка значения
  a_buffer(pi_insert_pos) = pn_nextval
 
End Sub

Rem переустановка позиции чтения в последнюю вставленную запись
Sub Rewind_To_Insert_Pos()
 pi_backward_read_pos = pi_insert_pos
End Sub

Rem инициализация буфера размера n и заполнение числами от о до n-1
Sub Init(ByVal n As Long)
  
  ReDim a_buffer(0 To n - 1) As Variant
    
  p_Size = n
  Dim iPos As Long
  For iPos = 0 To n - 1
    insert_next CDec(iPos)
  Next iPos
  Rewind_To_Insert_Pos
  
  pb_inited = True
End Sub

Rem итерируем назад
Property Get read_Next_Backward() As Variant
  Dim iPos As Long
  Dim x_val As Variant
  Rem сначала читаем
  iPos = pi_backward_read_pos
  x_val = a_buffer(iPos)
    
  Rem затем смещаем позицию
  iPos = iPos - 1
  If iPos < ci_Low_end Then
    iPos = Size - 1
  End If
  pi_backward_read_pos = iPos
  read_Next_Backward = x_val
End Property

Rem плучение последнего вставленного значения
Property Get Last_Inserted() As Variant
  Last_Inserted = a_buffer(pi_insert_pos)
End Property

Private Sub Class_Terminate()
  If pb_inited Then
    Erase a_buffer
  End If
End Sub