use tempdb;
go

create table dbo.t1 (id int primary key, a int);
create table dbo.t2 (id int primary key, a int);
go

create trigger dbo.tr_t1
on dbo.t1
after insert, update, delete
as
begin
 set nocount on;

 if object_id('tempdb..#tr_t2', 'U') is not null
  return;

 create table #tr_t1 (dummy int);

 with s (id, a, is_deleted) as
 (
  select
   isnull(i.id, d.id), i.a, case when i.id is null then 1 else 0 end
  from
   inserted i full join
   deleted d on d.id = i.id
 )
 merge into dbo.t2 t
 using s on s.id = t.id
 when not matched then
  insert
   (id, a)
  values
   (s.id, s.a)
 when matched and s.is_deleted = 0 then
  update
   set a = s.a
 when matched and s.is_deleted = 1 then
  delete;
end;
go

create trigger dbo.tr_t2
on dbo.t2
after insert, update, delete
as
begin
 set nocount on;

 if object_id('tempdb..#tr_t1', 'U') is not null
  return;

 create table #tr_t2 (dummy int);

 with s (id, a, is_deleted) as
 (
  select
   isnull(i.id, d.id), i.a, case when i.id is null then 1 else 0 end
  from
   inserted i full join
   deleted d on d.id = i.id
 )
 merge into dbo.t1 t
 using s on s.id = t.id
 when not matched then
  insert
   (id, a)
  values
   (s.id, s.a)
 when matched and s.is_deleted = 0 then
  update
   set a = s.a
 when matched and s.is_deleted = 1 then
  delete;
end;
go

insert into dbo.t1 values (1, 1);
insert into dbo.t2 values (2, 2);

select * from dbo.t1;
select * from dbo.t2;
go

drop table dbo.t1, dbo.t2;
go