теоретически - можно
практически - если текстов много и/или они длинные, то может быть черезчур ресурсоемко/медленно

формула массива (ввод через CTRL+SHIFT+ENTER)
=ПОИСКПОЗ(ЛОЖЬ;ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)=ПСТР(A2;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A2)));1);0)

KL
[MVP - Microsoft Excel]

@NikKL, а разве ДВССЫЛ() не летучая... ? Чего ты ушёл от конструкции СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;ДЛСТР(A1))) ?Летучая, просто первая пробная версия формулы была летучей и без того, а потом в спешке я забыл почистить финальный вариант.

Я смотрю вы с Deggasad никак не можете уйти от предложенного мной принципа решения :-) Когда я писал его, я исходил исключительно из конкретного примера - времени на поиск универсальности не было.

Может такое решение подойдет:

формула массива (ввод через CTRL+SHIFT+ENTER)
=SI(A1=A2;0;COINCIDIR(FALSO;ESNUMERO(1/(EXTRAE(A1;FILA(INDICE(A:A;1):INDICE(A:A;LARGO(A1)));1)=EXTRAE(A2;FILA(INDICE(A:A;1):INDICE(A:A;LARGO(A2)));1)));0))

KL
[MVP - Microsoft Excel]

пардон формула вместо русского перевелась на испанский:

=ЕСЛИ(A1=A2;0;ПОИСКПОЗ(ЛОЖЬ;ЕЧИСЛО(1/(ПСТР(A1;СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;ДЛСТР(A1)));1)=ПСТР(A2;СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;ДЛСТР(A2)));1)));0))

KL
[MVP - Microsoft Excel]

@NikВот мой окончательный вариант :-)
{=ПОИСКПОЗ(ЛОЖЬ;ПСТР(A1&" ";СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A1);ДЛСТР(A2))));1)=ПСТР(A2&СИМВОЛ(1);СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A2);ДЛСТР(A1))));1);)}Думаю, что этот вариант немного не дотягивает до окончательного. Комментарии:

1) попробуй эту формулу в такой ситуации:
[A1] ="мама мыла раму мылом"
[A2] ="мама мыла раму мылом и зубным порошком"

2) для одинаковых текстов формула выдает, что различия начинаются (!?) после последнего (или начиная с несуществующего) знака.

3) если сможешь заставить работать свое решение, то выигрыш в скорости по сравнению с моим будет коллосальным - почти в 10 раз в Excel 2007.

KL
[MVP - Microsoft Excel]

KL (XL) @NikВот мой окончательный вариант :-)
{=ПОИСКПОЗ(ЛОЖЬ;ПСТР(A1&" ";СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A1);ДЛСТР(A2))));1)=ПСТР(A2&СИМВОЛ(1);СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A2);ДЛСТР(A1))));1);)}3) если сможешь заставить работать свое решение, то выигрыш в скорости по сравнению с моим будет коллосальным - почти в 10 раз в Excel 2007.
Похоже, вот длинная, но чертовски быстрая (быстрее твоей) альтернатива:

=ЕСЛИ(A1=A2;0;ЕСЛИ(ЛЕВСИМВ(A1;МИН(ДЛСТР(A1);ДЛСТР(A2)))=ЛЕВСИМВ(A2;МИН(ДЛСТР(A1);ДЛСТР(A2)));МИН(ДЛСТР(A1);ДЛСТР(A2))+1;ПОИСКПОЗ(ЛОЖЬ;ПСТР(A1;СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;МИН(ДЛСТР(A1);ДЛСТР(A2))));1)=ПСТР(A2;СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;МИН(ДЛСТР(A2);ДЛСТР(A1))));1);)))

KL
[MVP - Microsoft Excel]

@NikА если так:
{=ПОИСКПОЗ(ЛОЖЬ;ПСТР(A1&СИМВОЛ(1);СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A1);ДЛСТР(A2))));1)=ПСТР(A2&СИМВОЛ(2);СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;1+МИН(ДЛСТР(A2);ДЛСТР(A1))));1);)}Пункт 2 остается в силе.
Моя последняя формула в 4 раза быстрее

@NikА в твоём варианте я бы изменил ЕЧИСЛО(1/(....)) на ЕЧИСЛО(-(....)). Вот тебе и выигрыш в 10 раз ;-)Это на скорость расчета практически не повлияет, и тем более в 10 раз ;-)

KL
[MVP - Microsoft Excel]

