.model tiny
.586p
.code
org 100h
start:
 push 0E00h ; lba 16..27 пол байта параметров 0Eh
 push 0000h ; lba 0..15
 push 01f0h ; передаём базовый порт hdd
 call read_sector
ret

read_sector proc
 push ax ; сохраняем используемые регистры
 push dx
 push bp
 push bx
 push cx
 push di
  mov ax, sp ; устанавливаем базу на смещение данных в стэке
  add ax, 14d
  mov bp, ax
  mov bx, ss:[bp] ; теперь bx указывает на базовый порт hdd
  mov dx, bx ; направляем dx на порт состояния hdd (у нас 03F6h)
  add dx, 0206h
  mov al, 2h ; запрещаем прерывания данному устройству
  out dx, al
  push bx ; базовый адрес портов hdd 
  call wait_bsy ; ждём освобождение канала
  mov dx, bx ; записываем в dx 01F6h
  add dx, 6h 
  mov al, ss:[bp+5] ; вытягиваем из стэка с байтом LBA[24-27] и пол байтом параметров 1110b
  or al, 0E0h ; для уверенности что используется система LBA адресации
  out dx, al ; выбираем устройство
  push bx
  call wait_bsy ; ждём освобождение канала
  push bx
  call wait_dsdy ; ждём готовность устройства принять команду 
  mov dx, bx ; читать будем только 1 сектор сообщаем об этом через порт 01F2h
  add dx, 2d
  mov al, 1h
  out dx, al
  inc dx ;              LBA[0-7] пишем в 01F3h
  mov al, ss:[bp+2]
  out dx, al
  inc dx ;              LBA[8-15] пишем в 01F4h
  mov al, ss:[bp+3]
  out dx, al
  inc dx ;              LBA[16-23] пишем в 01F5h
  mov al, ss:[bp+4]
  out dx, al
  mov dx, bx ; записываем в dx 01F7h и отправляем в этот порт команду 20h (чтение сектора)
  add dx, 7d
  mov al, 20h
  out dx, al
  mov dx, bx ; отправляем в стэк номер альтернативного регистора состояния - 7 (функция добавит автоматом)
  add dx, 01FFh
  push dx
  call wait_bsy ; ждём пока канал занят
  push bx
  call wait_hdd_data ; ждём готовность информации
  cld
  lea di, sect_buff ; направляем ds:di на буффер для чтения сектора
  mov cx, 100h
  mov dx, bx
  rep insw
  mov dx, bx
  add dx, 01FFh ; разрешаем прерывания
  mov al, 0h
  out dx, al
 pop di ;         восстанавливаем использованые регистры
 pop cx
 pop bx
 pop bp
 pop dx
 pop ax
 ret 6d
read_sector endp

wait_bsy proc ;   процедура ожидания освобождения канала
 push ax
 push dx
 push bp
  mov ax, sp ; читаем порт 1f7h пока 7-ой бит равен 1
  add ax, 8d
  mov bp, ax
  mov dx, ss:[bp]
  add dx, 7h
  @waiting:
   in al, dx
   test al, 80h
   jnz @waiting
 pop bp
 pop dx
 pop ax
 ret 2d
wait_bsy endp

wait_dsdy proc ; процедура ожидания готовности к приёму команд
 push ax
 push dx
 push bp
  mov ax, sp ; читаем порт 1f7h пока 6-ой бит равен 0
  add ax, 8d
  mov bp, ax
  mov dx, ss:[bp]
  add dx, 7h
  @waiting:
   in al, dx
   test al, 40h
   jz @waiting
 pop bp
 pop dx
 pop ax
 ret 2d
wait_dsdy endp

wait_hdd_data proc ; процедура ожидания готовности информации
 push ax
 push dx
 push bp
  mov ax, sp ; читаем порт 1f7h пока 3-ой бит равен 0
  add ax, 8d
  mov bp, ax
  mov dx, ss:[bp]
  add dx, 7h
  @waiting:
   in al, dx
   test al, 08h
   jz @waiting
  mov dx, ss:[bp]
  add dx, 1h
  in al, dx
 pop bp
 pop dx
 pop ax
 ret 2d
wait_hdd_data endp

 sect_buff db 200h dup (?) ; буффер для чтения сектора
end start