Function AntiTarget()
   Lparameters tcTableAlias, tlReturnWorkArea
   ** Author: Igor Nikiforov   2007 - 06 - 11 
   ** Returns the alias of a table that is the parent table for a relation as specified in the INTO clause of SET RELATION.
   ** tcTableAlias Returns the alias of the parent table in another work area.
   ** nWorkArea specifies a work area number and tcTableAlias specifies a table alias.
   ** By default, the alias of the parent table from the current work area is returned
   ** if you don't specify the work area or alias.
   ** If tlReturnWorkArea Is .T. returns the number of WorkArea else returns the Alias of parent table
   Do Case
      Case Type("tcTableAlias") = "N"
         tcTableAlias = Alias(tcTableAlias)
      Case  Type("tcTableAlias") = "C"
         tcTableAlias = Alltrim(tcTableAlias)
         If Used(tcTableAlias)
            tcTableAlias = Alias(tcTableAlias)
         Else
            Return Iif(tlReturnWorkArea, - 1 , Null)  && No table is open in Work Area specified by the tcTableAlias
         Endif
      Otherwise
         tcTableAlias = Alias()
   Endcase
   If Empty(tcTableAlias) .Or. .Not.Used(tcTableAlias)
      Return Iif(tlReturnWorkArea, - 1 , Null)  && No table is open in Work Area specified by the tcTableAlias
   Endif
   Local lnI, lnJ, lcTarget
   Local Array laUsed( 1 )
   If .Not.Empty(Aused(laUsed))
      For lnI =  1  To Alen(laUsed,  1 )
         lnJ =  1 
         lcTarget = Target(lnJ, laUsed(lnI,  1 ))
         Do While .Not.Empty(lcTarget)
            If lcTarget == tcTableAlias
               Return Iif(tlReturnWorkArea, laUsed(lnI,  2 ), Alias(laUsed(lnI,  2 )))
            Endif
            lnJ = lnJ +  1 
            lcTarget = Target(lnJ, laUsed(lnI,  1 ))
         Enddo
      Endfor
   Endif
   Return Iif(tlReturnWorkArea,  0 , "") && No parent table

Open Database (Home( 2 ) + 'Data\testdata')
Use In Select("products")
Use In Select("alcustomer")
Use In Select("customer")
Use In Select("employee")
Use In Select("orders")
Use In Select("orditems")

Use customer Alias alcustomer  In  0  Order cust_id  && Opens Customer table
Use employee In  0  Order emp_id  && Opens Customer table
Use orders In   0  Order order_id  && Opens Customer table
Use products In   0 
Use orditems In   0  Order product_id
Select products
Set Relation To product_id  Into orditems
Select orders
Set Relation To emp_id Into employee
Set Relation To cust_id Into alcustomer  Additive
? " Target(1) ", Target( 1 )
? " Target(2) ", Target( 2 )
? " AntiTarget([orders]) ", AntiTarget()
? " AntiTarget([employee]) ", AntiTarget([employee])
? " AntiTarget([customer]) ", AntiTarget([customer])
? " AntiTarget([ ALCUSTOMER ]) ", AntiTarget([ ALCUSTOMER ])
? " AntiTarget([products]) ", AntiTarget([products])
Select orditems
? " AntiTarget([orditems]) ", AntiTarget()
? " AntiTarget([Null]) ", AntiTarget(Null)
For lnI =  1  To  6 
   ? " AntiTarget("+Alltrim(Str(lnI ))+") ", AntiTarget(lnI)
Endfor