KL (XL) @NikА в твоём варианте я бы изменил ЕЧИСЛО(1/(....)) на ЕЧИСЛО(-(....)). Вот тебе и выигрыш в 10 раз ;-)Это на скорость расчета практически не повлияет, и тем более в 10 раз ;-)Самого главного то и не сказал:

весь смысл решения через 1/() в том, чтобы привести значения ЛОЖЬ и #NA т.с. к "общему знаменателю". При делении 1 на 0 (ЛОЖЬ) или на ошибку (#NA) результатом будет ошибка (#DIV0 или #NA), т.е. не число. В случае деления на 1 (ИСТИНА) результатом будет число. Что и требовалось получить. Если же использовать -(), то значение ЛОЖЬ тоже даст число - 0, а это приведет к ошибке в результате например здесь:

[A1]="мама мыла рам к у мылом"
[A2]="мама мыла раму мылом и зубным порошком"


KL
[MVP - Microsoft Excel]

@NikОк. А будет ли выигрыш в быстродействии в 4 раза для случая
[A1]="мама мыла рам к у мылом"
[A2]="мама мыла раму мылом и зубным порошком"

Мне кажется, что нет :-)Четко подмечено! Тут я, сам того не ведая, немного схитрил - использовал для тестирования лишь частный случай :-) Скорость в этом случае та же, но... это правда не отменяет потенциальной экономии в скорости в частном случае полного совпадения более короткого текста с началом более длинного.

@NikИ ещё вопрос: почему на скорость практически не сказывается замена 1/() на -()Ну потому что при сравнении решений, где соотношение скоростей 1:10, те 9% которые выигрываются, на мой взгляд, - ничтожны. А почему ты думал, что выигрыш будет больше? Я кажется всегда говорил, что, по моим наблюдениям, разница между --() и др. способами превращения логических значений в числа порядка 15% быстрее в Excel2003 и 10% в Excel2007. Может где-то "вкралась очепятка"?

KL
[MVP - Microsoft Excel]

@NikЯ вообще давно хотел спросить как ты произвожишь замеры скорости вычисления формул ? ;-)

Вот тут надстройка RangeCalc , только помни, что замеры надо обязательно производить в режиме ручного пересчета:

http://www.decisionmodels.com/downloads.htm

KL
[MVP - Microsoft Excel]

DeggasadА я то думал грешным делом, что это я любитель позагоняться!!!
А что такое "позагоняться"?

KL
[MVP - Microsoft Excel]

@NikДа.... интересная надстройка... Только есть небольшая проблемка - рассчётное время выполнения формул плавает :-) У меня наши две формулы не различаются по быстродействию (на офф. ХР). Вернее, их время выполнения получалось то 0,03 то 0,05 мс. Сделал больше замеров - появились цифры 0,04; 0,06 и аж 0,08 мс. Чаще всего выдавался результат 0,03 мс. Но никак разница в 4 раза заметна не была... Неужели разница в оффисе настолько сказывается ?
1) Время плавает потому что:
- в твоем компе ничто не стоит на месте, начинаются и заканчиваются разные процессы, которые влияют на доступность памяти и процессора в данный момент.
- версии Office и Windows влияют несомненно
- часто вмешивается экселевский механизм SmartCalculation, который сам решает нужно ли пересчитывать определенные зависимости в каждой конкретной ситуации.
- в данной формуле к тому же все зависит от длинны текста и от того, какая часть ЕСЛИ() выполняется.
- в случае с функциями поиска значений очень влияет размер рангов поиска и тип поиска (точный или приблизительный)
- важно количество формул включенных в промер, чем больше, тем очевидней разница если она есть
- не забывай, что в твоем примере речь идет о ничтожно малых промежутках времени, т.е. разница между первым и последним промером 0.0005 сек.

2) Попробуй следующее
- возьми мой первый пример:
[A1]="мама мыла раму мылом"
[A2]="мама мыла раму мылом и зубным порошком"
- растяни его от [A1] до [A1000]
- в столбце [С1:С1000] введи первую формулу
- в столбце [Е1:Е1000] введи вторую формулу
- отключи автоматический пересчет
- запусти надстройку по 3-5 раз для каждого из диапазонов [С1:С1000] и [Е1:Е1000]
- сравни среднее арифметическое промеров для каждого из диапазонов

теперь поменяй пример в столбце [A1:A1000] на:
[A1]="мама мыла рам к у мылом"
[A2]="мама мыла раму мылом и зубным порошком"