DBCC TRACEON( 3604 )
GO
SELECT @@SPID
GO
 -- 57 - это мой SPID из предыдущей команды
 
DBCC PSS ( 0 ,  57 ,  0 )
GO

if OBJECT_ID('dbo.fn_hexstring2bigint', 'FN') IS NOT NULL
  DROP FUNCTION dbo.fn_hexstring2bigint
GO

CREATE FUNCTION dbo.fn_hexstring2bigint 
(
@HexString varchar( 100 )
)
RETURNS bigint
AS
begin

  declare @Result bigint, @i int

  SET @i =  1 
  SET @Result =  0 

  SET @HexString = RIGHT(@HexString, LEN(@HexString)- 2 )

  WHILE (@i <= LEN(@HexString))
    begin
      SELECT @Result = @Result *  16  + 
             CASE UPPER(SUBSTRING(@HexString, @i,  1 ))
             WHEN '0' THEN  0 
             WHEN '1' THEN  1 
             WHEN '2' THEN  2 
             WHEN '3' THEN  3 
             WHEN '4' THEN  4 
             WHEN '5' THEN  5 
             WHEN '6' THEN  6 
             WHEN '7' THEN  7 
             WHEN '8' THEN  8 
             WHEN '9' THEN  9 
             WHEN 'A' THEN  10 
             WHEN 'B' THEN  11 
             WHEN 'C' THEN  12 
             WHEN 'D' THEN  13 
             WHEN 'E' THEN  14 
             WHEN 'F' THEN  15 
             END
      SET @i = @i +  1 
    end
  RETURN @Result
end
GO

if OBJECT_ID('dbo.get_useroptions', 'P') IS NOT NULL
  DROP PROCEDURE dbo.get_useroptions
GO

CREATE PROCEDURE dbo.get_useroptions
  @SPID int
AS
SET NOCOUNT ON

 -- Remote process (connection) USEROPTIONS dumper
 
 -- Martin Rakhmanoff
 
 -- jimmers@yandex.ru
 
 -- 1:12 PM 8/30/2002
 

declare @poptions bigint, @poptions2 bigint, @cmd varchar( 100 )

declare @USEROPTIONS table ([Set Option] varchar( 50 ))

CREATE TABLE #DBCC_PSS (ParentObject varchar( 20 ), 
                              Object varchar( 50 ), 
                               Field varchar( 50 ), 
                               VALUE varchar( 100 ))

 -- Dump Process Status Structure
 
SET @cmd = 'DBCC PSS (0, ' + CAST(@SPID as varchar( 10 )) + ' , 0) WITH TABLERESULTS'
INSERT #DBCC_PSS EXEC(@cmd)

 -- Get OPTIONS
 
SELECT @poptions = dbo.fn_hexstring2bigint(VALUE) FROM #DBCC_PSS WHERE Field = 'poptions'
SELECT @poptions2 = dbo.fn_hexstring2bigint(VALUE) FROM #DBCC_PSS WHERE Field = 'poptions2'

 -- Parse 'em
 
if @poptions & 0x40000000 <>  0 
  insert @USEROPTIONS values('ANSI_NULL_DFLT_OFF')
if @poptions & 0x20000000 <>  0 
  insert @USEROPTIONS values('ANSI_NULL_DFLT_ON')
if @poptions & 0x8000000 <>  0 
  insert @USEROPTIONS values('QUOTED_IDENTIFIER')
if @poptions & 0x200000 <>  0 
  insert @USEROPTIONS values('NOCOUNT')
if @poptions & 0x20000 <>  0 
  insert @USEROPTIONS values('XACT_ABORT')
if @poptions & 0x10000 <>  0 
  insert @USEROPTIONS values('NUMERIC_ROUNDABORT')
if @poptions & 0x40 <>  0 
  insert @USEROPTIONS values('ARITHABORT')
if @poptions & 0x10 <>  0 
  insert @USEROPTIONS values('ARITHIGNORE')
if @poptions2 & 0x2000 <>  0 
  insert @USEROPTIONS values('CONCAT_NULL_YIELDS_NULL')
if @poptions2 & 0x20 <>  0 
  insert @USEROPTIONS values('ANSI_NULLS')
if @poptions2 & 0x10 <>  0 
  insert @USEROPTIONS values('ANSI_PADDING')
if @poptions2 & 0x8 <>  0 
  insert @USEROPTIONS values('ANSI_WARNINGS')
if @poptions2 & 0x4 <>  0 
  insert @USEROPTIONS values('CURSOR_CLOSE_ON_COMMIT')
if @poptions2 & 0x2 <>  0 
  insert @USEROPTIONS values('IMPLICIT_TRANSACTIONS')

 -- Show results
 
SELECT * FROM @USEROPTIONS

RETURN  0 
GO

 -- Should be identical to DBCC USEROPTIONS
 
EXECUTE dbo.get_useroptions @@SPID
GO