можно использовать FileSystemObject, вот кстати некий Билл написал такой скрипт ;)

You are welcome to play around with this script I wrote some time in the
past. It gives more information than you need, but not too hard to strip
that.

Option Explicit
Dim fso, WshShell
Set fso = CreateObject("Scripting.FileSystemObject")
Set WshShell = WScript.CreateObject("WScript.Shell")
'
Dim s, CountTgt, FileDesc, CountFiles, CountSubs
Dim SrchDir, FileType, File, Subfldr
Dim StartTime, EndTime, ElapsedTime
'
CountTgt = 0
CountFiles = 0
CountSubs = 0
StartTime = Now
'
SrchDir = "c:"
FileType = "vbs"
Count(SrchDir)
'
EndTime = Now
ElapsedTime = DateDiff("s", StartTime, EndTime)
'
Dim L1, L2, L3, L4, L5, L6, OutFile, Results
L1 = "Specified Search Directory: " & _
UCase(SrchDir) & vbcrlf
L2 = "Specified File Search: " & "." & UCase(FileType) & _
" - " & FileDesc & vbcrlf & vbcrlf
L3 = "There are " & CountFiles & " files and " & CountSubs & _
" folders in " & UCase(SrchDir) & vbcrlf & vbcrlf
L4 = "Search Results: " & CountTgt & " ." & UCase(FileType) & _
" files found. "
L5 = "Search time: " & ElapsedTime & " seconds" & vbcrlf
L6 = "================================"
Set fso = CreateObject("Scripting.FileSystemObject")
OutFile = fso.GetSpecialFolder(2) & "\" & _
UCase(FileType) & "list.txt"
'
Set Results = fso.CreateTextFile(OutFile, True)
Results.Write L1 & L2 & L3 & L4 & L5 & L6 & L6 & vbcrlf & s
Results.Close
WshShell.Run OutFile
'
Sub Count(path)
For each File in fso.GetFolder(path).Files
CountFiles = CountFiles + 1
If UCase(fso.GetExtensionName(File.Name))=UCase(FileType) Then
s = s & File.Path & vbcrlf
CountTgt = CountTgt + 1
FileDesc = File.Type
End If
Next
For each Subfldr in fso.GetFolder(path).SubFolders
CountSubs = CountSubs + 1
Count(SubFldr)
Next
End Sub

Bill James