MESSAGEBOX(FSumString(999999999999.99))

* //  СУММА ПРОПИСЬЮ  min - 0, max - 999999999999.99
FUNCTION	FSumString(n)
LOCAL	i,s,r,ss,c

n=iif(empty(n) .or. vartype(n)!='N',0,iif(n<0,0-n,n))
r=""
s=str(n,15,2)
FOR	i=1	to	10	STEP	3
	ss=substr(s,i,3)
	if	ss!=space(3)
		c=substr(ss,1,1)
		c=icase(c='1','сто ',c='2','двести ',c='3','триста ',c='4','четыреста ',c='5','пятьсот ',c='6','шестьсот ',c='7','семьсот ',c='8','восемьсот ',c='9','девятьсот ','')
		r=r+c
		if	substr(ss,2,1)="1"
			c=substr(ss,3,1)
			c=icase(c='0','десять ',c='1','одиннадцать ',c='2','двенадцать ',c='3','тринадцать ',c='4','четырнадцать ',c='5','пятнадцать ',c='6','шестнадцать ',c='7','семнадцать ',c='8','восемнадцать ',c='9','девятнадцать ','')
			r=r+c+icase(i=1,'миллиардов ',i=4,'миллионов ',i=7,'тысяч ',i=10,'рублей ','')
		else
			c=substr(ss,2,1)
			c=icase(c='2','двадцать ',c='3','тридцать ',c='4','сорок ',c='5','пятьдесят ',c='6','шестьдесят ',c='7','семьдесят ',c='8','восемьдесят ',c='9','девяносто ','')
			r=r+c
			c=substr(ss,3,1)
			do	case
				case	c='0'
					c=icase(i=1,'миллиардов ',i=4,'миллионов ',i=7,'тысяч ','рублей ')
				case	c='1'
					c=iif(i=7,'одна тысяча ','один '+iif(i=1,'миллиард ',iif(i=4,'миллион ','рубль ')))
				case	c='2'
					c=iif(i=7,'две тысячи ','два '+iif(i=1,'миллиарда ',iif(i=4,'миллиона ','рубля ')))
				case	c='3'
					c=iif(i=7,'три тысячи ','три '+iif(i=1,'миллиарда ',iif(i=4,'миллиона ','рубля ')))
				case	c='4'
					c=iif(i=7,'четыре тысячи ','четыре '+iif(i=1,'миллиарда ',iif(i=4,'миллиона ','рубля ')))
				case	c='5'
					c=iif(i=7,'пять тысяч ','пять '+iif(i=1,'миллиардов ',iif(i=4,'миллионов ','рублей ')))
				case	c='6'
					c=iif(i=7,'шесть тысяч ','шесть '+iif(i=1,'миллиардов ',iif(i=4,'миллионов ','рублей ')))
				case	c='7'
					c=iif(i=7,'семь тысяч ','семь '+iif(i=1,'миллиардов ',iif(i=4,'миллионов ','рублей ')))
				case	c='8'
					c=iif(i=7,'восемь тысяч ','восемь '+iif(i=1,'миллиардов ',iif(i=4,'миллионов ','рублей ')))
				case	c='9'
					c=iif(i=7,'девять тысяч ','девять '+iif(i=1,'миллиардов ',iif(i=4,'миллионов ','рублей ')))
			endcase
			r=r+c
		endif
	endif
ENDFOR
s=substr(s,14,2)
ss=substr(s,1,1)
c=substr(s,2,1)
r=r+s+iif(ss='1' .or. ss='0',' копеек',icase(c>'4',' копеек',c='1',' копейка',c>'1' .and. c<'5',' копейки',''))
r=iif(n<1,'Ноль ','')+upper(substr(r,1,1))+substr(r,2)
RETURN	r