oSMTP=NEWOBJECT("smtpmail","smtpmail.prg")

DEFINE CLASS clssmtp AS custom
	*-- SMTP-server
	PROTECTED cserver
	cserver = ""
	PROTECTED clogin
	clogin = ""
	PROTECTED cpassword
	cpassword = .F.
	PROTECTED cmailfrom
	cmailfrom = ""
	PROTECTED clasterror
	clasterror = ""
	PROTECTED omsg
	omsg = .F.
	Name = "clssmtp"

	*-- Установка данных отправителя
	PROCEDURE setfrom
		lpara tcServer, tcLogin, tcPass, tcMailFrom
		this.cServer = tcServer
		this.cLogin = tcLogin
		this.cpassword = tcPass
		this.cMailFrom = tcMailFrom
	ENDPROC

	*-- Добавление файла
	PROCEDURE attachfile
		lpara tcFile
		local llOk
		if this.CreateMsg()
			Try
				this.oMsg.AddAttachment(tcFile)
				this.cLastError = ''
				llOk = .T.
			Catch To loError
				this.cLastError = loError.Message
			Finally
				*
			Endtry
		endif
		return llOk
	ENDPROC

	PROCEDURE send
		lpara tcTo, tcSubj, tcText
		local llOk
		if this.CreateMsg()
			Try
				with this.oMsg
			 		.To = tcTo
			 		.Subject = tcSubj
					.TextBody = tcText
			 		.TextBodyPart.Charset ="windows-1251"
			 		.TextBodyPart.ContentTransferEncoding ="quoted-printable"
			 		.Send()
			 	endwith
				this.cLastError = ''
				llOk = .T.
			Catch To loError
				this.cLastError = loError.Message
			Finally
				this.oMsg = .F.
			Endtry
		endif
		return llOk
	ENDPROC


	PROCEDURE getlasterror
		return this.cLastError
	ENDPROC


	PROTECTED PROCEDURE createmsg
		local lcSchema, llOk

		if vartype(this.oMsg) = 'O'
			llOk = .T.
		else
			Try
			 	this.oMsg = NewObject("CDO.Message")
			 	lcSchema = "http://schemas.microsoft.com/cdo/configuration/"
			 	with this.oMsg.Configuration.Fields
			 		.Item(lcSchema + "smtpserverport") =  25  && SMTP Port
			 		.Item(lcSchema + "sendusing") =  2  && Send it using port
			 		.Item(lcSchema + "smtpserver") = this.cServer && host of smtp server
			 		.Item(lcSchema + "smtpauthenticate") =  1  && Authenticate
			 		.Item(lcSchema + "sendusername") = this.cLogin && Username
			 		.Item(lcSchema + "sendpassword") = this.cPassword && Password
			 		.Update()
			 	endwith
				this.oMsg.From = this.cMailFrom
				this.cLastError = ''
				llOk = .T.
			Catch To loError
				this.cLastError = loError.Message
			Finally
				*
			Endtry
		endif
		return llOk
	ENDPROC


ENDDEFINE

loSMTP = NewObject('clsSMTP')
loSMTP.SetFrom("smtp.mailserver.ru", "MyMailLogin", "Password", "От кого<MyMail@mailserver.ru>;")
...
if !loSMTP.Attachfile("c:\test.txt")
   ? "Не удалось приаттачить файл", loSMTP.GetLastError()
else
   if !loSMTP.Send("мыло получателя", "Тема письма", "Тело" + chr( 13 ) + chr( 10 ) + "письма")
      ? 'Не удалось отправить письмо', loSMTP.GetLastError()
   else
      ? 'Письмо ушло'
   endif
endif