DECLARE SUB ProcessKeyExt (Msg AS ANY)
DECLARE SUB MoveCur (Msg AS ANY)
DECLARE SUB PutCross (Msg AS ANY)
DECLARE SUB PutZerro (Msg AS ANY)
DECLARE SUB SetCursor (x AS LONG, y AS LONG)
DECLARE SUB DrawUI ()
DECLARE SUB InitProc ()
DECLARE SUB IdleProc ()
DECLARE SUB ProcessKey (Msg AS ANY)
DECLARE SUB NewMsg (code AS INTEGER, wParam AS LONG, lParam AS LONG, Msg AS ANY)
DECLARE SUB MainLoop ()
DECLARE SUB GetMsg (Msg AS ANY)
DECLARE SUB PutMsg (Msg AS ANY)
TYPE TRect
  x AS LONG
  y AS LONG
END TYPE
TYPE TMsg
  Msg AS INTEGER
  wParam AS LONG
  lParam AS LONG
END TYPE

CONST MsgQueueSize =  100 
CONST UIHeight =  3 
CONST UIWidth =  3 

DIM SHARED UIPict(UIWidth, UIHeight) AS STRING *  1 
DIM SHARED Cur AS TRect
DIM SHARED MsgQueue(MsgQueueSize) AS TMsg
DIM SHARED MsgHead AS INTEGER
DIM SHARED MsgTail AS INTEGER
DIM SHARED OldV AS STRING *  1 


CONST MsgNone =  0 
CONST MsgUp =  1 
CONST MsgDown =  2 
CONST MsgLeft =  3 
CONST MsgRight =  4 
CONST MsgKey =  5 
CONST MsgKeyExt =  6 
CONST MsgDraw =  7 
CONST MsgCross =  8 
CONST MsgZerro =  9 
CONST MsgQuit = - 1 

CALL InitProc
CALL MainLoop







SUB DrawUI
FOR y% =  1  TO UIHeight
  FOR x% =  1  TO UIWidth
    LOCATE y%, x%,  0 
    PRINT UIPict(x%, y%);
  NEXT
NEXT
SetCursor Cur.x, Cur.y
END SUB

SUB GetMsg (Msg AS TMsg)
IF MsgHead <> MsgTail THEN
  Msg = MsgQueue(MsgTail)
  MsgTail = MsgTail +  1 
  IF MsgTail > MsgQueueSize THEN MsgTail =  1 
ELSE
  Msg.Msg = MsgNone

END IF
END SUB

SUB IdleProc
DIM Msg AS TMsg
ch$ = INKEY$
IF LEN(ch$) =  1  THEN
  NewMsg MsgKey, ASC(ch$),  0 , Msg
  CALL PutMsg(Msg)
ELSE
  IF LEN(ch$) =  2  THEN
    NewMsg MsgKeyExt, ASC(MID$(ch$,  2 ,  1 )),  0 , Msg
    CALL PutMsg(Msg)
  END IF
END IF

END SUB

SUB InitProc
DIM Msg AS TMsg
MsgHead =  1 
MsgTail =  1 

FOR y% =  1  TO UIHeight
  FOR x% =  1  TO UIWidth
    UIPict(x%, y%) = "."
  NEXT
NEXT

NewMsg MsgDraw,  0 ,  0 , Msg
PutMsg Msg
Cur.x =  2 
Cur.y =  2 
CLS

END SUB

SUB MainLoop
DIM Msg AS TMsg
cont =  1 
WHILE cont =  1 
  IdleProc
  GetMsg Msg
  SELECT CASE Msg.Msg
  CASE MsgQuit
    cont =  0 
  CASE MsgKey
    ProcessKey Msg
  CASE MsgKeyExt
    ProcessKeyExt Msg
  CASE MsgDraw
    DrawUI
  CASE MsgCross
    PutCross Msg
  CASE MsgZerro
    PutZerro Msg
  CASE MsgUp TO MsgRight
    MoveCur Msg
  END SELECT
WEND




END SUB

SUB MoveCur (Msg AS TMsg)
DIM x AS LONG
DIM y AS LONG
x = Cur.x
y = Cur.y
SELECT CASE Msg.Msg
  CASE MsgUp
    y = y -  1 
  CASE MsgDown
    y = y +  1 
  CASE MsgRight
    x = x +  1 
  CASE MsgLeft
    x = x -  1 
END SELECT
IF x <  1  OR x > UIWidth THEN EXIT SUB
IF y <  1  OR y > UIHeight THEN EXIT SUB
CALL SetCursor(x, y)

END SUB

SUB NewMsg (code AS INTEGER, wParam AS LONG, lParam AS LONG, Msg AS TMsg)
Msg.Msg = code
Msg.wParam = wParam
Msg.lParam = lParam
END SUB

SUB ProcessKey (Msg AS TMsg)
SELECT CASE Msg.wParam
CASE  27 
  NewMsg MsgQuit,  0 ,  0 , Msg
  PutMsg Msg
CASE ASC("x"), ASC("X")
  NewMsg MsgCross, Cur.x, Cur.y, Msg
  PutMsg Msg
CASE ASC("o"), ASC("O"), ASC("0")
  NewMsg MsgZerro, Cur.x, Cur.y, Msg
  PutMsg Msg
END SELECT
  
END SUB

SUB ProcessKeyExt (Msg AS TMsg)
SELECT CASE Msg.wParam
  CASE ASC("M")
    NewMsg MsgRight,  0 ,  0 , Msg
    PutMsg Msg
  CASE ASC("K")
    NewMsg MsgLeft,  0 ,  0 , Msg
    PutMsg Msg
  CASE ASC("H")
    NewMsg MsgUp,  0 ,  0 , Msg
    PutMsg Msg
  CASE ASC("P")
    NewMsg MsgDown,  0 ,  0 , Msg
    PutMsg Msg
END SELECT

END SUB

SUB PutCross (Msg AS TMsg)
x% = Msg.wParam
y% = Msg.lParam
UIPict(x%, y%) = "X"
NewMsg MsgDraw,  0 ,  0 , Msg
PutMsg Msg
END SUB

SUB PutMsg (Msg AS TMsg)
MsgQueue(MsgHead) = Msg
MsgHead = MsgHead +  1 
IF MsgHead > MsgQueueSize THEN MsgHead =  1 
END SUB

SUB PutZerro (Msg AS TMsg)
x% = Msg.wParam
y% = Msg.lParam
UIPict(x%, y%) = "O"
NewMsg MsgDraw,  0 ,  0 , Msg
PutMsg Msg

END SUB

SUB SetCursor (x AS LONG, y AS LONG)
IF x <  1  OR x > UIWidth THEN EXIT SUB
IF y <  1  OR y > UIWidth THEN EXIT SUB
LOCATE y, x,  1 
Cur.x = x
Cur.y = y


END SUB