<?xml version=' 1 . 0 '?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fox="http://xmlgraphics.apache.org/fop/extensions"
                xmlns:fo="http://www.w3.org/1999/XSL/Format"
                version=' 1 . 0 '>
<!-- ****************************************************************
     $Id: fop1.xsl 8913 2010-10-01 04:44:57Z bobstayton $
     ****************************************************************
     This file is part of the XSL DocBook Stylesheet distribution.
     See ../README or http://docbook.sf.net/release/xsl/current/ for
     copyright and other information.
**************************************************************** -->

<!-- ======================================================= -->
<!-- ЗДЕСЬ УБРАН КУСОК, РАБОТАЮЩИЙ С BOOKMARK'АМИ -->
<!-- ======================================================= -->

<!-- Metadata support ("Document Properties" in Adobe Reader) -->
<!-- Подключено преобразование в транслит для метаинфы PDF взамен внешней утилиты PDFTK -->
<!-- Шаблон строковых замен взят из книги "Технология XSLT" Алексея Валикова, -->
<!-- шаблон непосредственного преобразования подсказал refreg с форума SQL.ru -->

<xsl:template name="fop1-document-information">
  <xsl:variable name="authors" select="(//author|//editor|//corpauthor|//authorgroup)[1]"/>

  <!-- Переменные для однобуквенных замен  -->
  <xsl:variable name="l-rus" select="'абвгдеёзийклмнопрстуфьыъэАБВГДЕЁЗИЙКЛМНОПРСТУФЬЫЪЭ'"/>
  <xsl:variable name="l-trans" select="'abvgdeеzijklmnoprstuf`y`eABVGDEEZIJKLMNOPRSTUF`Y`E'"/>

  <xsl:variable name="title">
    <xsl:apply-templates select="/*[1]" mode="label.markup"/>
    <xsl:apply-templates select="/*[1]" mode="title.markup"/>
    <xsl:variable name="subtitle">
      <xsl:apply-templates select="/*[1]" mode="subtitle.markup"/>
    </xsl:variable>
    <xsl:if test="$subtitle !=''">
      <xsl:text> - </xsl:text>
      <xsl:value-of select="$subtitle"/>
    </xsl:if>
  </xsl:variable>

  <fo:declarations>
    <x:xmpmeta xmlns:x="adobe:ns:meta/">
      <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#">
        <rdf:Description rdf:about="" xmlns:dc="http://purl.org/dc/elements/1.1/">
          <!-- Dublin Core properties go here -->

          <!-- Title -->
          <dc:title>
            <!-- Однобуквенная замена и вызов шаблона несколькобуквенных замен  -->
            <xsl:call-template name="replace-string">
              <xsl:with-param name="text-string"
                              select="normalize-space(translate($title,$l-rus,$l-trans))"/>
            </xsl:call-template>
          </dc:title>
          <!-- dc:title><xsl:value-of select="normalize-space($title)"/></dc:title -->

          <!-- Author -->
	  <xsl:if test="$authors">
	    <xsl:variable name="author">
	      <xsl:choose>
		<xsl:when test="$authors[self::authorgroup]">
                  <xsl:call-template name="person.name.list">
                    <xsl:with-param name="person.list" 
                         select="$authors/*[self::author|self::corpauthor|self::othercredit|self::editor]"/>
                  </xsl:call-template>
                </xsl:when>
                <xsl:when test="$authors[self::corpauthor]">
                  <xsl:value-of select="$authors"/>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:call-template name="person.name">
                    <xsl:with-param name="node" select="$authors"/>
                  </xsl:call-template>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:variable>

            <dc:creator>
              <!-- Однобуквенная замена и вызов шаблона несколькобуквенных замен -->
              <xsl:call-template name="replace-string">
                <xsl:with-param name="text-string"
                                select="normalize-space(translate($author,$l-rus,$l-trans))"/>
              </xsl:call-template>
            </dc:creator>
            <!-- dc:creator><xsl:value-of select="normalize-space($author)"/></dc:creator -->
          </xsl:if>

          <!-- Subject -->
          <xsl:if test="//subjectterm">
            <dc:description>
              <xsl:for-each select="//subjectterm">
                <xsl:value-of select="normalize-space(.)"/>
                <xsl:if test="position() != last()">
                  <xsl:text>, </xsl:text>
                </xsl:if>
              </xsl:for-each>
            </dc:description>
          </xsl:if>
        </rdf:Description>

        <rdf:Description rdf:about="" xmlns:pdf="http://ns.adobe.com/pdf/1.3/">
          <!-- PDF properties go here -->

          <!-- Keywords -->
          <xsl:if test="//keyword">
            <pdf:Keywords>
              <xsl:for-each select="//keyword">
                <xsl:value-of select="normalize-space(.)"/>
                <xsl:if test="position() != last()">
                  <xsl:text>, </xsl:text>
                </xsl:if>
              </xsl:for-each>
            </pdf:Keywords>
          </xsl:if>
        </rdf:Description>

        <rdf:Description rdf:about="" xmlns:xmp="http://ns.adobe.com/xap/1.0/">
          <!-- XMP properties go here -->

          <!-- Creator Tool -->
          <xmp:CreatorTool>FB2DocBook converter (by KiR)</xmp:CreatorTool>
        </rdf:Description>

      </rdf:RDF>
    </x:xmpmeta>
  </fo:declarations>
