global type f_strtoarray from function_object
end type

forward prototypes
global function integer f_strtoarray (string value, character divchar, ref string result[])
end prototypes

global function integer f_strtoarray (string value, character divchar, ref string result[]); /*************************************************************
Description:
------------
  Converting string with list values from div char to string array

Return value:
-------------
  Count items from array

Revision history:
-----------------
  1.0  Initial version
*************************************************************/ 
string l[]
result = l

if Len( value ) =  0  then
  return  0 
end if

int b, p, c, w
p =  1 
c =  0 
w = Len( divChar )
b = Pos( value, divChar,  1  )
do while b >  0 
  c++
  l[c] = Mid( value, p, b - p)
  p = b + w
  b = Pos( value, divChar, p)
loop

if p <= Len( value ) then
  c++
  l[c] = Mid( value, p )
end if

result = l

return c
end function

global type f_librarypath from function_object
end type

forward prototypes
global function string f_librarypath (string libraryname)
end prototypes

global function string f_librarypath (string libraryname); /*************************************************************
Description:
------------
  Return path from library

Return value:
-------------
  Path from library or NULL if library in library list not found

Revision history:
-----------------
  1.0  Initial version
*************************************************************/ 

string s
SetNull( s )

if Len( libraryName ) =  0  then
  return s
end if

libraryName = '\' + Lower( Trim( libraryName ) )

string libs[]
int c, p, i
c = f_StrToArray( GetLibraryList(), ',', libs )

for i =  1  to c
  p = LastPos( Lower( libs[i]), libraryName )
  if p >  0  then
    return Mid( libs[i],  1 , p -  1  )
  end if
end for

return s
end function

MessageBox( 'Path', f_LibraryPath( 'asc_system.pbl' ) )