</xsl:template>

<!-- Шаблон непосредственного преобразования в транслит -->
<xsl:template name="replace-string" match="text()">
  <xsl:param name="text-string"/>
  <xsl:variable name="m01" select="$text-string"/>

  <xsl:variable name="m02">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m01"/>
      <xsl:with-param name="search-for" select="'ж'"/>
      <xsl:with-param name="replace-to" select="'zh'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m03">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m02"/>
      <xsl:with-param name="search-for" select="'Ж'"/>
      <xsl:with-param name="replace-to" select="'ZH'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m04">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m03"/>
      <xsl:with-param name="search-for" select="'х'"/>
      <xsl:with-param name="replace-to" select="'kh'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m05">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m04"/>
      <xsl:with-param name="search-for" select="'Х'"/>
      <xsl:with-param name="replace-to" select="'KH'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m06">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m05"/>
      <xsl:with-param name="search-for" select="'ц'"/>
      <xsl:with-param name="replace-to" select="'ts'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m07">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m06"/>
      <xsl:with-param name="search-for" select="'Ц'"/>
      <xsl:with-param name="replace-to" select="'TS'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m08">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m07"/>
      <xsl:with-param name="search-for" select="'ч'"/>
      <xsl:with-param name="replace-to" select="'ch'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m09">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m08"/>
      <xsl:with-param name="search-for" select="'Ч'"/>
      <xsl:with-param name="replace-to" select="'CH'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m10">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m09"/>
      <xsl:with-param name="search-for" select="'ш'"/>
      <xsl:with-param name="replace-to" select="'sh'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m11">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m10"/>
      <xsl:with-param name="search-for" select="'Ш'"/>
      <xsl:with-param name="replace-to" select="'SH'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m12">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m11"/>
      <xsl:with-param name="search-for" select="'щ'"/>
      <xsl:with-param name="replace-to" select="'sch'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m13">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m12"/>
      <xsl:with-param name="search-for" select="'Щ'"/>
      <xsl:with-param name="replace-to" select="'SCH'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m14">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m13"/>
      <xsl:with-param name="search-for" select="'ю'"/>
      <xsl:with-param name="replace-to" select="'yu'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m15">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m14"/>
      <xsl:with-param name="search-for" select="'Ю'"/>
      <xsl:with-param name="replace-to" select="'YU'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m16">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m15"/>
      <xsl:with-param name="search-for" select="'я'"/>
      <xsl:with-param name="replace-to" select="'ya'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="m17">
    <xsl:call-template name="replace">
      <xsl:with-param name="str" select="$m16"/>
      <xsl:with-param name="search-for" select="'Я'"/>
      <xsl:with-param name="replace-to" select="'YA'"/>
    </xsl:call-template>
  </xsl:variable>

  <xsl:value-of select="$m17"/>
</xsl:template>

<!-- Общий шаблон строковых замен -->
<xsl:template name="replace" match="text()" mode="replace">
  <xsl:param name="str"/>
  <xsl:param name="search-for"/>
  <xsl:param name="replace-to"/>
  <xsl:choose>
    <xsl:when test="contains($str, $search-for)">
      <xsl:value-of select="substring-before($str, $search-for)"/>
      <xsl:copy-of select="$replace-to"/>
      <xsl:call-template name="replace">
        <xsl:with-param name="str" select="substring-after($str, $search-for)"/>
        <xsl:with-param name="search-for" select="$search-for"/>
        <xsl:with-param name="replace-to" select="$replace-to"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$str"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>